{ pkgs, lib, config, machines, ... }:
let
  domain = "autogeree.net";
  domainID = lib.replaceStrings ["."] ["_"] domain;
  inherit (builtins) attrValues;
  inherit (builtins.extraBuiltins) git;
  inherit (config) networking;
  inherit (config.services) knot;
  inherit (config.security) gnupg;
  inherit (config.users) users groups;
  # Use the Git commit time of the ${domain}.nix file to set the serial number.
  # WARNING: the ${domain}.nix must be committed into Git for this to work.
  # WARNING: this does not take other .nix into account, though they may contribute to the zone's data.
  serial = domain: toString (git ./. [ "log" "-1" "--format=%ct" "--" (domain + ".nix") ]);
in
{
services.knot.zones."${domain}" = {
  conf = ''
    acl:
      - id: acl_localhost_acme_${domainID}
        address: 127.0.0.1
        action: update
        update-owner: name
        update-owner-match: equal
        update-owner-name: [_acme-challenge.${domain}]
        update-type: [TXT]
      - id: acl_tsig_acme_${domainID}
        address: ${machines.losurdo.extraArgs.ipv4}
        key: acme_${domainID}
        action: update
        update-owner: name
        update-owner-match: equal
        update-owner-name: [_acme-challenge.${domain}]
        update-type: [TXT]

    zone:
      - domain: ${domain}
        file: ${domain}.zone
        serial-policy: increment
        semantic-checks: on
        notify: secondary_gandi
        notify: secondary_muarf
        acl: acl_gandi
        acl: acl_muarf
        acl: acl_localhost_acme_${domainID}
        acl: acl_tsig_acme_${domainID}
        dnssec-signing: off
        dnssec-policy: ed25519
  '';
  # TODO: increase the TTL once things have settled down
  data = ''
    $ORIGIN ${domain}.
    $TTL 500

    ; SOA (Start Of Authority)
    @ SOA ns admin (
      ${serial domain} ; Serial number
      24h   ; Refresh
      15m   ; Retry
      1000h ; Expire (1000h)
      1d    ; Negative caching
    )

    ; NS (Name Server)
    @ NS ns
    @ NS ns6.gandi.net.
    @ NS ns0.muarf.org.

    ; A (DNS -> IPv4)
    @          A ${machines.mermet.extraArgs.ipv4}
    mermet     A ${machines.mermet.extraArgs.ipv4}
    autoconfig A ${machines.mermet.extraArgs.ipv4}
    code       A ${machines.mermet.extraArgs.ipv4}
    git        A ${machines.mermet.extraArgs.ipv4}
    imap       A ${machines.mermet.extraArgs.ipv4}
    mail       A ${machines.mermet.extraArgs.ipv4}
    ns         A ${machines.mermet.extraArgs.ipv4}
    pop        A ${machines.mermet.extraArgs.ipv4}
    smtp       A ${machines.mermet.extraArgs.ipv4}
    submission A ${machines.mermet.extraArgs.ipv4}
    www        A ${machines.mermet.extraArgs.ipv4}
    chomsky    A 91.216.110.36
    alpes      A 195.88.84.51

    ; SPF (Sender Policy Framework)
    @ 3600 IN SPF "v=spf1 mx ip4:${machines.mermet.extraArgs.ipv4} -all"
    @ 3600 IN TXT "v=spf1 mx ip4:${machines.mermet.extraArgs.ipv4} -all"

    ; MX (Mail eXchange)
    @ 180 MX 5 mail

    ; SRV (SeRVice)
    _git._tcp.git 18000 IN SRV 0 0 9418 git

    ; CAA (Certificate Authority Authorization)
    ; DOC: https://blog.qualys.com/ssllabs/2017/03/13/caa-mandated-by-cabrowser-forum
    @ CAA 128 issue "letsencrypt.org"
  '';
};
users.users.knot.extraGroups = [ groups.keys.name ];
services.knot = {
  keyFiles = [ gnupg.secrets."knot/tsig/${domain}/acme.conf".path ];
};
security.gnupg.secrets."knot/tsig/${domain}/acme.conf" = {
  # Generated with: keymgr -t acme_${domainID}
  user = users.knot.name;
};
systemd.services.knot = {
  after = [ gnupg.secrets."knot/tsig/${domain}/acme.conf".service ];
  wants = [ gnupg.secrets."knot/tsig/${domain}/acme.conf".service ];
};
/* Useless since the zone is public
services.unbound.extraConfig = ''
  stub-zone:
    name: "autogeree.net"
    stub-addr: 127.0.0.1@5353
'';
*/
}