{
  inputs = {
    nixpkgs.url = "flake:nixpkgs";
    git-hooks.url = "github:cachix/git-hooks.nix";
    git-hooks.inputs.nixpkgs.follows = "nixpkgs";
    logic.url = "git+https://radicle-mermet.sourcephile.fr/z3795BqJN8hSMGkyAUr8hHviEEi2H.git";
  };
  outputs = inputs:
    let
      pkg = "literate-phylomemy";
      lib = inputs.nixpkgs.lib;
      fileInputs = with lib.fileset; toSource {
        root = ./.;
        fileset = unions [
          ./literate-phylomemy.cabal
          ./ChangeLog.md
          ./Readme.md
          ./LICENSES
          (fileFilter (file: lib.any file.hasExt [ "hs" ]) ./src)
          (fileFilter (file: lib.any file.hasExt [ "hs" "golden" ]) ./tests)
        ];
      };
      perSystem = f: lib.genAttrs lib.systems.flakeExposed (system: f rec {
        inherit system;
        pkgs = inputs.nixpkgs.legacyPackages.${system};
        haskellPackages = pkgs.haskellPackages.extend (with pkgs.haskell.lib; finalHaskellPkgs: previousHaskellPkgs: {
          ${pkg} = buildFromSdist (finalHaskellPkgs.callCabal2nix pkg fileInputs { });
          logic = finalHaskellPkgs.callCabal2nix "logic" inputs.logic { };
        });
      });
    in
    rec {
      # nix -L build
      packages = perSystem ({ haskellPackages, ... }: {
        default = haskellPackages.${pkg};
      });
      # nix -L develop  or  direnv allow
      devShells = perSystem ({ pkgs, haskellPackages, system, ... }: {
        default =
          haskellPackages.shellFor {
            packages = ps: [ ps.${pkg} ];
            nativeBuildInputs = [
              haskellPackages.cabal-fmt
              haskellPackages.cabal-install
              haskellPackages.ghcid
              haskellPackages.haskell-language-server
              haskellPackages.hlint
              pkgs.git-chglog
              pkgs.reuse
            ];
            withHoogle = false;
            inherit (checks.${system}.git-hooks-check) shellHook;
          };
      });
      # nix flake check
      checks = perSystem (args: with args; {
        git-hooks-check = inputs.git-hooks.lib.${system}.run {
          src = ./.;
          hooks = {
            cabal-fmt.enable = true;
            fourmolu.enable = true;
            hlint.enable = true;
            nixpkgs-fmt.enable = true;
            ormolu.settings.cabalDefaultExtensions = true;
            reuse = {
              enable = true;
              entry = "${pkgs.reuse}/bin/reuse lint";
              pass_filenames = false;
            };
          };
        };
      });
    };
}