{
# Pin down nixpkgs from github, instead of using global, system or user registries.
inputs.nixpkgs.url = "github:NixOS/nixpkgs/b69f140a8028e4718bde4e5082f8df38e50b7971";
#inputs.nixpkgs.url = "flake:nixpkgs";
inputs.flake-utils.url = "github:numtide/flake-utils";
inputs.shell = { type = "path"; path = "./shell"; flake = false; };
inputs.secrets = { type = "path"; path = "./sec"; flake = false; };
inputs.pass = { type = "path"; path = "./pass"; flake = false; };
outputs = inputs: let
  remoteNixpkgsPatches = [
    /*
    { meta.description = "syncoid: fix PATH to let it use sudo";
      url = "https://github.com/NixOS/nixpkgs/pull/83901.diff";
      sha256 = "0q2dicmvl3h3hb9xdd870n5hf6lac489p000c7f1r6k70sh2id4l";
    }
    */
    { meta.description = "sanoid: fix sanoid.conf generation";
      url = "https://github.com/NixOS/nixpkgs/pull/83904.diff";
      sha256 = "sha256-Wze1a7y0f22dgz+w0JZC4rL1B1Esfmi1msF8Rvil6f0=";
    }
    { meta.description = "nixos/security.gnupg: provisioning GnuPG-protected secrets through the Nix store";
      url = "https://github.com/NixOS/nixpkgs/pull/93659.diff";
      sha256 = "3im5nSrlM32DQUeq0Yp1MHkUcQyLdCGbxfJjgcc9e78=";
    }
    { meta.description = "nixos/croc: init";
      url = "https://github.com/NixOS/nixpkgs/pull/93629.diff";
      sha256 = "sha256-BxKjjeiuwjvNKrs2u+igdNu5aZhhDJkNjzUl7B5c99M=";
    }
    { meta.description = "dovecot_fts_xapian: 1.3.1 -> 1.3.3";
      url = "https://github.com/NixOS/nixpkgs/pull/94938.diff";
      sha256 = "10bjwcwpvq7nnqdpz0n7c61kb3b27v1abyc80pki7d13jmzzjc04";
    }
    { meta.description = "transmission: use freeformType on settings";
      url = "https://github.com/NixOS/nixpkgs/pull/96655.diff";
      sha256 = "sha256-lRKe8WnGPc8ojaD9W8ZS+NVMhIoGOCOj9njhqQhzaCM";
    }
    { meta.description = "tor: improve type-checking and hardening";
      url = "https://github.com/NixOS/nixpkgs/pull/97740.diff";
      sha256 = "sha256-ojmDxbGtfsvrUCtjkR7ZynayEGNDLwYl2Ea6yLOQpIk=";
    }
    /*
    { meta.description = "nixos/postfix: add sandbox";
      url = "https://github.com/NixOS/nixpkgs/pull/93305.diff";
      sha256 = "sha256-KmoaPj8G4kRlwkBKo/giyST8xQfnjX3OJhh68NKNaRI=";
    }
    { meta.description = "nixos/rspamd: add sandbox";
      url = "https://github.com/NixOS/nixpkgs/pull/93293.diff";
      sha256 = "sha256-7OfBzJPeGVhHf4ziYLwOpqaYbElCsjLkT4Y/bbCOPx0=";
    }
    */
    { meta.description = "nixos/syncoid: split in multiple systemd services";
      url = "https://github.com/NixOS/nixpkgs/pull/98455.diff";
      sha256 = "sha256-vmPzvjwAOSWqfizgDk3l6FrMD2OsG+8UpIkQvOUcXNI=";
    }
    { meta.description = "zerobin: update to v1.0.5";
      url = "https://github.com/NixOS/nixpkgs/pull/98734.diff";
      sha256 = "sha256-mEFvzR0ymwR7V3bJBnr9fR3GxA1jDfXZXQzo+jc5Nxc=";
    }
    /*
    { meta.description = "apparmor";
      url = "https://github.com/NixOS/nixpkgs/pull/93457.diff";
      sha256 = "sha256-JzS6/42AS9f0XUuC8ybw1tR8lpFwOC59BNqYN4mmeVI=";
    }
    */
    { meta.description = "Update public-inbox to 1.6.0 and add systemd services";
      url = "https://github.com/NixOS/nixpkgs/pull/104457.diff";
      sha256 = "187fwjw922w6xcwdjnk6r6q4jbmk542vq3qci2z95q026w4l2p7f";
    }
    { meta.description = "Add freeciv service";
      url = "https://github.com/NixOS/nixpkgs/pull/104460.diff";
      sha256 = "sha256-HU6+Pq6WqVKdpnoRBU9FUneunZGc2q+STPAQR5kUS5o=";
    }
  ];
  localNixpkgsPatches = [
    nixpkgs/patches/apparmor.diff
    #nixpkgs/patches/public-inbox.diff
    #nixpkgs/patches/zerobin.diff
    #nixpkgs/patches/gitolite.diff
    #nixpkgs/patches/tor.diff
    #nixpkgs/patches/fix-ld-nix.diff
    #nixpkgs/patches/fix-ld-nix-apparmor.diff
  ];
  originPkgs = inputs.nixpkgs.legacyPackages."x86_64-linux";
  nixpkgs = originPkgs.applyPatches {
    name = "nixpkgs-patched";
    src = inputs.nixpkgs;
    patches = map originPkgs.fetchpatch remoteNixpkgsPatches ++ localNixpkgsPatches;
    postPatch = ''
      patch=$(printf '%s\n' ${builtins.concatStringsSep " "
         (map (p: p.sha256) remoteNixpkgsPatches ++ localNixpkgsPatches)} |
        sort | sha256sum | cut -c -7)
      echo "+patch-$patch" >.version-suffix
    '';
  };
  lib = originPkgs.lib;
  machines = builtins.mapAttrs (machineName: machineConfig:
    let cfg = import machineConfig { inherit inputs; }; in
    import (nixpkgs + "/nixos/lib/eval-config.nix") (cfg // {
      extraArgs = {
        inherit machineName inputs;
        machines = inputs.self.nixosConfigurations;
      } // (cfg.extraArgs or {});
      modules = cfg.modules ++ [({pkgs, ...}: {
        nix.registry.nixpkgs.flake = nixpkgs;
        nix.package = pkgs.nixFlakes;
        nix.extraOptions = "experimental-features = nix-command flakes";
        nixpkgs.overlays = import nixpkgs/overlays.nix;
        system.nixos.versionSuffix = ".${
          lib.substring 0 8 (inputs.self.lastModifiedDate or inputs.self.lastModified)}.${
          inputs.self.shortRev or "dirty"}";
        system.nixos.revision = lib.mkIf (inputs.self ? rev) inputs.self.rev;
        # Let 'nixos-version --json' know about the Git revision of this flake.
        system.configurationRevision = lib.mkIf (inputs.self ? rev) inputs.self.rev;
        boot.initrd.network.ssh.hostKeys = [ "/root/initrd/ssh.key" ];
        security.gnupg.store = inputs.pass + "/machines/${machineName}";
        /*
        system.configurationRevision =
          if inputs.self ? rev
          then inputs.self.rev
          else throw "Refusing to build from a dirty Git tree!";
        */
        programs.ssh.knownHosts = {
          mermet = {
            hostNames = [ "mermet" "mermet.sourcephile.fr" ];
            publicKey = "ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIFvKN2sIpH782MFjaOpcty1Hs/T/TPNJpXI08H3O3oxl";
          };
          losurdo = {
            hostNames = [ "losurdo" "losurdo.sourcephile.fr" ];
            publicKey = "ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIHJkAq1T0Dxozt4RPylvWrUmeuejiG+n/owb3ucnWP9F";
          };
        };
      })];
    }));
  in
  {
    # nix -L build .#nixosConfigurations.${machineName}.config.system.build.toplevel
    nixosConfigurations = machines {
      losurdo = machines/losurdo.nix;
      mermet  = machines/mermet.nix;
    };
  }
  // inputs.flake-utils.lib.eachDefaultSystem (system:
    #let pkgs = inputs.nixpkgs.legacyPackages.${system}; in
    let
      pkgs = import nixpkgs {
        inherit system;
        overlays = import nixpkgs/overlays.nix;
      };
    in {
    legacyPackages = pkgs;
    devShell = import ./shell.nix { inherit inputs pkgs; };
    apps = builtins.mapAttrs (machineName: { config, ... }: let
      system = config.system.build.toplevel;
      keygrip = builtins.getAttr machineName {
        losurdo = "9AA84E6F6D71F9163C46BF396B141A0806219077";
        mermet  = "89F52A879E0019A966503AFFDE72EEA84CDFA3A7";
      };
      target = "root@${config.networking.hostName}.${config.networking.domain}";
      profile = "/nix/var/nix/profiles/system";
      in rec {
      # Example: nix run .#losurdo.switch
      "switch" = {
        type = "app";
        program = (pkgs.writeShellScript "switch" ''
          set -eux
          set -o pipefail
          nix-store --add-root machines/${machineName}.root --indirect --realise ${system}
          nix copy --to ssh://'${target}' --substitute-on-destination ${system}
          ${sendkeys.program}
          # Send the SSH key of the initrd
          gpg --decrypt '${config.security.gnupg.store}/initrd/ssh.key.gpg' |
          ssh '${target}' install -D -m 400 -o root -g root /dev/stdin /root/initrd/ssh.key
          # Send the Wireguard key of the initrd
          gpg --decrypt '${config.security.gnupg.store}/wireguard/wg-intra/privateKey.gpg' |
          ssh '${target}' install -D -m 400 -o root -g root /dev/stdin /root/initrd/wg-intra.key
          ssh '${target}' \
            nix-env --profile '${profile}' --set '${system}' '&&' \
            '${profile}'/bin/switch-to-configuration switch
        '').outPath;
      };
      # Example: nix run .#losurdo.sendkeys
      "sendkeys" = {
        type = "app";
        program = (pkgs.writeShellScript "sendkeys" ''
          set -eux
          set -o pipefail
          ssh '${target}' \
            gpg-connect-agent --no-autostart --homedir /var/lib/gnupg "'keyinfo --list'" /bye 2>&1 |
          grep -qx -e "gpg-connect-agent: no gpg-agent running in this session" \
                   -e "S KEYINFO ${keygrip} . . . 1 .*" || {
            # Send the GnuPG root key
            gpg --decrypt '${config.security.gnupg.store}/root/key.pass.gpg' |
            gpg --batch --pinentry-mode loopback --passphrase-fd 0 --export-secret-subkeys @root@${machineName} |
            ssh '${target}' \
              gpg --no-autostart --homedir /var/lib/gnupg --no-autostart --batch --pinentry-mode loopback --import

            # Send the GnuPG root key's passphrase
            gpg --decrypt '${config.security.gnupg.store}/root/key.pass.gpg' |
            ssh '${target}' \
              gpg-preset-passphrase --homedir /var/lib/gnupg --preset ${keygrip}
          }
        '').outPath;
      };
    }) inputs.self.nixosConfigurations;}
  );
}