{ pkgs, lib, hostName, ... }:
{
  # none is the recommended elevator with ZFS (which has its own I/O scheduler)
  # and/or for SSD, whereas HDD could use mq-deadline.
  services.udev.extraRules = ''
    ACTION=="add|change", KERNEL=="sd[a-z]*[0-9]*|mmcblk[0-9]*p[0-9]*|nvme[0-9]*n[0-9]*p[0-9]*", ENV{ID_FS_TYPE}=="zfs_member", ATTR{../queue/scheduler}="none"
    ACTION=="add|change", KERNEL=="sd[a-z][0-9]*", ATTR{../queue/rotational}=="0", ATTR{../queue/scheduler}="none"
    ACTION=="add|change", KERNEL=="nvme[0-9]*n[0-9]*p[0-9]*", ATTR{../queue/rotational}=="0", ATTR{../queue/scheduler}="none"
  '';

  boot.supportedFilesystems = [ "zfs" ];
  boot.initrd.supportedFilesystems = [ "zfs" ];

  # Using ZFS together with hibernation (suspend to disk)
  # may cause filesystem corruption.
  # See https://github.com/openzfs/zfs/issues/260
  boot.kernelParams = [ "nohibernate" ];

  # Stable enough, clearer, and faster than the default /dev/disk/by-id
  boot.zfs.devNodes = "/dev/disk/by-partlabel";
  # Not useful so far.
  boot.zfs.forceImportAll = false;
  # More resilient for remote hosts,
  # though it may call zpool clear.
  boot.zfs.forceImportRoot = true;
  boot.zfs.requestEncryptionCredentials = lib.mkDefault [ "${hostName}/root" ];

  boot.zfs.enableUnstable = false;

  # Enables periodic scrubbing of ZFS pools.
  services.zfs.autoScrub.enable = true;
  services.zfs.autoScrub.interval = "Sun *-*-08..14 00:15:00";

  # According to zpool(8), for consumer hardware
  # periodic manual TRIM is preferred over the automatic TRIM
  # that ZFS implements.
  services.zfs.trim.enable = true;
  services.zfs.trim.interval = "Sun *-*-01..07 00:15:00";

  environment.systemPackages = [
    pkgs.lzop # For remote syncoid
    pkgs.mbuffer # For remote syncoid
    pkgs.sanoid
  ];
}