{
# Pin down nixpkgs instead of using global, system or user registries.
inputs.nixpkgs.url = "github:NixOS/nixpkgs/3c0e3697520cbe7d9eb3a64bfd87de840bf4aa77";
inputs.flake-utils.url = "github:numtide/flake-utils";
inputs.shell = { type = "path"; path = "./shell"; flake = false; };
inputs.secrets = { type = "path"; path = "./sec"; flake = false; };
inputs.pass = { type = "path"; path = "./pass"; flake = false; };
outputs = inputs: let
  #   sha256 = "sha256-AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA=";
  remoteNixpkgsPatches = [
    { meta.description = "dstat: fix pluginpath";
      url = "https://github.com/NixOS/nixpkgs/pull/80151.diff";
      sha256 = "0jjw2gvp7b7v2n2m2d6yj0gw711j6p9lyjf5ywp2y9ql6905qf4b";
    }
    { meta.description = "syncoid: fix PATH to let it use sudo";
      url = "https://github.com/NixOS/nixpkgs/pull/83901.diff";
      sha256 = "0q2dicmvl3h3hb9xdd870n5hf6lac489p000c7f1r6k70sh2id4l";
    }
    { meta.description = "sanoid: fix sanoid.conf generation";
      url = "https://github.com/NixOS/nixpkgs/pull/83904.diff";
      sha256 = "Sy9wPmL+Lfl7hMEeXYOEMk3KlfdL21aL92v6MiGajds=";
    }
    { meta.description = "nixos/public-inbox: init";
      url = "https://github.com/NixOS/nixpkgs/pull/77450.diff";
      sha256 = "13ikg7chpbf6rrg5sngbdb95q3awhdgl4g8vci42xmqyf208hzzd";
    }
    { meta.description = "apparmor: fix and improve the service";
      url = "https://github.com/NixOS/nixpkgs/pull/93457.diff";
      sha256 = "sha256-JzS6/42AS9f0XUuC8ybw1tR8lpFwOC59BNqYN4mmeVI=";
    }
    { meta.description = "nixos/security.gnupg: provisioning GnuPG-protected secrets through the Nix store";
      url = "https://github.com/NixOS/nixpkgs/pull/93659.diff";
      sha256 = "3im5nSrlM32DQUeq0Yp1MHkUcQyLdCGbxfJjgcc9e78=";
    }
    { meta.description = "nixos/croc: init";
      url = "https://github.com/NixOS/nixpkgs/pull/93629.diff";
      sha256 = "sha256-hzs5Z9cYCo6aNFfylB37W+1neejV4/kVyM1QmqVhVww=";
    }
    { meta.description = "dovecot_fts_xapian: 1.3.1 -> 1.3.3";
      url = "https://github.com/NixOS/nixpkgs/pull/94938.diff";
      sha256 = "10bjwcwpvq7nnqdpz0n7c61kb3b27v1abyc80pki7d13jmzzjc04";
    }
    { meta.description = "transmission: use freeformType on settings";
      url = "https://github.com/NixOS/nixpkgs/pull/96655.diff";
      sha256 = "sha256-5TRjz57xKcQuTUkEZ2cBwH6nCXxMfKcAHAogc/gMcjg=";
    }
    { meta.description = "prosody: 0.11.5 -> 0.11.6";
      url = "https://github.com/NixOS/nixpkgs/pull/97739.diff";
      sha256 = "sha256-wWChwKSRCA3F0+09cyn5w6EJyX4n38s4jYo3io/2QGs";
    }
    { meta.description = "tor: improve type-checking and hardening";
      url = "https://github.com/NixOS/nixpkgs/pull/97740.diff";
      sha256 = "sha256-ojmDxbGtfsvrUCtjkR7ZynayEGNDLwYl2Ea6yLOQpIk=";
    }
  ];
  localNixpkgsPatches = [
    #nixpkgs/patches/tor.diff
    #nixpkgs/patches/fix-ld-nix.diff
    #nixpkgs/patches/fix-ld-nix-apparmor.diff
  ];
  originPkgs = inputs.nixpkgs.legacyPackages."x86_64-linux";
  nixpkgs = originPkgs.applyPatches {
    name = "nixpkgs-patched";
    src = inputs.nixpkgs;
    patches = map originPkgs.fetchpatch remoteNixpkgsPatches ++ localNixpkgsPatches;
    postPatch = ''
      patch=$(printf '%s\n' ${builtins.concatStringsSep " "
         (map (p: p.sha256) remoteNixpkgsPatches ++ localNixpkgsPatches)} |
        sort | sha256sum | cut -c -7)
      echo "+patch-$patch" >.version-suffix
    '';
  };
  lib = originPkgs.lib;
  initrdKey = "initrd/ssh.key";
  machines = builtins.mapAttrs (machineName: machineConfig:
    let cfg = import machineConfig { inherit inputs; }; in
    import (nixpkgs + "/nixos/lib/eval-config.nix") (cfg // {
      extraArgs = {
        inherit machineName inputs;
        machines = inputs.self.nixosConfigurations;
      } // (cfg.extraArgs or {});
      modules = cfg.modules ++ [({pkgs, ...}: {
        nix.registry.nixpkgs.flake = nixpkgs;
        nix.package = pkgs.nixFlakes;
        nix.extraOptions = "experimental-features = nix-command flakes";
        nixpkgs.overlays = import nixpkgs/overlays.nix;
        system.nixos.versionSuffix = ".${
          lib.substring 0 8 (inputs.self.lastModifiedDate or inputs.self.lastModified)}.${
          inputs.self.shortRev or "dirty"}";
        system.nixos.revision = lib.mkIf (inputs.self ? rev) inputs.self.rev;
        # Let 'nixos-version --json' know about the Git revision of this flake.
        system.configurationRevision = lib.mkIf (inputs.self ? rev) inputs.self.rev;
        boot.initrd.network.ssh.hostKeys = [ "/root/${initrdKey}" ];
        /*
        system.configurationRevision =
          if inputs.self ? rev
          then inputs.self.rev
          else throw "Refusing to build from a dirty Git tree!";
        */
      })];
    }));
  in
  {
    # nix -L build .#nixosConfigurations.${machineName}.config.system.build.toplevel
    nixosConfigurations = machines {
      losurdo = machines/losurdo.nix;
      mermet  = machines/mermet.nix;
    };
  }
  // inputs.flake-utils.lib.eachDefaultSystem (system:
    #let pkgs = inputs.nixpkgs.legacyPackages.${system}; in
    let
      pkgs = import nixpkgs {
        inherit system;
        config = {};
        overlays = import nixpkgs/overlays.nix;
        #overlays = import (inputs.self + "/nixpkgs/overlays.nix");
      };
    in {
    devShell = import ./shell.nix { inherit inputs pkgs; };
    apps = builtins.mapAttrs (machineName: { config, ... }: {
      type = "app";
      program = (let
        system = config.system.build.toplevel;
        rootKey = "root/key";
        keygrip = builtins.getAttr machineName {
          losurdo = "9AA84E6F6D71F9163C46BF396B141A0806219077";
          mermet  = "89F52A879E0019A966503AFFDE72EEA84CDFA3A7";
        };
        target = "root@${config.networking.hostName}.${config.networking.domain}";
        nixCopyFlags = ["--substitute-on-destination"];
        profile = "/nix/var/nix/profiles/system";
        in pkgs.writeShellScript "install" ''
          set -eux
          nix-store --add-root machines/${machineName}.root --indirect --realise ${system}
          ${pkgs.nixFlakes}/bin/nix copy --to ssh://'${target}' \
           ${lib.escapeShellArgs nixCopyFlags} ${system}
          ssh '${target}' \
            ${pkgs.gnupg}/bin/gpg-connect-agent --no-autostart --homedir /var/lib/gnupg "'keyinfo --list'" /bye 2>&1 |
          grep -qx -e "gpg-connect-agent: no gpg-agent running in this session" \
                   -e "S KEYINFO ${keygrip} . . . 1 .*" || {
            # Send the rootKey
            gpg --decrypt '${config.security.gnupg.store}/${rootKey}.pass.gpg' |
            gpg --batch --pinentry-mode loopback --passphrase-fd 0 --export-secret-subkeys @root@${machineName} |
            ssh '${target}' \
              gpg --no-autostart --homedir /var/lib/gnupg --no-autostart --batch --pinentry-mode loopback --import

            # Send the rootKey's passphrase
            gpg --decrypt '${config.security.gnupg.store}/${rootKey}.pass.gpg' |
            ssh '${target}' \
              gpg-preset-passphrase --homedir /var/lib/gnupg --preset ${keygrip}
          }
          # Send the SSH key of the initrd
          gpg --decrypt '${config.security.gnupg.store}/${initrdKey}.gpg' |
          ssh '${target}' \
            install -D -m 400 -o root -g root /dev/stdin /root/${initrdKey}
          ssh '${target}' \
            nix-env --profile '${profile}' --set '${system}' '&&' \
            '${profile}'/bin/switch-to-configuration switch
      '').outPath;
    }) inputs.self.nixosConfigurations;
    }
  );
}