{ pkgs, lib, config, ... }:
{
nixpkgs.overlays = [
  (final: super: {
    gnupg = super.gnupg.override {
      # Wants polkit which wants spidermonkey (slow to compile)
      pcsclite = null;
    };
    systemd = super.systemd.override {
      # Wants tpm2-tss which does not cross-compile
      withTpm2Tss = false;
      # Does not cross-compile :(
      withEfi = false;
    };
    # https://logs.nix.samueldr.com/nixos/2019-07-23#2416964;
    xorg = super.xorg.overrideScope' (ofinal: osuper: {
      fontadobe100dpi = final.hello;
      fontadobe75dpi = final.hello;
      fontcursormisc = final.hello;
      fontmiscmisc = final.hello;
    });
    # Perl's ModuleBuild does not cross-compile
    # https://github.com/NixOS/nixpkgs/issues/66741#issuecomment-944831760
    xdg-utils = final.hello;
    procmail = final.hello;
    noto-fonts-emoji = final.hello;
    x11_ssh_askpass = final.hello;
    dconf = super.dconf.overrideAttrs (old: {
      doCheck = false;
    });
    # Need gobject-instrospection which does not cross-compile
    arandr = final.hello;
    # Depends on judy which does not cross-compile
    stress-ng = final.hello;
    hwinfo = final.hello;
    # Fails to cross-compile: perl5.34.0-IO-Tty-armv7l-unknown-linux-gnueabihf
    mosh = final.hello;
    # error: Error loading target specification:
    # Could not find specification for target "armv7l-unknown-linux-gnueabihf".
    # Run `rustc --print target-list` for a list of built-in targets
    gparted = final.hello;
  })
];
#environment.noXlibs = true;
fonts.fontconfig.enable = false;
# lesspipe does not cross-compile
programs.less.enable = lib.mkForce false;
programs.mosh.enable = false;
programs.traceroute.enable = false;
security.apparmor.enable = false;
services.udisks2.enable = false;
}