shell.nix

   1 let
   2   nixpkgs_channel = builtins.getEnv "nixpkgs_channel";
   3   originNixpkgs = import (.config/nixpkgs-channel + ("/" + nixpkgs_channel + ".nix"));
   4   originPkgs = import originNixpkgs {
   5     config   = {}; # Make the config pure, ignoring user's config.
   6     overlays = [];
   7   };
   8   remoteNixpkgsPatches = [
   9     /*
  10     { meta.description = "nsd : use types.lines where appropriate";
  11       url = "https://github.com/NixOS/nixpkgs/pull/78968.diff";
  12       sha256 = "11bqq1g1ax6i7xghihyhklmqpsq3njalardp6nvzphkjgxrypb47";
  13     }
  14     { meta.description = "shorewall: init at 5.2.3.3";
  15       url = "https://github.com/NixOS/nixpkgs/pull/46131.diff";
  16       sha256 = "0mfzlcr23ni5spnwksmmls50sw10alqbr5j6hjrwp9i30z0419yx";
  17     }
  18     */
  19     { meta.description = "Dovecot plugin for Full Text Search (FTS) with Xapian";
  20       url = "https://github.com/NixOS/nixpkgs/pull/78780.diff";
  21       sha256 = "15ix8kwisjcgf4n7x7vlh223rb3206lcd5b13wbcvld07rzinjkc";
  22     }
  23     /* Disabled because it triggers the local build of too many reverse-dependencies
  24     { meta.description = "openldap: enable sha2 and pbkdf2 modules";
  25       url = "https://github.com/NixOS/nixpkgs/pull/79286.diff";
  26       sha256 = "0y255x74qksqy7fm4bdwlknhm3s55vgfgbv4dd7580p4lcavya0m";
  27     }
  28     */
  29     /*
  30     { meta.description = "Replace simp-le with lego and support DNS-01 challenge";
  31       url = "https://github.com/NixOS/nixpkgs/pull/77578.diff";
  32       sha256 = "15zs2146zh54jg1gywrcwyqxpx7izc35vlakk3cvrlqwwsvlr2rf";
  33     }
  34     */
  35     { meta.description = "dstat: fix pluginpath";
  36       url = "https://github.com/NixOS/nixpkgs/pull/80151.diff";
  37       sha256 = "0jjw2gvp7b7v2n2m2d6yj0gw711j6p9lyjf5ywp2y9ql6905qf4b";
  38     }
  39     /*
  40     { meta.description = "shorewall: fix warnings due to types.loaOf being deprecated";
  41       url = "https://github.com/NixOS/nixpkgs/pull/80154.diff";
  42       sha256 = "0b216m1rib3jl6s3r5cbkd5h1bfhppikg4cz9ayr1fspsflr3bci";
  43     }
  44     { meta.description = "shorewall: fix RestartTriggers";
  45       url = "https://github.com/NixOS/nixpkgs/pull/81774.diff";
  46       sha256 = "14drpym2mq9gq505psjzqq23gv0wkbwrrvh438h5jirzcym3467a";
  47     }
  48     */
  49   ];
  50   localNixpkgsPatches = [
  51     patches/direnv.diff
  52     patches/syncoid.diff
  53   ];
  54   nixpkgs = originPkgs.applyPatches {
  55     name = "nixpkgs-patched";
  56     src = originNixpkgs;
  57     patches = map originPkgs.fetchpatch remoteNixpkgsPatches ++ localNixpkgsPatches;
  58     postPatch = ''
  59       patch=$(printf '%s\n' ${builtins.concatStringsSep " "
  60          (map (p: p.sha256) remoteNixpkgsPatches ++ localNixpkgsPatches)} |
  61         sort | sha256sum | cut -c -7)
  62       echo "+patch-$patch" >.version-suffix
  63     '';
  64   };
  65   pkgs = import nixpkgs {
  66     config = {}; # Make the config pure, ignoring user's config.
  67     overlays = import ./overlays.nix;
  68   };
  69
  70   lib = pkgs.lib;
  71   nixos = pkgs.nixos {};
  72   # Configuration of shell/modules/
  73   configuration = {config, ...}: {
  74     imports = [
  75     ];
  76     nix = {
  77       nixConf = ''
  78         auto-optimise-store = true
  79       '';
  80     };
  81     nix-plugins = {
  82       enable = true;
  83     };
  84     gnupg = {
  85       enable = true;
  86       gnupgHome = toString ../sec/gnupg;
  87       keys = import shell/openpgp.nix;
  88       gpgExtraConf = ''
  89         # julm@sourcephile.fr
  90         trusted-key 0xB2450D97085B7B8C
  91       '';
  92     };
  93     openssl = {
  94       enable = true;
  95       opensslHome = toString ../sec/openssl;
  96       certificates = import shell/x509.nix;
  97     };
  98     openssh = {
  99       # WARNING: nixops uses its own ssh, not this one.
 100       enable = true;
 101       sshConf = ''
 102         Ciphers aes256-gcm@openssh.com,aes128-gcm@openssh.com,aes256-ctr
 103         Compression no
 104         #CompressionLevel 4
 105         ControlMaster auto
 106         ControlPath ${builtins.toString ../sec/ssh}/ssh-%h-%p-%r.socket
 107         HashKnownHosts no
 108         #SSAPIAuthentication no
 109         SendEnv LANG LC_*
 110         StrictHostKeyChecking yes
 111         UserKnownHostsFile ${builtins.toString ../sec/ssh/known_hosts}
 112       '';
 113     };
 114     virtualbox = {
 115       enable = true;
 116     };
 117   };
 118
 119   # Using modules enables to separate specific configurations
 120   # from reusable code in shell/modules.nix and shell/modules/
 121   # which may find its way in another git repository one day.
 122   modules =
 123     (import shell/modules.nix {
 124       inherit pkgs lib;
 125       modules = [ configuration ];
 126     }).config;
 127
 128   # Utility to query the Nix files like nixops show-option
 129   # but without requiring a nixops database, and not limited to config entries.
 130   pwd = toString (./. + "");
 131   sourcephile-nix-get = pkgs.writeShellScriptBin "sourcephile-nix-get" ''
 132     nix-instantiate --read-write-mode \
 133      --arg networkExprs "[${pwd}/servers.nix ${pwd}/servers/production.nix]" \
 134      --arg args '{}' --argstr "uuid" whatever \
 135      --argstr deploymentName production "<nixops/eval-machine-info.nix>" \
 136      --eval-only --strict --arg checkConfigurationOptions false -A "$@"
 137   '';
 138   sourcephile-shred-tmp = pkgs.writeShellScriptBin "sourcephile-shred-tmp" ''
 139     # Cleanup "../sec/tmp/"
 140     # This is done when entering the nix-shell
 141     # because direnv already hooks trap EXIT.
 142     cd "${pwd}"
 143     test ! -e sec/tmp || {
 144     find sec/tmp -type f -exec shred -fu {} +
 145     rm -rf sec/tmp
 146     }
 147   '';
 148 in
 149 pkgs.mkShell {
 150   name = "sourcephile-nix";
 151   src = null;
 152   #preferLocalBuild = true;
 153   #allowSubstitutes = false;
 154   buildInputs = modules.nix-shell.buildInputs ++ [
 155     sourcephile-nix-get
 156     sourcephile-shred-tmp
 157     nixos.nixos-generate-config
 158     nixos.nixos-install
 159     nixos.nixos-enter
 160     #pkgs.binutils
 161     pkgs.coreutils
 162     pkgs.cryptsetup
 163     pkgs.curl
 164     #pkgs.direnv
 165     pkgs.dnsutils
 166     #pkgs.dropbear
 167     pkgs.e2fsprogs
 168     pkgs.git
 169     pkgs.glibcLocales
 170     pkgs.gnumake
 171     pkgs.gnupg
 172     pkgs.htop
 173     #pkgs.inetutils
 174     pkgs.ipcalc
 175     #pkgs.iputils
 176     pkgs.less
 177     pkgs.libfaketime
 178     pkgs.ldns
 179     #pkgs.ldns.examples
 180     #pkgs.mailutils
 181     pkgs.man
 182     pkgs.mdadm
 183     pkgs.gptfdisk
 184     pkgs.ncdu
 185     pkgs.ncurses
 186     pkgs.nixops
 187     #pkgs.openssl
 188     pkgs.pass
 189     pkgs.procps
 190     pkgs.rsync
 191     #pkgs.rxvt_unicode.terminfo
 192     #pkgs.sqlite
 193     pkgs.sqlite
 194     #pkgs.sudo
 195     pkgs.tig
 196     pkgs.time
 197     #pkgs.tmux
 198     pkgs.tree
 199     pkgs.utillinux
 200     #pkgs.vim
 201     #pkgs.virtualbox
 202     pkgs.which
 203     pkgs.xdg_utils
 204     pkgs.zfs
 205     pkgs.fio
 206     pkgs.strace
 207     pkgs.utillinux
 208     #pkgs.zfstools
 209   ];
 210   #enableParallelBuilding = true;
 211   shellHook = ''
 212     echo >&2 "nix: running shellHook"
 213
 214     # Nix
 215     PATH=$NIX_SHELL_PATH:$PATH
 216     export NIX_PATH="nixpkgs=${toString pkgs.path}:nixpkgs-overlays="$PWD"/overlays:nixops=${toString pkgs.nixops}/share/nix/nixops"
 217
 218     # Since the .envrc calls this shellHook
 219     # the EXIT trap cannot be freely used
 220     # because it's already used by direnv,
 221     # hence shred at startup, which is not ideal.
 222     sourcephile-shred-tmp
 223
 224     ${modules.nix-shell.shellHook}
 225
 226     # password-store
 227     export PASSWORD_STORE_DIR="$PWD"/../sec/pass
 228
 229     # gpg
 230     export GPG_TTY=$(tty)
 231     gpg-connect-agent updatestartuptty /bye >/dev/null
 232
 233     # nixops
 234     #export NIXOPS_DEPLOYMENT="staging"
 235     export MERMET_DEPLOYMENT=production
 236     export LOSURDO_DEPLOYMENT=production
 237     export NIXOPS_STATE="$PWD"/../sec/nixops/state.nixops
 238     NIXOPS_OPTS+=" --show-trace"
 239     export NIXOPS_OPTS
 240
 241     # disnix
 242     #export DISNIXOS_USE_NIXOPS=1
 243     #export DISNIX_CLIENT_INTERFACE=disnix-nixops-client
 244     #export DISNIX_PROFILE=default
 245     #export DISNIX_TARGET_PROPERTY=hostname
 246     #export DYSNOMIA_STATEDIR="$PWD"/../sec/dysnomia
 247   '';
 248 }