{-# LANGUAGE BangPatterns #-}
{-# LANGUAGE FlexibleContexts #-}
{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE MultiParamTypeClasses #-}
{-# LANGUAGE NamedFieldPuns #-}
{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE ScopedTypeVariables #-}
{-# LANGUAGE TupleSections #-}
{-# LANGUAGE TypeFamilies #-}
module Hcompta.CLI.Command.Tags where

import           Control.Monad (Monad(..), forM_, liftM, mapM)
import           Control.Monad.IO.Class (liftIO)
import           Control.Monad.Trans.Except (runExceptT)
import           Data.Bool
import           Data.Either (Either(..), partitionEithers)
import           Data.Foldable (Foldable(..))
import           Data.Functor ((<$>))
import           Data.Functor.Compose (Compose(..))
import           Data.List ((++), replicate)
import qualified Data.List (filter)
import           Data.Map.Strict (Map)
import qualified Data.Map.Strict as Data.Map
import           Data.Maybe (Maybe(..))
import           Data.Monoid (Monoid(..), (<>))
import           Data.String (String)
import           Prelude (($), (.), Bounded(..), FilePath, Integer, IO, Num(..), flip, id, unlines)
import           Text.Show (Show(..))
import           System.Console.GetOpt
                 ( ArgDescr(..)
                 , OptDescr(..)
                 , usageInfo )
import           System.Environment as Env (getProgName)
import           System.Exit (exitSuccess)
import qualified System.IO as IO

import           Hcompta.Account (Account)
import qualified Hcompta.CLI.Args as Args
import           Hcompta.CLI.Context (Context)
import qualified Hcompta.CLI.Context as Context
import qualified Hcompta.CLI.Format.Ledger as CLI.Ledger
import qualified Hcompta.CLI.Write as Write
import qualified Hcompta.Filter as Filter
import qualified Hcompta.Filter.Read as Filter.Read
import qualified Hcompta.Format.Ledger as Ledger
import qualified Hcompta.Format.Ledger.Journal as Ledger.Journal
import qualified Hcompta.Format.Ledger.Read as Ledger.Read
import           Hcompta.Lib.Consable (Consable(..))
import qualified Hcompta.Lib.Leijen as W
import qualified Hcompta.Tag as Tag

data Ctx
 =   Ctx
 { ctx_input              :: [FilePath]
 , ctx_filter_transaction :: Filter.Simplified
                             (Filter.Filter_Bool
                             (Filter.Filter_Transaction
                             Ledger.Transaction))
 , ctx_filter_tag         :: Filter.Simplified
                             Filter.Filter_Tag
 , ctx_tree               :: Bool
 } deriving (Show)

nil :: Ctx
nil =
	Ctx
	 { ctx_input = []
	 , ctx_filter_transaction = mempty
	 , ctx_filter_tag = mempty
	 , ctx_tree = False
	 }

usage :: IO String
usage = do
	bin <- Env.getProgName
	let pad = replicate (length bin) ' '
	return $unlines $
		[ "SYNTAX "
		, "  "++bin++" tags [-i JOURNAL_FILE]"
		, "  "++pad++"      [-t TRANSACTION_FILTER]"
		, "  "++pad++"      [JOURNAL_FILE] [...]"
		, ""
		, usageInfo "OPTIONS" options
		]

options :: Args.Options Ctx
options =
	[ Option "h" ["help"]
	 (NoArg (\_context _ctx -> do
		usage >>= IO.hPutStr IO.stderr
		exitSuccess))
	 "show this help"
	, Option "i" ["input"]
	 (ReqArg (\s _context ctx -> do
		return $ ctx{ctx_input=s:ctx_input ctx}) "FILE")
	 "read data from given file, multiple uses merge the data as would a concatenation do"
	, Option "t" ["transaction-filter"]
	 (ReqArg (\s context ctx -> do
		ctx_filter_transaction <-
			liftM ((ctx_filter_transaction ctx <>) . Filter.simplify) $
			liftIO $ Filter.Read.read Filter.Read.filter_transaction s
			>>= \f -> case f of
			 Left  ko -> Write.fatal context $ ko
			 Right ok -> do
				Write.debug context $ "filter: transaction: " ++ show ok
				return ok
		return $ ctx{ctx_filter_transaction}) "FILTER")
	 "filter at transaction level, multiple uses are merged with a logical AND"
	, Option "T" ["tag-filter"]
	 (ReqArg (\s context ctx -> do
		ctx_filter_tag <-
			liftM ((ctx_filter_tag ctx <>) . Filter.simplify) $
			liftIO $ Filter.Read.read Filter.Read.filter_tag s
			>>= \f -> case f of
			 Left  ko -> Write.fatal context $ ko
			 Right ok -> do
				Write.debug context $ "filter: tag: " ++ show ok
				return ok
		return $ ctx{ctx_filter_tag}) "FILTER")
	 "filter at transaction level, multiple uses are merged with a logical AND"
	, Option "" ["tree"]
	 (OptArg (\arg context ctx -> do
		ctx_tree <- case arg of
		 Nothing    -> return $ True
		 Just "yes" -> return $ True
		 Just "no"  -> return $ False
		 Just _     -> Write.fatal context $
			W.text "--tree option expects \"yes\", or \"no\" as value"
		return $ ctx{ctx_tree})
	  "[yes|no]")
	 "print tags as a tree"
	]

run :: Context.Context -> [String] -> IO ()
run context args = do
	(ctx, inputs) <- Args.parse context usage options (nil, args)
	read_journals <-
		liftM Data.Either.partitionEithers $ do
		CLI.Ledger.paths context $ ctx_input ctx ++ inputs
		>>= do
			mapM $ \path -> do
				liftIO $ runExceptT $ Ledger.Read.file
				 (Ledger.Read.context
					 ( ctx_filter_transaction ctx
					 , ctx_filter_tag ctx
					 ) Ledger.journal)
				 path
				>>= \x -> case x of
				 Left  ko -> return $ Left (path, ko)
				 Right ok -> return $ Right ok
	case read_journals of
	 (errs@(_:_), _journals) ->
		forM_ errs $ \(_path, err) -> do
			Write.fatal context $ err
	 ([], journals) -> do
		let files = ledger_tags ctx journals
		style_color <- Write.with_color context IO.stdout
		W.displayIO IO.stdout $ do
		W.renderPretty style_color 1.0 maxBound $ do
		doc_tags context ctx files

ledger_tags
 :: Ctx
 -> [ Ledger.Journal (Tags Ledger.Transaction) ]
 -> Tags Ledger.Transaction
ledger_tags _ctx =
	Data.Foldable.foldl'
	 (flip $ Ledger.Journal.fold
		 (\Ledger.Journal{Ledger.journal_transactions=ts} ->
			mappend ts))
	 mempty

doc_tags
 :: Context
 -> Ctx
 -> Tags Ledger.Transaction
 -> W.Doc
doc_tags _context ctx =
	(case ctx_tree ctx of
	 True ->
		Data.Map.foldlWithKey
		 (\doc p vs ->
			doc <> foldMap (\s -> W.dullyellow (W.toDoc () s) <> (W.bold $ W.dullblack ":")) p <>
			" (" <> (W.toDoc () (Data.Map.size vs)) <> ")" <>
			W.nest 2 (
				Data.Map.foldlWithKey
				 (\doc' v vn ->
					doc' <> W.line <> W.dullred (W.toDoc () v) <>
					" (" <> (W.toDoc () vn) <> ")"
				 )
				 W.empty vs
			 ) <> W.line
		 )
		 W.empty
	 False ->
		Data.Map.foldlWithKey
		 (\doc p vs ->
			doc <>
			Data.Map.foldlWithKey
			 (\doc' v _vn ->
				doc' <>
				foldMap (\s -> W.dullyellow (W.toDoc () s) <> (W.bold $ W.dullblack ":")) p <>
				W.dullred (W.toDoc () v) <> W.line
			 ) W.empty vs
		 )
		 W.empty
	 ) .
	tags

-- * Requirements' interface

-- ** Class 'Posting'

class Posting        p where
	posting_account :: p -> Account

instance Posting Ledger.Posting where
	posting_account = Ledger.posting_account

-- ** Class 'Transaction'

class
 ( Posting  (Transaction_Posting  t)
 , Foldable (Transaction_Postings t)
 )
 =>    Transaction          t where
	type Transaction_Posting  t
	type Transaction_Postings t :: * -> *
	-- transaction_postings      :: t -> Transaction_Postings t (Transaction_Posting t)
	transaction_tags          :: t -> Map Tag.Path [Tag.Value]

instance Transaction        Ledger.Transaction where
	type Transaction_Posting  Ledger.Transaction = Ledger.Posting
	type Transaction_Postings Ledger.Transaction = Compose [] (Compose (Map Account) [])
	transaction_tags = Ledger.transaction_tags

-- * Type 'Tags'

data Transaction t => Tags t
 = Tags
 { tags :: Map Tag.Path (Map Tag.Value Integer)
 }
 deriving (Show)

instance Transaction t => Monoid (Tags t) where
	mempty = Tags mempty
	mappend t0 t1 =
		Tags
		 { tags = Data.Map.unionWith
			 (Data.Map.unionWith (+))
			 (tags t0)
			 (tags t1)
		 }
instance Transaction t => Consable (Filter.Simplified Filter.Filter_Tag) Tags t where
	mcons f t !ts =
		case Filter.simplified f of
		 Right False -> ts
		 Right True  -> ts{ tags = merge (transaction_tags t) (tags ts) }
		 Left fT ->
			ts{ tags = merge
			 (Data.Map.mapMaybeWithKey
				 (\p vs ->
					if Filter.test fT (p, vs)
					then Just $ Data.List.filter (\v -> Filter.test fT (p, [v])) vs
					else Nothing)
				 (transaction_tags t))
			 (tags ts)
			 }
		where
			merge
			 :: Map Tag.Path [Tag.Value]
			 -> Map Tag.Path (Map Tag.Value Integer)
			 -> Map Tag.Path (Map Tag.Value Integer)
			merge =
				Data.Map.mergeWithKey
				 (\_k x1 x2 -> Just $
					Data.Map.unionWith (+) x2 $
					Data.Map.fromListWith (+) $ (, 1) <$> x1)
				 ((Data.Map.fromListWith (+) . ((, 1) <$>)) <$>)
				 id
instance
 ( Filter.Transaction t
 , Transaction        t
 ) => Consable
 ( Filter.Simplified
    (Filter.Filter_Bool
    (Filter.Filter_Transaction t))
 ,  Filter.Simplified Filter.Filter_Tag
 )
 Tags t where
	mcons (ft, fT) t !ts =
		if Filter.test ft t
		then mcons fT t ts
		else ts