flake.nix

   1 {
   2 inputs.nixpkgs.url = "github:NixOS/nixpkgs/495b19d5b3e62b4ec7e846bdfb6ef3d9c3b83492";
   3 inputs.flake-utils.url = "github:numtide/flake-utils";
   4 inputs.home-manager.url = "github:nix-community/home-manager";
   5 inputs.home-manager.inputs.nixpkgs.follows = "nixpkgs";
   6 inputs.doom-emacs.url = "github:hlissner/doom-emacs";
   7 inputs.doom-emacs.flake = false;
   8 inputs.nix-doom-emacs.url = "github:vlaci/nix-doom-emacs";
   9 inputs.nix-doom-emacs.inputs.nixpkgs.follows = "nixpkgs";
  10 inputs.nix-doom-emacs.inputs.home-manager.follows = "home-manager";
  11 inputs.nix-doom-emacs.inputs.flake-utils.follows = "flake-utils";
  12 inputs.nix-doom-emacs.inputs.emacs-overlay.follows = "emacs-overlay";
  13 inputs.emacs-overlay.url = "github:nix-community/emacs-overlay/master";
  14 #inputs.pass = { type = "path"; path = "./pass"; flake = false; };
  15
  16 outputs = inputs: let
  17   remoteNixpkgsPatches = import nixpkgs/patches.nix;
  18   localNixpkgsPatches = [
  19   ];
  20   originPkgs = inputs.nixpkgs.legacyPackages."x86_64-linux";
  21   nixpkgsPath = originPkgs.applyPatches {
  22     name = "nixpkgs-patched";
  23     src = inputs.nixpkgs.outPath;
  24     patches = map originPkgs.fetchpatch remoteNixpkgsPatches ++ localNixpkgsPatches;
  25     postPatch = ''
  26       patch=$(printf '%s\n' ${builtins.concatStringsSep " "
  27          (map (p: p.sha256) remoteNixpkgsPatches ++ localNixpkgsPatches)} |
  28         sort | sha256sum | cut -c -7)
  29       echo "-patch-$patch" >.version-suffix
  30     '';
  31   };
  32   lib = originPkgs.lib;
  33   nixosSystem = import (nixpkgsPath + "/nixos/lib/eval-config.nix");
  34   #nixosSystem = inputs.nixpkgs.lib.nixosSystem;
  35   in {
  36   nixosConfigurations = lib.genAttrs
  37     (builtins.attrNames (lib.filterAttrs (n: v: v == "directory") (builtins.readDir ./hosts)))
  38     (hostName: nixosSystem rec {
  39       system = "x86_64-linux";
  40       specialArgs = {
  41         inherit hostName inputs;
  42         # Encrypted using git-crypt, hence kept out of /nix/store
  43         private = "/root/private";
  44         # Encrypted using systemd-creds, hence can go into the /nix/store
  45         credentials = private/hosts + "/${hostName}/credentials";
  46       };
  47       pkgs = import nixpkgsPath {
  48         inherit system;
  49         config.allowUnfree = true; # For hplip
  50         overlays = import nixpkgs/overlays.nix;
  51       };
  52       modules = [
  53         {
  54           config._module.args = {
  55             inherit hostName inputs;
  56             hosts = inputs.self.nixosConfigurations;
  57           };
  58         }
  59         (import (./hosts + "/${hostName}.nix"))
  60         inputs.nixpkgs.nixosModules.notDetected
  61         inputs.home-manager.nixosModules.home-manager
  62         ({ pkgs, ... }: {
  63           nix.registry.nixpkgs = lib.mkDefault { flake = inputs.nixpkgs; };
  64           nix.package = pkgs.nixFlakes;
  65           nix.extraOptions = "experimental-features = nix-command flakes";
  66           #nixpkgs.overlays = import nixpkgs/overlays.nix;
  67           /*
  68           system.nixos.versionSuffix = ".${
  69             lib.substring 0 8 (inputs.self.lastModifiedDate or inputs.self.lastModified)}.${
  70             inputs.self.shortRev or "dirty"}";
  71           system.nixos.revision = lib.mkIf (inputs.self ? rev) inputs.self.rev;
  72           */
  73           # Let 'nixos-version --json' know about the Git revision of this flake.
  74           system.configurationRevision = lib.mkIf (inputs.self ? rev) inputs.self.rev;
  75           /*
  76           system.configurationRevision =
  77             if inputs.self ? rev
  78             then inputs.self.rev
  79             else throw "Refusing to build from a dirty Git tree!";
  80           */
  81         })
  82         {
  83           home-manager.useGlobalPkgs = true;
  84           home-manager.useUserPackages = true;
  85           home-manager.verbose = true;
  86           home-manager.backupFileExtension = null;
  87           home-manager.extraSpecialArgs = {
  88             inherit hostName inputs;
  89           };
  90         }
  91       ];
  92     });
  93   } //
  94   inputs.flake-utils.lib.eachDefaultSystem (system:
  95     #let pkgs = inputs.nixpkgs.legacyPackages.${system}; in
  96     let
  97     pkgs = import nixpkgsPath {
  98       inherit system;
  99       config = {}; # Make the config pure, ignoring user's config.
 100       overlays = import nixpkgs/overlays.nix;
 101     }; in {
 102       devShell = import ./shell.nix { inherit pkgs inputs system; };
 103     }
 104   );
 105 }