{
inputs.nixpkgs.url = "github:NixOS/nixpkgs/495b19d5b3e62b4ec7e846bdfb6ef3d9c3b83492";
inputs.flake-utils.url = "github:numtide/flake-utils";
inputs.home-manager.url = "github:nix-community/home-manager";
inputs.home-manager.inputs.nixpkgs.follows = "nixpkgs";
inputs.doom-emacs.url = "github:hlissner/doom-emacs";
inputs.doom-emacs.flake = false;
inputs.nix-doom-emacs.url = "github:vlaci/nix-doom-emacs";
inputs.nix-doom-emacs.inputs.nixpkgs.follows = "nixpkgs";
inputs.nix-doom-emacs.inputs.home-manager.follows = "home-manager";
inputs.nix-doom-emacs.inputs.flake-utils.follows = "flake-utils";
inputs.nix-doom-emacs.inputs.emacs-overlay.follows = "emacs-overlay";
inputs.emacs-overlay.url = "github:nix-community/emacs-overlay/master";
#inputs.pass = { type = "path"; path = "./pass"; flake = false; };

outputs = inputs: let
  remoteNixpkgsPatches = import nixpkgs/patches.nix;
  localNixpkgsPatches = [
  ];
  originPkgs = inputs.nixpkgs.legacyPackages."x86_64-linux";
  nixpkgsPath = originPkgs.applyPatches {
    name = "nixpkgs-patched";
    src = inputs.nixpkgs.outPath;
    patches = map originPkgs.fetchpatch remoteNixpkgsPatches ++ localNixpkgsPatches;
    postPatch = ''
      patch=$(printf '%s\n' ${builtins.concatStringsSep " "
         (map (p: p.sha256) remoteNixpkgsPatches ++ localNixpkgsPatches)} |
        sort | sha256sum | cut -c -7)
      echo "-patch-$patch" >.version-suffix
    '';
  };
  lib = originPkgs.lib;
  nixosSystem = import (nixpkgsPath + "/nixos/lib/eval-config.nix");
  #nixosSystem = inputs.nixpkgs.lib.nixosSystem;
  in {
  nixosConfigurations = lib.genAttrs
    (builtins.attrNames (lib.filterAttrs (n: v: v == "directory") (builtins.readDir ./hosts)))
    (hostName: nixosSystem rec {
      system = "x86_64-linux";
      specialArgs = {
        inherit hostName inputs;
      };
      pkgs = import nixpkgsPath {
        inherit system;
        config.allowUnfree = true; # For hplip
        overlays = import nixpkgs/overlays.nix;
      };
      modules = [
        {
          config._module.args = {
            inherit hostName inputs;
            hosts = inputs.self.nixosConfigurations;
          };
        }
        (import nixos/options.nix)
        (import (./hosts + "/${hostName}.nix"))
        inputs.nixpkgs.nixosModules.notDetected
        inputs.home-manager.nixosModules.home-manager
        ({ pkgs, ... }: {
          nix.registry.nixpkgs = lib.mkDefault { flake = inputs.nixpkgs; };
          nix.package = pkgs.nixFlakes;
          nix.extraOptions = "experimental-features = nix-command flakes";
          #nixpkgs.overlays = import nixpkgs/overlays.nix;
          /*
          system.nixos.versionSuffix = ".${
            lib.substring 0 8 (inputs.self.lastModifiedDate or inputs.self.lastModified)}.${
            inputs.self.shortRev or "dirty"}";
          system.nixos.revision = lib.mkIf (inputs.self ? rev) inputs.self.rev;
          */
          # Let 'nixos-version --json' know about the Git revision of this flake.
          system.configurationRevision = lib.mkIf (inputs.self ? rev) inputs.self.rev;
          /*
          system.configurationRevision =
            if inputs.self ? rev
            then inputs.self.rev
            else throw "Refusing to build from a dirty Git tree!";
          */
        })
        {
          home-manager.useGlobalPkgs = true;
          home-manager.useUserPackages = true;
          home-manager.verbose = true;
          home-manager.backupFileExtension = null;
          home-manager.extraSpecialArgs = {
            inherit hostName inputs;
          };
        }
      ];
    });
  } //
  inputs.flake-utils.lib.eachDefaultSystem (system:
    #let pkgs = inputs.nixpkgs.legacyPackages.${system}; in
    let
    pkgs = import nixpkgsPath {
      inherit system;
      config = {}; # Make the config pure, ignoring user's config.
      overlays = import nixpkgs/overlays.nix;
    }; in {
      devShell = import ./shell.nix { inherit pkgs inputs system nixpkgsPath; };
      apps = builtins.mapAttrs (hostName: { config, ... }: let
        build = config.system.build;
        target = "\"\${TARGET:-root@${config.networking.hostName}.${config.networking.domain}}\"";
        profile = "/nix/var/nix/profiles/system";
        in rec {
        # Example: nix run .#aubergine.switch
        "switch" = {
          type = "app";
          program = (pkgs.writeShellScript "switch" (''
            set -eux
            set -o pipefail
            shopt -s globstar
            chmod -R g-rwx,o-rwx **/*.gpg
            trap 'git reset **/*.gpg' EXIT
            git rm -rf --cached --ignore-unmatch **/*.gpg # prevent copying to /nix/store

            nix-store --add-root hosts/${hostName}.nixpkgs --indirect --realise ${nixpkgsPath}
            nix-store --add-root hosts/${hostName}.root --indirect --realise ${build.toplevel}
            nix copy --to ssh://${target}${lib.optionalString config.install.substituteOnDestination " --substitute-on-destination"} ${build.toplevel}
            ssh ${target} systemctl start nixos-fallback.service ';' \
              nix-env --profile ${profile} --set '${build.toplevel}' '&&' \
              ${profile}/bin/switch-to-configuration test
            ssh ${target} -o ControlPath=none \
              systemctl stop nixos-fallback.service ';' \
              ${profile}/bin/switch-to-configuration boot '&&' \
              nix-env --delete-generations 7d --profile ${profile}
            ''
          )).outPath;
        };
      }) inputs.self.nixosConfigurations;
    }
  );
}