{-# LANGUAGE DefaultSignatures #-}
{-# LANGUAGE FlexibleContexts #-}
{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE GADTs #-}
{-# LANGUAGE MultiParamTypeClasses #-}
{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE Rank2Types #-}
{-# LANGUAGE ScopedTypeVariables #-}
{-# LANGUAGE TypeFamilies #-}
{-# LANGUAGE UndecidableInstances #-}
-- | Expression for 'Int's.
module Language.LOL.Symantic.Expr.Int where

import Data.Proxy (Proxy(..))

import Language.LOL.Symantic.AST
import Language.LOL.Symantic.Type
import Language.LOL.Symantic.Expr.Common
import Language.LOL.Symantic.Expr.Lambda
import Language.LOL.Symantic.Repr.Dup
import Language.LOL.Symantic.Trans.Common

-- * Class 'Sym_Int'

-- | Symantic.
class Sym_Int repr where
	int ::      Int -> repr Int
	neg :: repr Int -> repr Int
	add :: repr Int -> repr Int -> repr Int
	
	default int :: Trans t repr =>        Int -> t repr Int
	default neg :: Trans t repr => t repr Int -> t repr Int
	default add :: Trans t repr => t repr Int -> t repr Int -> t repr Int
	int = trans_lift . int
	neg = trans_map1 neg
	add = trans_map2 add

instance -- Sym_Int Dup
 ( Sym_Int r1
 , Sym_Int r2
 ) => Sym_Int (Dup r1 r2) where
	int x = int x `Dup` int x
	neg (x1 `Dup` x2) = neg x1 `Dup` neg x2
	add (x1 `Dup` x2) (y1 `Dup` y2) = add x1 y1 `Dup` add x2 y2

-- * Type 'Expr_Int'
-- | Expression.
data Expr_Int (root:: *)
type instance Root_of_Expr (Expr_Int root) = root
type instance Type_of_Expr (Expr_Int root) = Type_Int
type instance Sym_of_Expr (Expr_Int root) repr = Sym_Int repr
type instance Error_of_Expr ast (Expr_Int root) = Error_Expr_Int ast

instance -- Expr_from AST Expr_Int
 ( Type_from AST (Type_Root_of_Expr root)
 , Expr_from AST root
 
 , Type_Root_Lift Type_Int (Type_Root_of_Expr root)
 , Error_Type_Lift (Error_Type_Fun AST)
                   (Error_of_Type AST (Type_Root_of_Expr root))
 , Error_Expr_Lift (Error_Expr_Lambda (Error_of_Type AST (Type_Root_of_Expr root))
                                      (                   Type_Root_of_Expr root)
                                      AST)
                   (Error_of_Expr AST root)
 , Error_Expr_Lift (Error_Expr AST) (Error_of_Expr AST root)
 
 , Type_Unlift Type_Int (Type_of_Expr root)
 
 , Root_of_Expr root ~ root
 -- , Root_of_Type (Type_Root_of_Expr root) ~ Type_Root_of_Expr root
 ) => Expr_from AST (Expr_Int root) where
	expr_from _px_ex ctx ast k =
		case ast of
		 AST "int" asts ->
			case asts of
			 [AST ast_int []] ->
				case read_safe ast_int of
				 Left err -> Left $ error_expr_lift $ Error_Expr_Read err ast
				 Right (i::Int) ->
					k type_int $ Forall_Repr_with_Context $
						const $ int i
			 _ -> Left $ error_lambda_lift $
				Error_Expr_Fun_Wrong_number_of_arguments 3 ast
		 AST "neg" asts -> unary_from  asts neg
		 AST "add" asts -> binary_from asts add
		 _ -> Left $ error_expr_lift $ Error_Expr_Unsupported ast
		where
		unary_from asts
		 (op::forall repr. Sym_Int repr
		    => repr Int -> repr Int) =
			case asts of
			 [ast_x] ->
				expr_from (Proxy::Proxy root) ctx ast_x $
				 \(ty_x::Type_Root_of_Expr root h_x) (Forall_Repr_with_Context x) ->
					case type_unlift $ unType_Root ty_x of
					 Just (Type_Int::Type_Int (Type_Root_of_Expr root) h_x) ->
						k ty_x $ Forall_Repr_with_Context (op . x)
					 _ -> Left $ error_lambda_lift $
						Error_Expr_Fun_Argument_mismatch
						 (Exists_Type type_int)
						 (Exists_Type ty_x) ast
			 _ -> Left $ error_lambda_lift $
				Error_Expr_Fun_Wrong_number_of_arguments 1 ast
		binary_from asts
		 (op::forall repr. Sym_Int repr
		    => repr Int -> repr Int -> repr Int) =
			case asts of
			 [ast_x, ast_y] ->
				expr_from (Proxy::Proxy root) ctx ast_x $
				 \(ty_x::Type_Root_of_Expr root h_x) (Forall_Repr_with_Context x) ->
				expr_from (Proxy::Proxy root) ctx ast_y $
				 \(ty_y::Type_Root_of_Expr root h_y) (Forall_Repr_with_Context y) ->
					case type_unlift $ unType_Root ty_x of
					 Just (Type_Int::Type_Int (Type_Root_of_Expr root) h_x) ->
						case type_unlift $ unType_Root ty_y of
						 Just (Type_Int::Type_Int (Type_Root_of_Expr root) h_y) ->
							k ty_x $ Forall_Repr_with_Context $
							 \c -> x c `op` y c
						 Nothing -> Left $ error_lambda_lift $
							Error_Expr_Fun_Argument_mismatch
							 (Exists_Type type_int)
							 (Exists_Type ty_y) ast
					 Nothing -> Left $ error_lambda_lift $
						Error_Expr_Fun_Argument_mismatch
						 (Exists_Type type_int)
						 (Exists_Type ty_x) ast
			 _ -> Left $ error_lambda_lift $
				Error_Expr_Fun_Wrong_number_of_arguments 2 ast
		error_lambda_lift
		 :: Error_Expr_Lambda (Error_of_Type AST (Type_Root_of_Expr root)) (Type_Root_of_Expr root) AST
		 -> Error_of_Expr AST root
		error_lambda_lift = error_expr_lift

-- ** Type 'Expr_Lambda_Int'
-- | Convenient alias.
type Expr_Lambda_Int lam = Expr_Root (Expr_Cons (Expr_Lambda lam) Expr_Int)

expr_lambda_int_from
 :: forall lam ast.
 Expr_from ast (Expr_Lambda_Int lam)
 => Proxy lam
 -> ast
 -> Either (Error_of_Expr ast (Expr_Lambda_Int lam))
           (Exists_Type_and_Repr (Type_Root_of_Expr (Expr_Lambda_Int lam))
                                 (Forall_Repr (Expr_Lambda_Int lam)))
expr_lambda_int_from _px_lam ast =
	expr_from
	 (Proxy::Proxy (Expr_Lambda_Int lam))
	 Context_Empty ast $ \ty (Forall_Repr_with_Context repr) ->
		Right $ Exists_Type_and_Repr ty $
			Forall_Repr $ repr Context_Empty

-- * Type 'Error_Expr_Int'
data Error_Expr_Int ast
 =   Error_Expr_Int
 deriving (Eq, Show)