flake.nix

   1 {
   2   /*
   3     nixConfig = {
   4     extra-substituters = [
   5       "https://nix-community.cachix.org"
   6     ];
   7     extra-trusted-public-keys = [
   8       "nix-community.cachix.org-1:mB9FSh9qf2dCimDSUo8Zy7bkq5CX+/rkCWyvRCYg3Fs="
   9     ];
  10     };
  11   */
  12
  13   inputs = {
  14     doom-emacs.flake = false;
  15     doom-emacs.url = "github:hlissner/doom-emacs";
  16     home-manager.inputs.nixpkgs.follows = "nixpkgs";
  17     home-manager.url = "github:nix-community/home-manager/release-24.05";
  18     nix-formatter-pack.inputs.nixpkgs.follows = "nixpkgs";
  19     nix-formatter-pack.url = "github:Gerschtli/nix-formatter-pack";
  20     nixpkgs.url = "github:NixOS/nixpkgs/nixos-24.05";
  21     git-hooks.inputs.nixpkgs.follows = "nixpkgs";
  22     git-hooks.inputs.nixpkgs-stable.follows = "nixpkgs";
  23     git-hooks.url = "github:cachix/git-hooks.nix";
  24   };
  25
  26   outputs = inputs:
  27     let
  28       remoteNixpkgsPatches = import nixpkgs/patches.nix;
  29       localNixpkgsPatches = [
  30       ];
  31       originPkgs = inputs.nixpkgs.legacyPackages."x86_64-linux";
  32       nixpkgsPath = originPkgs.applyPatches {
  33         name = "nixpkgs-patched";
  34         src = inputs.nixpkgs.outPath;
  35         patches = map originPkgs.fetchpatch remoteNixpkgsPatches ++ localNixpkgsPatches;
  36         postPatch = ''
  37           patch=$(printf '%s\n' ${builtins.concatStringsSep " "
  38              (map (p: p.sha256) remoteNixpkgsPatches ++ localNixpkgsPatches)} |
  39             sort | sha256sum | cut -c -7)
  40           echo "-patch-$patch" >.version-suffix
  41         '';
  42       };
  43       profile = "/nix/var/nix/profiles/system";
  44       inherit (inputs.nixpkgs) lib;
  45       overlays = system:
  46         import nixpkgs/overlays.nix ++ [
  47         ];
  48       #nixosSystem = lib.nixosSystem;
  49       nixosSystem = import (nixpkgsPath + "/nixos/lib/eval-config.nix");
  50       forAllSystems = f: lib.genAttrs lib.systems.flakeExposed (system: f rec {
  51         inherit system;
  52         #pkgs = inputs.nixpkgs.legacyPackages.${system};
  53         pkgs = import nixpkgsPath {
  54           inherit system;
  55           overlays = overlays system;
  56         };
  57       });
  58       self = with lib.fileset; toSource {
  59         root = ./.;
  60         fileset =
  61           let exts = [ "clear" "conf" "cred" "crt" "css" "el" "hs" "json" "nix" "patch" "pem" "pub" "sh" "theme" "vim" ]; in
  62           unions [
  63             (fileFilter (file: lib.any file.hasExt exts) ./home-manager)
  64             (fileFilter (file: lib.any file.hasExt exts) ./homes)
  65             (fileFilter (file: lib.any file.hasExt exts) ./hosts)
  66             (fileFilter (file: lib.any file.hasExt exts) ./nixos)
  67             (fileFilter (file: lib.any file.hasExt exts) ./nixpkgs)
  68             (fileFilter (file: lib.any file.hasExt exts) ./share)
  69             (fileFilter (file: lib.any file.hasExt exts) ./users)
  70             ./shell.nix
  71           ];
  72       };
  73     in
  74     rec {
  75       # nix -L build .#hello
  76       packages = forAllSystems ({ pkgs, ... }: pkgs);
  77
  78       # nix -L build .#nixosConfigurations.oignon.config.system.build.toplevel
  79       # nix -L build .#nixosConfigurations.oignon.config.boot.kernelPackages.kernel.configfile
  80       # nix -L build .#nixosConfigurations.oignon.pkgs.hello
  81       # nix eval --raw .#nixosConfigurations.oignon.config.networking.nftables.ruleset
  82       nixosConfigurations = lib.genAttrs
  83         (builtins.attrNames (lib.filterAttrs (_n: v: v == "directory") (builtins.readDir (self + "/hosts"))))
  84         (hostName: nixosSystem {
  85           system = null;
  86           specialArgs = {
  87             # Required to avoid infinite recursion
  88             # when `inputs` is used in `imports`.
  89             inherit inputs;
  90           };
  91           modules = [
  92             nixos/default.nix
  93             (import (self + "/hosts/${hostName}.nix"))
  94             ({ config, ... }: {
  95               _module.args = {
  96                 inherit hostName;
  97                 hosts = nixosConfigurations;
  98                 host = nixosConfigurations.${hostName}._module.args;
  99               };
 100               nixpkgs.overlays = overlays config.nixpkgs.hostPlatform.system;
 101               nixpkgs.config.allowUnfreePredicate = pkg: builtins.elem (lib.getName pkg) [
 102                 "anydesk"
 103                 "cudatoolkit"
 104                 "geogebra"
 105                 "hplip"
 106                 "memtest86-efi"
 107                 "nvidia-settings"
 108                 "nvidia-x11"
 109               ];
 110             })
 111             inputs.home-manager.nixosModules.home-manager
 112             {
 113               home-manager.useGlobalPkgs = true;
 114               home-manager.useUserPackages = true;
 115               home-manager.verbose = true;
 116               #home-manager.force = true;
 117               home-manager.backupFileExtension = "old";
 118               home-manager.extraSpecialArgs = {
 119                 inherit hostName inputs;
 120               };
 121             }
 122           ];
 123         });
 124
 125       # nix -L develop  or  direnv allow
 126       devShells = forAllSystems ({ pkgs, system, ... }:
 127         {
 128           default = pkgs.callPackage (self + "/shell.nix")
 129             {
 130               inherit pkgs inputs system nixpkgsPath;
 131               inherit (checks.${system}.git-hooks-check) shellHook;
 132             };
 133         }
 134       );
 135
 136       # nix -L run .#oignon.switch
 137       apps = forAllSystems ({ pkgs, system, ... }:
 138         with builtins;
 139         mapAttrs
 140           (hostName: { config, ... }:
 141             let
 142               inherit (config.system) build;
 143               scriptApp = scriptName: ps: script: {
 144                 type = "app";
 145                 program = (pkgs.writeShellScript "${hostName}-${scriptName}" ''
 146                   export PATH="${lib.makeBinPath ([ pkgs.coreutils ] ++ ps)}:$PATH"
 147                   set -eux
 148                   ${script}
 149                 '').outPath;
 150               };
 151             in
 152             {
 153               # Example: nix run .#aubergine.switch
 154               "switch" = scriptApp "switch" [ ] ''
 155                 shopt -s globstar
 156
 157                 chmod -R g-rwx,o-rwx **/*.gpg
 158                 trap 'git reset **/*.gpg' EXIT
 159                 git rm -rf --cached --ignore-unmatch **/*.gpg # prevent copying to /nix/store
 160
 161                 nix-store --add-root hosts/${hostName}.nixpkgs --indirect --realise ${nixpkgsPath}
 162                 nix-store --add-root hosts/${hostName}.root --indirect --realise ${build.toplevel}
 163
 164                 nix copy --to "ssh://${config.install.target}?''${targetStore-}"${lib.optionalString config.install.substituteOnDestination " --substitute-on-destination"} ${build.toplevel}
 165
 166                 if ssh ${config.install.target} set -x ';' \
 167                   systemctl reset-failed nixos-fallback '2>/dev/null' ';' \
 168                   test "''${NO_NIXOS_FALLBACK:+set}" '||' \
 169                   systemd-run -u nixos-fallback --description=nixos-fallback /bin/sh -xc '''\'''
 170                     PATH=${with pkgs; lib.makeBinPath [ coreutils nix systemd ]}
 171                     sleep $((10 * 60))
 172                     ${profile}/bin/switch-to-configuration switch
 173                     systemctl reboot
 174                   '\'''' '&&' \
 175                   ${build.toplevel}/bin/switch-to-configuration test
 176                 then
 177                   ssh ${config.install.target} -o ControlPath=none set -x ';' \
 178                     systemctl stop nixos-fallback.service ';' \
 179                     nix-env --profile ${profile} --set '${build.toplevel}' ';' \
 180                     ${build.toplevel}/bin/switch-to-configuration boot '&&' \
 181                     nix-env --delete-generations 7d --profile ${profile}
 182                 else
 183                   tput rev
 184                   echo WARNING: switch-to-configuration was not registered at boot
 185                   tput sgr0
 186                   ssh ${config.install.target} -o ControlPath=none set -x ';' \
 187                     systemctl stop nixos-fallback.service
 188                   false
 189                 fi
 190               '';
 191             })
 192           nixosConfigurations);
 193
 194       # nix flake check
 195       checks = forAllSystems (args: with args; {
 196         git-hooks-check = inputs.git-hooks.lib.${system}.run {
 197           src = self;
 198           hooks = {
 199             nixpkgs-fmt.enable = true;
 200           };
 201         };
 202       });
 203
 204       # nix fmt
 205       formatter = forAllSystems ({ pkgs, ... }:
 206         inputs.nix-formatter-pack.lib.mkFormatter {
 207           inherit pkgs;
 208           config = {
 209             tools = {
 210               deadnix.enable = true;
 211               nixpkgs-fmt.enable = true;
 212               statix.enable = true;
 213             };
 214           };
 215         }
 216       );
 217     };
 218 }