{ config, pkgs, lib, inputs, hostName, ... }:
let inherit (config.users) users; in
{
imports = [
  ../profiles/dnscrypt-proxy2.nix
  oignon/hardware.nix
  oignon/tor.nix
];

home-manager.users.julm = {
  imports = [ ../homes/julm.nix ];
  host.name = hostName;
  host.hardware = ["ThinkPad" "X201"];
};
systemd.services.home-manager-julm.postStart = ''
  ${pkgs.nix}/bin/nix-env --delete-generations +1 --profile /nix/var/nix/profiles/per-user/julm/home-manager
'';
users.mutableUsers = false;
users.users.julm = {
  isNormalUser = true;
  uid = 1000;
  # Put the hashedPassword in /nix/store, but it will also be in /etc/passwd
  # which is already world readable.
  hashedPassword = lib.readFile ../secrets/julm/hashedPassword;
  extraGroups = [
    "adbusers"
    "lp"
    "networkmanager"
    "scanner"
    "tor"
    "video"
    "wheel"
    "networkmanager"
    #"vboxusers"
  ];
  # If created, zfs-mount.service would require:
  # zfs set overlay=yes ${hostName}/home
  createHome = false;
};

nix = {
  extraOptions = ''
    auto-optimise-store = true
  '';
  gc = {
    automatic = true;
    dates = "weekly";
    options = "--delete-older-than 7d";
  };
  nixPath = [
    "nixpkgs=/etc/nixpkgs"
    "nixpkgs-overlays=/etc/nixpkgs-overlays/overlays.nix"
  ];
  trustedUsers = [ users.julm.name ];
};
environment.etc."nixpkgs".source = pkgs.path;
environment.etc."nixpkgs-overlays".source = inputs.self + "/nixpkgs";

nixpkgs.config = {
  allowUnfree = true;
};
documentation.nixos.enable = true;
time.timeZone = "Europe/Paris";
i18n.defaultLocale = "fr_FR.UTF-8";
console.font = "Lat2-Terminus16";
console.keyMap = "fr";

networking = {
  hostName = hostName;
  domain = "localdomain";
  search = [ "sourcephile.fr" ];
  networkmanager = {
    enable = true;
    #dhcp = "dhcpcd";
    logLevel = "INFO";
    wifi = {
      #backend = "iwd";
      #backend = "wpa_supplicant";
      powersave = false;
    };
  };
  firewall = {
    enable = true;
  };
};

sound.enable = true;
hardware.pulseaudio.enable = true;
hardware.sane.enable = true;
hardware.sane.extraBackends = [ pkgs.hplipWithPlugin ];

environment.variables = {
  EDITOR = "vim";
  PAGER  = "less -R";
  SYSTEMD_LESS = "FKMRX";
};

programs = {
  bash = {
    interactiveShellInit = ''
      bind '"\e[A":history-search-backward'
      bind '"\e[B":history-search-forward'

      # Ignore duplicate commands, ignore commands starting with a space
      export HISTCONTROL=erasedups:ignorespace
      export HISTSIZE=42000
      # Append to the history instead of overwriting (good for multiple connections)
      shopt -s histappend

      # Utilities
      mkcd () { mkdir -p "$1"; cd "$1"; }
      fan () {
        if [ $# -gt 0 ]
        then sudo tee /proc/acpi/ibm/fan <<<"level $1"
        else grep '^\(level\|speed\):' /proc/acpi/ibm/fan
        fi
        acpi -t
      }
    '';
    shellAliases = {
      cl = "clear";
      grep = "grep --color";
      l  = "ls -alh";
      ll = "ls -al";
      ls = "ls --color=tty";
      mem = "ps -e -orss=,user=,args= | sort -b -k1,1n";

      s="sudo systemctl";
      st="sudo systemctl status";
      u="systemctl --user";
      j="sudo journalctl -u";
      jb="sudo journalctl -b";

      nix-history="sudo nix-env --list-generations --profile /nix/var/nix/profiles/system";
      mv = "mv -i";
      sshfs = "sshfs -o ServerAliveInterval=15 -o reconnect -f";
    };
  };
  dconf.enable = true;
  mtr.enable = true;
};

services = {
  avahi = {
    enable  = true;
    nssmdns = true;
  };
  dbus = {
    packages = [ pkgs.gnome3.dconf ];
  };
  gvfs = {
    enable = true;
  };
  journald = {
    extraConfig = ''
      Compress=true
      MaxRetentionSec=1month
      Storage=persistent
      SystemMaxUse=100M
    '';
  };
  printing = {
    enable = true;
    drivers = [
      pkgs.gutenprint
      pkgs.hplip
    ];
  };
  sanoid = {
    enable = true;
    extraArgs = [ "--verbose" ];
    datasets = {
      "${hostName}/home" = {
        autosnap = true;
        autoprune = true;
        hourly = 12;
        daily = 7;
        monthly = 0;
        yearly = 0;
        recursive = true;
      };
      "${hostName}/var" = {
        autosnap = true;
        autoprune = true;
        hourly = 12;
        daily = 7;
        monthly = 0;
        yearly = 0;
        recursive = true;
      };
    };
  };
  udev = {
    packages = [
      # Allow members of the "adbusers" group to mount Android devices via MTP
      pkgs.android-udev-rules
    ];
  };
  xserver = {
    enable = true;
    layout = "fr";
    xkbOptions = "eurosign:e";
    libinput.enable = true;
    desktopManager = {
      session = [
        # Let the session be generated by home-manager
        { name = "home-manager";
          start = ''
            ${pkgs.runtimeShell} $HOME/.hm-xsession &
            waitPID=$!
          '';
        }
      ];
    };
    displayManager = {
      defaultSession = "home-manager";
      #defaultSession = "none+xmonad";
      autoLogin = {
        enable = true;
        user = users.julm.name;
      };
    };
  };
};

# This value determines the NixOS release with which your system is to be
# compatible, in order to avoid breaking some software such as database
# servers. You should change this only after NixOS release notes say you should.
system.stateVersion = "20.09"; # Did you read the comment?
}