{ config, lib, pkgs, ... }:

with lib;
let
  cfg = config.services.sourcehut;
  cfgIni = cfg.settings;
  scfg = cfg.man;
  iniKey = "man.sr.ht";
  statePath = "/var/lib/sourcehut/mansrht";

  drv = pkgs.sourcehut.mansrht;
in
{
  options.services.sourcehut.man = {
    user = mkOption {
      type = types.str;
      default = "mansrht";
      description = ''
        User for man.sr.ht.
      '';
    };

    port = mkOption {
      type = types.port;
      default = 5004;
      description = ''
        Port on which the "man" module should listen.
      '';
    };

    database = mkOption {
      type = types.str;
      default = "man.sr.ht";
      description = ''
        PostgreSQL database name for man.sr.ht.
      '';
    };
  };

  config = with scfg; lib.mkIf (cfg.enable && elem "man" cfg.services) {
    assertions =
      [
        {
          assertion = hasAttrByPath [ "git.sr.ht" "oauth-client-id" ] cfgIni;
          message = "man.sr.ht needs access to git.sr.ht.";
        }
      ];

    users = {
      users = {
        "${user}" = {
          isSystemUser = true;
          group = user;
          description = "man.sr.ht user";
        };
      };

      groups = {
        "${user}" = { };
      };
    };

    services.postgresql = {
      authentication = ''
        local ${database} ${user} trust
      '';
      ensureDatabases = [ database ];
      ensureUsers = [
        {
          name = user;
          ensurePermissions = { "DATABASE \"${database}\"" = "ALL PRIVILEGES"; };
        }
      ];
    };

    systemd = {
      services.mansrht = import ./service.nix { inherit config pkgs lib; } scfg drv iniKey {
        after = [ "postgresql.service" "network.target" ];
        requires = [ "postgresql.service" ];
        wantedBy = [ "multi-user.target" ];

        description = "man.sr.ht website service";

        serviceConfig.ExecStart = "${cfg.python}/bin/gunicorn ${drv.pname}.app:app -b ${cfg.address}:${toString port}";
      };
    };

    services.nginx.virtualHosts."man.${cfg.originBase}" = {
      forceSSL = true;
      locations."/".proxyPass = "http://${cfg.address}:${toString port}";
      locations."/query".proxyPass = "http://${cfg.address}:${toString (port + 100)}";
      locations."/static".root = "${pkgs.sourcehut.mansrht}/${pkgs.sourcehut.python.sitePackages}/mansrht";
    };
  };
}