{
  inputs = {
    nixpkgs.url = "flake:nixpkgs";
    git-hooks.url = "github:cachix/git-hooks.nix";
    git-hooks.inputs.nixpkgs.follows = "nixpkgs";
  };
  outputs = inputs:
    let
      pkg = "symantic-base";
      lib = inputs.nixpkgs.lib;
      fileInputs = with lib.fileset; toSource {
        root = ./.;
        fileset = unions [
          ./symantic-base.cabal
          ./LICENSES
          (fileFilter (file: lib.any file.hasExt [ ".hs" ]) ./src)
          (fileFilter (file: lib.any file.hasExt [ ".hs" ]) ./tests)
        ];
      };
      forAllSystems = f: lib.genAttrs lib.systems.flakeExposed (system: f rec {
        inherit system;
        pkgs = inputs.nixpkgs.legacyPackages.${system};
        haskellPackages = pkgs.haskellPackages.extend (with pkgs.haskell.lib; hfinal: hsuper: {
          ${pkg} = buildFromSdist (hfinal.callCabal2nix pkg fileInputs { });
        });
      });
    in
    rec {
      # nix -L build
      packages = forAllSystems ({ haskellPackages, ... }: {
        default = haskellPackages.${pkg};
      });
      # nix -L develop  or  direnv allow
      devShells = forAllSystems ({ pkgs, haskellPackages, system, ... }: {
        default =
          haskellPackages.shellFor {
            packages = ps: [ ps.${pkg} ];
            nativeBuildInputs = [
              haskellPackages.cabal-install
              haskellPackages.ghcid
              haskellPackages.haskell-language-server
              haskellPackages.hlint
              pkgs.git-chglog
              pkgs.reuse
            ];
            withHoogle = false;
            inherit (checks.${system}.git-hooks-check) shellHook;
          };
      });
      # nix flake check
      checks = forAllSystems (args: with args; {
        git-hooks-check = inputs.git-hooks.lib.${system}.run {
          src = ./.;
          hooks = {
            ormolu.settings.cabalDefaultExtensions = true;
            cabal-fmt.enable = true;
            fourmolu.enable = true;
            hlint.enable = true;
            nixpkgs-fmt.enable = true;
            reuse = {
              enable = true;
              entry = "${pkgs.reuse}/bin/reuse lint";
              pass_filenames = false;
            };
          };
        };
      });
    };
}