{
  inputs = {
    doom-emacs.follows = "julm-nix/doom-emacs";
    home-manager.follows = "julm-nix/home-manager";
    julm-nix.inputs.nixpkgs.follows = "nixpkgs";
    julm-nix.url = "git+file:///home/julm/work/sourcephile/nix/julm-nix?ref=main";
    nix-formatter-pack.follows = "julm-nix/nix-formatter-pack";
    #nixpkgs.follows = "julm-nix/nixpkgs";
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-23.11";
    pre-commit-hooks.follows = "julm-nix/pre-commit-hooks";
  };

  outputs = inputs:
    let
      remoteNixpkgsPatches = import (inputs.julm-nix + "/nixpkgs/patches.nix");
      localNixpkgsPatches = [
        #nixpkgs/patches/systemd-coredump.diff
      ];
      originPkgs = inputs.nixpkgs.legacyPackages."x86_64-linux";
      nixpkgsPath = originPkgs.applyPatches {
        name = "nixpkgs-patched";
        src = inputs.nixpkgs;
        patches = map originPkgs.fetchpatch remoteNixpkgsPatches ++ localNixpkgsPatches;
        postPatch = ''
          patch=$(printf '%s\n' ${builtins.concatStringsSep " "
             (map (p: p.sha256) remoteNixpkgsPatches ++ localNixpkgsPatches)} |
            sort | sha256sum | cut -c -7)
          echo "-patch-$patch" >.version-suffix
        '';
      };
      profile = "/nix/var/nix/profiles/system";
      inherit (inputs.nixpkgs) lib;
      #nixosSystem = lib.nixosSystem;
      nixosSystem = import (nixpkgsPath + "/nixos/lib/eval-config.nix");
      forAllSystems = f: lib.genAttrs lib.systems.flakeExposed (system: f rec {
        inherit system;
        #pkgs = inputs.nixpkgs.legacyPackages.${system};
        pkgs = import nixpkgsPath {
          inherit system;
          overlays =
            import nixpkgs/overlays.nix ++
            import (inputs.julm-nix + "/nixpkgs/overlays.nix");
        };
      });
    in
    {
      # nix -L build .#hello
      packages = forAllSystems (args: with args; pkgs);

      # nix -L build .#nixosConfigurations.mermet.config.system.build.toplevel
      # nix -L build .#nixosConfigurations.mermet.config.boot.kernelPackages.kernel.configfile
      # nix -L build .#nixosConfigurations.mermet.pkgs.hello
      # nix eval --raw .#nixosConfigurations.mermet.config.networking.nftables.ruleset
      nixosConfigurations = lib.genAttrs
        (builtins.attrNames (lib.filterAttrs (_n: v: v == "directory") (builtins.readDir (inputs.self + "/hosts"))))
        (hostName: nixosSystem
          {
            system = null;
            specialArgs = {
              # Required to avoid infinite recursion
              # when `inputs` is used in `imports`.
              inherit inputs;
            };
            modules = [
              nixos/default.nix
              (inputs.julm-nix + "/nixos/default.nix")
              (inputs.self + "/hosts/${hostName}.nix")
              {
                _module.args = {
                  inherit hostName;
                  hosts = inputs.self.nixosConfigurations;
                  host = inputs.self.nixosConfigurations.${hostName}._module.args;
                  info = import ./info.nix;
                };
                nixpkgs.overlays =
                  import nixpkgs/overlays.nix ++
                  import (inputs.julm-nix + "/nixpkgs/overlays.nix");
                #nixpkgs.buildPlatform = "x86_64-linux";
                nixpkgs.config.allowUnfreePredicate = pkg: builtins.elem (lib.getName pkg) [ "hplip" ];
              }
              inputs.nixpkgs.nixosModules.notDetected
              inputs.home-manager.nixosModules.home-manager
              {
                home-manager.useGlobalPkgs = true;
                home-manager.useUserPackages = true;
                home-manager.verbose = true;
                home-manager.backupFileExtension = null;
                home-manager.extraSpecialArgs = {
                  inherit hostName inputs;
                };
              }
              {
                programs.ssh.knownHosts = {
                  carotte = {
                    extraHostNames = [ "carotte" "carotte.sourcephile.fr" ];
                    publicKey = "ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIKnnS0w9zm5KuWwlfJu+qEXC0asESQySPp76szyMTE3J";
                  };
                  mermet = {
                    extraHostNames = [ "mermet" "mermet.sourcephile.fr" ];
                    publicKey = "ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIFvKN2sIpH782MFjaOpcty1Hs/T/TPNJpXI08H3O3oxl";
                  };
                  losurdo = {
                    extraHostNames = [ "losurdo" "losurdo.sourcephile.fr" ];
                    publicKey = "ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIHJkAq1T0Dxozt4RPylvWrUmeuejiG+n/owb3ucnWP9F";
                  };
                };
              }
            ];
          }
        );

      # nix -L develop  or  direnv allow
      devShell = forAllSystems ({ pkgs, system, ... }: pkgs.callPackage ./shell.nix
        {
          inherit pkgs inputs system nixpkgsPath;
          inherit (inputs.self.checks.${system}.pre-commit-check) shellHook;
        });

      # nix -L run .#mermet.switch
      apps = forAllSystems ({ pkgs, system, ... }:
        with builtins;
        mapAttrs
          (hostName: { config, pkgs, ... }:
            let
              inherit (config.system) build;
              scriptApp = scriptName: ps: script: {
                type = "app";
                program = (pkgs.writeShellScript "${hostName}-${scriptName}" ''
                  export PATH="${lib.makeBinPath ([ pkgs.buildPackages.coreutils ] ++ ps)}:$PATH"
                  set -eux
                  ${script}
                '').outPath;
              };
            in
            {
              # Example: nix run .#mermet.switch
              "switch" = scriptApp "switch" [ ] (
                ''
                  set -o pipefail
                  shopt -s globstar

                  chmod -R g-rwx,o-rwx **/*.gpg
                  trap 'git reset **/*.gpg' EXIT
                  git rm -rf --cached --ignore-unmatch **/*.gpg # prevent copying to /nix/store

                  nix-store --add-root hosts/${hostName}.nixpkgs --indirect --realise ${nixpkgsPath}
                  nix-store --add-root hosts/${hostName}.root --indirect --realise ${build.toplevel}

                  nix copy --to ssh://${config.install.target}${lib.optionalString config.install.substituteOnDestination " --substitute-on-destination"} ${build.toplevel}

                  ${config.security.initrd.install}

                  if ssh ${config.install.target} set -x ';' \
                    systemctl reset-failed nixos-fallback '2>/dev/null' ';' \
                    test "''${NO_NIXOS_FALLBACK:+set}" '||' \
                    systemd-run -u nixos-fallback --description=nixos-fallback /bin/sh -xc '''\'''
                      PATH=${with pkgs; lib.makeBinPath [ coreutils nix systemd ]}
                      sleep $((10 * 60))
                      ${profile}/bin/switch-to-configuration switch
                      systemctl reboot
                    '\'''' '&&' \
                    ${build.toplevel}/bin/switch-to-configuration test
                  then
                    ssh ${config.install.target} -o ControlPath=none set -x ';' \
                      systemctl stop nixos-fallback.service ';' \
                      nix-env --profile ${profile} --set '${build.toplevel}' ';' \
                      ${build.toplevel}/bin/switch-to-configuration boot '&&' \
                      nix-env --delete-generations 7d --profile ${profile}
                  else
                    tput rev
                    echo WARNING: switch-to-configuration was not registered at boot
                    tput sgr0
                    ssh ${config.install.target} -o ControlPath=none set -x ';' \
                      systemctl stop nixos-fallback.service
                    false
                  fi
                ''
              );
              # Example: nix run .#carotte.install-sd
              # DELETEME: quite useless, better to use nixos-install
              "install-sd" = scriptApp "install-sd" [ pkgs.zstd ] ''
                set -o pipefail
                nix-store --add-root hosts/${hostName}.root --indirect --realise ${build.sdImage}
                unzstd --stdout ${build.sdImage}/sd-image/*.img.zst |
                sudo -k dd conv=notrunc oflag=direct,sync status=progress of="''${1:-/dev/mmcblk0}"
              '';
            }
          )
          inputs.self.nixosConfigurations
      );

      # nix flake check
      checks = forAllSystems (args: with args; {
        pre-commit-check = inputs.pre-commit-hooks.lib.${system}.run {
          src = inputs.self;
          hooks = {
            nixpkgs-fmt.enable = true;
          };
        };
      });

      # nix fmt
      formatter = forAllSystems ({ pkgs, ... }:
        inputs.nix-formatter-pack.lib.mkFormatter {
          inherit pkgs;
          config = {
            tools = {
              deadnix.enable = true;
              nixpkgs-fmt.enable = true;
              statix.enable = true;
            };
          };
        }
      );

    };
}