{
inputs.nixpkgs.url = "github:NixOS/nixpkgs/32096899af23d49010bd8cf6a91695888d9d9e73";
inputs.home-manager.url = "github:nix-community/home-manager";
inputs.home-manager.inputs.nixpkgs.follows = "nixpkgs";
inputs.doom-emacs.url = "github:hlissner/doom-emacs";
inputs.doom-emacs.flake = false;
/*
inputs.nix-doom-emacs.url = "github:vlaci/nix-doom-emacs";
inputs.nix-doom-emacs.inputs.nixpkgs.follows = "nixpkgs";
inputs.nix-doom-emacs.inputs.home-manager.follows = "home-manager";
inputs.nix-doom-emacs.inputs.flake-utils.follows = "flake-utils";
inputs.nix-doom-emacs.inputs.emacs-overlay.follows = "emacs-overlay";
inputs.emacs-overlay.url = "github:nix-community/emacs-overlay/master";
*/
#inputs.pass = { type = "path"; path = "./pass"; flake = false; };

outputs = inputs: let
  remoteNixpkgsPatches = import nixpkgs/patches.nix;
  localNixpkgsPatches = [
  ];
  originPkgs = inputs.nixpkgs.legacyPackages."x86_64-linux";
  nixpkgsPath = originPkgs.applyPatches {
    name = "nixpkgs-patched";
    src = inputs.nixpkgs.outPath;
    patches = map originPkgs.fetchpatch remoteNixpkgsPatches ++ localNixpkgsPatches;
    postPatch = ''
      patch=$(printf '%s\n' ${builtins.concatStringsSep " "
         (map (p: p.sha256) remoteNixpkgsPatches ++ localNixpkgsPatches)} |
        sort | sha256sum | cut -c -7)
      echo "-patch-$patch" >.version-suffix
    '';
  };
  lib = inputs.nixpkgs.lib;
  profile = "/nix/var/nix/profiles/system";
  forAllSystems = f: lib.genAttrs lib.systems.flakeExposed (system: f rec {
    inherit system;
    #pkgs = inputs.nixpkgs.legacyPackages.${system};
    pkgs = pkgsForSystem system;
  });
  pkgsForSystem = system: import nixpkgsPath {
    inherit system;
    config = {
      allowUnfree = true; # For hplip
    };
    overlays = import nixpkgs/overlays.nix;
  };
  nixosSystem = import (nixpkgsPath + "/nixos/lib/eval-config.nix");
  #nixosSystem = inputs.nixpkgs.lib.nixosSystem;
  in {
    nixosConfigurations = lib.genAttrs
      (builtins.attrNames (lib.filterAttrs (n: v: v == "directory") (builtins.readDir ./hosts)))
      (hostName: nixosSystem {
        system = "x86_64-linux";
        pkgs = pkgsForSystem "x86_64-linux";
        specialArgs = {
          inherit hostName inputs;
        };
        modules = [
          {
            config._module.args = {
              inherit hostName inputs;
              hosts = inputs.self.nixosConfigurations;
            };
          }
          (import nixos/modules.nix)
          (import nixos/options.nix)
          (import (./hosts + "/${hostName}.nix"))
          inputs.nixpkgs.nixosModules.notDetected
          inputs.home-manager.nixosModules.home-manager
          ({ pkgs, ... }: {
            nix.registry.nixpkgs = lib.mkDefault { flake = inputs.nixpkgs; };
            nix.package = pkgs.nixFlakes;
            nix.extraOptions = "experimental-features = nix-command flakes";
            #nixpkgs.overlays = import nixpkgs/overlays.nix;
            /*
            system.nixos.versionSuffix = ".${
              lib.substring 0 8 (inputs.self.lastModifiedDate or inputs.self.lastModified)}.${
              inputs.self.shortRev or "dirty"}";
            system.nixos.revision = lib.mkIf (inputs.self ? rev) inputs.self.rev;
            */
            # Let 'nixos-version --json' know about the Git revision of this flake.
            system.configurationRevision = lib.mkIf (inputs.self ? rev) inputs.self.rev;
            /*
            system.configurationRevision =
              if inputs.self ? rev
              then inputs.self.rev
              else throw "Refusing to build from a dirty Git tree!";
            */
          })
          {
            home-manager.useGlobalPkgs = true;
            home-manager.useUserPackages = true;
            home-manager.verbose = true;
            home-manager.backupFileExtension = null;
            home-manager.extraSpecialArgs = {
              inherit hostName inputs;
            };
          }
        ];
      });
    # nix -L develop  or  direnv allow
    devShell = forAllSystems ({ pkgs, system, ... }: pkgs.callPackage ./shell.nix
      {
        inherit pkgs inputs system nixpkgsPath;
        #inherit (checks.${system}.pre-commit-check) shellHook;
      });
    # nix -L run .#oignon.switch
    apps = forAllSystems ({ pkgs, system, ... }:
      with builtins;
      mapAttrs (hostName: { config, ... }:
        let
          build = config.system.build;
          target = "\"\${TARGET:-root@${config.networking.hostName}.${config.networking.domain}}\"";
          scriptApp = scriptName: ps: script: {
            type = "app";
            program = (pkgs.writeShellScript "${hostName}-${scriptName}" ''
              export PATH="${lib.makeBinPath ([ pkgs.coreutils ] ++ ps)}:$PATH"
              set -eux
              ${script}
            '').outPath;
          };
        in rec {
        # Example: nix run .#aubergine.switch
        "switch" = scriptApp "switch" [] ''
          shopt -s globstar

          chmod -R g-rwx,o-rwx **/*.gpg
          trap 'git reset **/*.gpg' EXIT
          git rm -rf --cached --ignore-unmatch **/*.gpg # prevent copying to /nix/store

          nix-store --add-root hosts/${hostName}.nixpkgs --indirect --realise ${nixpkgsPath}
          nix-store --add-root hosts/${hostName}.root --indirect --realise ${build.toplevel}

          nix copy --to ssh://${target}${lib.optionalString config.install.substituteOnDestination " --substitute-on-destination"} ${build.toplevel}

          ssh ${target} set -x ';' \
            systemctl reset-failed nixos-fallback '2>/dev/null' ';' \
            systemd-run -u nixos-fallback --description=nixos-fallback /bin/sh -xc '''\'''
              PATH=${with pkgs; lib.makeBinPath [ coreutils nix systemd ]}
              fallback=$(realpath -e ${profile})
              sleep $((10 * 60))
              nix-env --profile ${profile} --set $fallback
              $fallback/bin/switch-to-configuration switch
              systemctl reboot
            '\'''' '&&' \
            ${profile}/bin/switch-to-configuration test

          ssh ${target} -o ControlPath=none set -x ';' \
            systemctl stop nixos-fallback.service ';' \
            nix-env --profile ${profile} --set '${build.toplevel}' ';' \
            ${profile}/bin/switch-to-configuration boot '&&' \
            nix-env --delete-generations 7d --profile ${profile}
        '';
      }) inputs.self.nixosConfigurations);
  };
}