{-# LANGUAGE UndecidableInstances #-}
{-# OPTIONS_GHC -fno-warn-orphans #-}
{-# OPTIONS_GHC -fconstraint-solver-iterations=5 #-}
-- | Symantic for @if@.
module Language.Symantic.Compiling.If where

import Data.Proxy
import Data.Text (Text)
import qualified Data.Text as Text
import Data.Type.Equality ((:~:)(Refl))

import Language.Symantic.Parsing
import Language.Symantic.Typing
import Language.Symantic.Compiling.Term
import Language.Symantic.Interpreting
import Language.Symantic.Transforming.Trans

-- * Class 'Sym_If'
class Sym_If term where
	if_ :: term Bool -> term a -> term a -> term a
	default if_ :: Trans t term => t term Bool -> t term a -> t term a -> t term a
	if_ = trans_map3 if_

-- * Type 'If'
data If
type instance Sym_of_Iface (Proxy If) = Sym_If
type instance Consts_of_Iface (Proxy If) = Consts_imported_by If
type instance Consts_imported_by If =
 '[ Proxy Bool
 ]

instance Sym_If HostI where
	if_ (HostI b) ok ko = if b then ok else ko
instance Sym_If TextI where
	if_ (TextI cond) (TextI ok) (TextI ko) =
		TextI $ \p v ->
			let p' = Precedence 2 in
			paren p p' $
			Text.concat
			 [ "if ", cond p' v
			 , " then ", ok p' v
			 , " else ", ko p' v ]
instance (Sym_If r1, Sym_If r2) => Sym_If (DupI r1 r2) where
	if_  = dupI3 (Proxy @Sym_If) if_

instance Const_from Text cs => Const_from Text (Proxy If ': cs) where
	const_from s k = const_from s $ k . ConstS

instance Proj_ConC cs (Proxy If)
data instance TokenT meta (ts::[*]) (Proxy If)
 = Token_Term_If_if (EToken meta ts) (EToken meta ts)
deriving instance Eq_Token meta ts => Eq (TokenT meta ts (Proxy If))
deriving instance Show_Token meta ts => Show (TokenT meta ts (Proxy If))
instance -- Term_fromI
 ( Inj_Const (Consts_of_Ifaces is) Bool
 , Inj_Const (Consts_of_Ifaces is) (->)
 , Term_from is
 ) => Term_fromI is (Proxy If) where
	term_fromI tok ctx k =
		case tok of
		 Token_Term_If_if tok_cond tok_ok ->
			-- if :: Bool -> a -> a -> a
			term_from tok_cond ctx $ \ty_cond (TermLC cond) ->
			term_from tok_ok   ctx $ \ty_ok   (TermLC ok) ->
			check_type
			 (At Nothing (ty @Bool))
			 (At (Just tok_cond) ty_cond) $ \Refl ->
			k (ty_ok ~> ty_ok) $ TermLC $
			 \c -> lam $ if_ (cond c) (ok c)