{ pkgs, lib, config, hostName, ... }:
{
imports = [
  ./softwares.nix
  ./options.nix
  julm/mutt.nix
  (import (julm/hosts + "/${hostName}.nix"))
];
programs.firefox = {
  profiles =
    let defaultProfile = {
      settings = {
        "browser.bookmarks.showMobileBookmarks" = true;
        "browser.compactmode.show" = true;
        "browser.search.isUS" = false;
        "browser.search.region" = "FR";
        "distribution.searchplugins.defaultLocale" = "fr-FR";
        "general.useragent.locale" = "fr-FR";
        "security.identityblock.show_extended_validation" = true;
        "toolkit.legacyUserProfileCustomizations.stylesheets" = true;
      };
      userChrome = builtins.readFile softwares/firefox/userChrome.css;
    }; in {
      "rp4xy6ye.2021" = lib.mkMerge [defaultProfile {
        id = 0;
        name = "2021";
        settings = {
          "browser.startup.homepage" = "https://code.sourcephile.fr";
        };
      }];
      "8y3d28fa.tor" = lib.mkMerge [defaultProfile {
        id = 1;
        name = "tor";
        settings = {
          "browser.startup.homepage" = "https://check.torproject.org";
        };
      }];
    };
};
home.file."${config.programs.gpg.homedir}/gpg.conf".text = ''
  # julm@autogeree.net
  trusted-key 0xD15AF7F467E8299B
  # julm@sourcephile.fr (2021-08-12)
  trusted-key 0xA58CD81C3863926F
'';
services.gpg-agent.sshKeys = [
  # julm@autogeree.net
  "D275EBA09C7E1FFBFB47F6EEF164E6D56FB24AB2"
  # julm@sourcephile.fr (2021-08-12)
  "3D94D14514F1EA2B6D62F1275D888897B082415D"
];
programs.irssi.extraConfig = builtins.readFile julm/irssi/config;
home.file.".irssi/passwd".text = ''
  FreeNode   : ${pkgs.pass}/bin/pass freenode.net/irc/julm
  GeekNode   : ${pkgs.pass}/bin/pass geeknode.org/irc/julm
  IndyMedia  : ${pkgs.pass}/bin/pass indymedia.org/irc/julm
  Libera     : ${pkgs.pass}/bin/pass libera.chat/irc/julm
  OFTC       : ${pkgs.pass}/bin/pass oftc.net/irc/julm
  ToileLibre : ${pkgs.pass}/bin/pass toile-libre.org/irc/julm
'';
programs.ssh.matchBlocks = lib.genAttrs ["lan.losurdo.sourcephile.fr" "losurdo.wg"] (_: {
  compression = true; # Helps to get a better framerate with forwardX11
  forwardX11 = true;
  forwardX11Trusted = true;
  serverAliveInterval = 15;
});
programs.git = {
  userName = "Julien Moutinho";
  userEmail = "julm@sourcephile.fr";
  signing.key = "0x7182433A39582282929B2A222E3618DD0D087650";
  signing.signByDefault = false;
  package =
    if lib.elem hostName [ "losurdo" "oignon" ]
    then pkgs.gitFull
    else pkgs.gitMinimal;
  extraConfig = {
    sendemail.smtpEncryption = "ssl"; # Yes, "ssl", not "tls" which does not work because it expects STARTTLS.
    sendemail.smtpServer = "mail.sourcephile.fr";
    sendemail.smtpServerPort = "465";
    sendemail.smtpUser = "julm@sourcephile.fr";
  };
};
home.stateVersion = "20.09";
home.sessionPath = [ "${config.home.homeDirectory}/bin" ];
home.sessionVariables = {
  EDITOR = "vim";
  LANG = "fr_FR.UTF-8";
  LESS = "-FRSX";
  LOCALE_ARCHIVE = "${pkgs.glibcLocales}/lib/locale/locale-archive";
  MANPAGER = "less";
};
}