{-# LANGUAGE DataKinds #-}
{-# LANGUAGE DefaultSignatures #-}
{-# LANGUAGE FlexibleContexts #-}
{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE MultiParamTypeClasses #-}
{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE Rank2Types #-}
{-# LANGUAGE ScopedTypeVariables #-}
{-# LANGUAGE TypeFamilies #-}
{-# LANGUAGE TypeOperators #-}
{-# LANGUAGE UndecidableInstances #-}
{-# OPTIONS_GHC -fno-warn-orphans #-}
-- | Symantic for 'Bool'.
module Language.Symantic.Compiling.Bool where

import Control.Monad
import qualified Data.Bool as Bool
import Data.Monoid
import Data.Proxy
import Data.String (IsString)
import Data.Text (Text)
import Data.Type.Equality ((:~:)(Refl))
import qualified Data.Text as Text
import Prelude hiding ((&&), not, (||))

import Language.Symantic.Typing
import Language.Symantic.Compiling.Term
import Language.Symantic.Interpreting
import Language.Symantic.Transforming.Trans

-- * Class 'Sym_Bool'
class Sym_Bool term where
	bool ::      Bool -> term Bool
	not  :: term Bool -> term Bool
	(&&) :: term Bool -> term Bool -> term Bool
	(||) :: term Bool -> term Bool -> term Bool
	xor  :: term Bool -> term Bool -> term Bool
	xor x y = (x || y) && not (x && y)
	
	default bool :: Trans t term =>        Bool -> t term Bool
	default not  :: Trans t term => t term Bool -> t term Bool
	default (&&) :: Trans t term => t term Bool -> t term Bool -> t term Bool
	default (||) :: Trans t term => t term Bool -> t term Bool -> t term Bool
	
	bool = trans_lift . bool
	not  = trans_map1 not
	(&&) = trans_map2 (&&)
	(||) = trans_map2 (||)

infixr 2 ||
infixr 2 `xor`
infixr 3 &&

type instance Sym_of_Iface (Proxy Bool) = Sym_Bool
type instance Consts_of_Iface (Proxy Bool) = Proxy Bool ': Consts_imported_by Bool
type instance Consts_imported_by Bool =
 [ Proxy Bounded
 , Proxy Enum
 , Proxy Eq
 , Proxy Ord
 ]

instance Sym_Bool HostI where
	bool = HostI
	not  = liftM Bool.not
	(&&) = liftM2 (Bool.&&)
	(||) = liftM2 (Bool.||)
instance Sym_Bool TextI where
	bool a = TextI $ \_p _v ->
		Text.pack (show a)
	not (TextI x) =
		TextI $ \p v ->
			let p' = Precedence 9 in
			paren p p' $ "not " <> x p' v
	(&&) = textI_infix "&&"    (Precedence 6)
	(||) = textI_infix "||"    (Precedence 5)
	xor  = textI_infix "`xor`" (Precedence 5)
instance (Sym_Bool r1, Sym_Bool r2) => Sym_Bool (DupI r1 r2) where
	bool x = bool x `DupI` bool x
	not  = dupI1 sym_Bool not
	(&&) = dupI2 sym_Bool (&&)
	(||) = dupI2 sym_Bool (||)
	xor  = dupI2 sym_Bool xor

instance Const_from Text cs => Const_from Text (Proxy Bool ': cs) where
	const_from "Bool" k = k (ConstZ kind)
	const_from s k = const_from s $ k . ConstS
instance Show_Const cs => Show_Const (Proxy Bool ': cs) where
	show_const ConstZ{} = "Bool"
	show_const (ConstS c) = show_const c

instance -- Proj_ConC
 ( Proj_Const cs Bool
 , Proj_Consts cs (Consts_imported_by Bool)
 ) => Proj_ConC cs (Proxy Bool) where
	proj_conC _ (TyConst q :$ TyConst c)
	 | Just Refl <- eq_skind (kind_of_const c) SKiType
	 , Just Refl <- proj_const c (Proxy::Proxy Bool)
	 = Just $ case () of
		 _ | Just Refl <- proj_const q (Proxy::Proxy Bounded) -> Just Con
		   | Just Refl <- proj_const q (Proxy::Proxy Enum)    -> Just Con
		   | Just Refl <- proj_const q (Proxy::Proxy Eq)      -> Just Con
		   | Just Refl <- proj_const q (Proxy::Proxy Ord)     -> Just Con
		 _ -> Nothing
	proj_conC _c _q = Nothing
instance -- Term_fromI
 ( AST ast
 , Lexem ast ~ LamVarName
 , Inj_Const (Consts_of_Ifaces is) Bool
 , Inj_Const (Consts_of_Ifaces is) (->)
 ) => Term_fromI is (Proxy Bool) ast where
	term_fromI ast _ctx k =
		case ast_lexem ast of
		 "True"  -> k (ast_nodes ast) tyBool $ TermLC $ \_c -> bool True
		 "False" -> k (ast_nodes ast) tyBool $ TermLC $ \_c -> bool False
		 "not"   -> op1_from not
		 "&&"    -> op2_from (&&)
		 "||"    -> op2_from (||)
		 "xor"   -> op2_from xor
		 _ -> Left $ Error_Term_unsupported
		where
		op1_from (op::forall term. Sym_Bool term => term Bool -> term Bool) =
			from_ast0 ast $ \_lex as ->
			k as (tyBool ~> tyBool) $ TermLC $
			 \_c -> lam op
		op2_from (op::forall term. Sym_Bool term => term Bool -> term Bool -> term Bool) =
			from_ast0 ast $ \_lex as ->
			k as (tyBool ~> tyBool ~> tyBool) $ TermLC $
			 \_c -> lam $ lam . op

-- | The 'Bool' 'Type'
tyBool :: Inj_Const cs Bool => Type cs Bool
tyBool = TyConst inj_const

sym_Bool :: Proxy Sym_Bool
sym_Bool = Proxy

syBool :: IsString a => Syntax a
syBool = Syntax "Bool" []

syTrue :: IsString a => Syntax a
syTrue = Syntax "True" []

syFalse :: IsString a => Syntax a
syFalse = Syntax "False" []