{ config, pkgs, lib, hostName, ... }:
with lib;
{
  imports = [
    networking/nftables.nix
  ];

  boot.kernel.sysctl = {
    # Improve MTU detection
    # This can thaw TCP connections stalled by a host
    # requiring a lower MTU along the path,
    # though it would do so after a little delay
    # so it's better to set a low MTU when possible.
    "net/ipv4/tcp_mtu_probing" = 1;
  };

  networking = {
    inherit hostName;
    domain = mkDefault "wg";
    #search = [ "sourcephile.fr" ];
    firewall = {
      enable = mkDefault true;
      allowPing = mkDefault true;
    };
    networkmanager = {
      enable = mkDefault config.services.xserver.enable;
      #dhcp = "dhcpcd";
      logLevel = mkDefault "INFO";
      wifi = {
        #backend = "iwd";
        #backend = "wpa_supplicant";
        powersave = mkDefault false;
      };
    };
    usePredictableInterfaceNames = true;
  };

  programs.mtr.enable = true;
  programs.traceroute.enable = mkDefault true;
  programs.usbtop.enable = true;

  services.avahi = {
    nssmdns = mkDefault true;
    openFirewall = mkDefault false;
    publish.enable = mkDefault false;
  };
  networking.nftables.ruleset = mkIf config.services.avahi.enable (''
    table inet filter {
      chain output-lan {
        skuid root udp sport mdns udp dport mdns comment "avahi: multicast DNS"
      }
    }
  '' + optionalString config.services.avahi.openFirewall ''
    table inet filter {
      chain input-lan {
        udp dport mdns comment "avahi: multicast DNS"
      }
    }
  '');

  services.openssh = {
    enable = mkDefault true;
    forwardX11 = mkDefault true;
    openFirewall = mkDefault false;
  };

  # Fix https://github.com/NixOS/nixpkgs/issues/180175 by removing -s (aka. --wait-for-startup)
  systemd.services.NetworkManager-wait-online = {
    serviceConfig.ExecStart = [ "" "${pkgs.networkmanager}/bin/nm-online -q" ];
  };
  environment.etc."NetworkManager/dispatcher.d/congctl" = {
    mode = "700";
    source = pkgs.writeShellScript "congctl" ''
      case $NM_DISPATCHER_ACTION in
        up)
          case $DEVICE_IP_IFACE in
            # WLAN or WWAN
            # https://en.wikipedia.org/wiki/TCP_congestion_control#TCP_Westwood+
            wl*|ww*)
              ip route show dev $DEVICE_IP_IFACE |
              while read -r route; do
                ip route change $route dev $DEVICE_IP_IFACE congctl westwood
              done
            ;;
          esac
        ;;
      esac
    '';
  };
}