Language/TCT/Write/XML.hs

   1 {-# LANGUAGE FlexibleContexts #-}
   2 {-# LANGUAGE FlexibleInstances #-}
   3 {-# LANGUAGE OverloadedLists #-}
   4 {-# LANGUAGE OverloadedStrings #-}
   5 {-# LANGUAGE ViewPatterns #-}
   6 {-# OPTIONS_GHC -fno-warn-orphans #-}
   7 module Language.TCT.Write.XML where
   8
   9 import Control.Monad (Monad(..))
  10 import Data.Bool
  11 import Data.Default.Class (Default(..))
  12 import Data.Eq (Eq(..))
  13 import Data.Foldable (Foldable(..))
  14 import Data.Function (($), (.))
  15 import Data.Functor ((<$>), (<$), ($>))
  16 import Data.Maybe (Maybe(..))
  17 import Data.Monoid (Monoid(..))
  18 import Data.Ord (Ord(..))
  19 import Data.Semigroup (Semigroup(..))
  20 import Data.Sequence (Seq, ViewL(..), ViewR(..), (<|))
  21 import Data.Set (Set)
  22 import Data.TreeSeq.Strict (Tree(..), tree0)
  23 import Data.Tuple (uncurry)
  24 import Prelude (Num(..), undefined)
  25 import qualified Data.Char as Char
  26 import qualified Data.List as List
  27 import qualified Data.Sequence as Seq
  28 import qualified Data.Text.Lazy as TL
  29 import qualified Language.TCT.Write.Plain as Plain
  30 import qualified System.FilePath as FP
  31
  32 -- import Language.TCT.Debug
  33 import Language.TCT.Utils
  34 import Language.TCT hiding (Parser)
  35 import Language.XML
  36 import Text.Blaze.XML ()
  37
  38 -- | Main entry point
  39 --
  40 -- NOTE: 'XmlNode' are still annotated with 'Cell',
  41 --       but nothing is done to preserve any ordering amongst them,
  42 --       because 'Node's sometimes need to be reordered
  43 --       (eg. about/title may have a title from the section before,
  44 --       hence outside of about).
  45 --       Still holding: @'cell_begin' < 'cell_end'@ and 'Cell' nesting.
  46 document :: Roots -> XMLs
  47 document doc =
  48         -- (`S.evalState` def) $
  49         case Seq.viewl doc of
  50          sec@(Tree (unCell -> NodeHeader HeaderSection{}) _body) :< foot ->
  51                 let (titles, content) = partitionSection sec in
  52                 case Seq.viewl titles of
  53                  (unTree -> Cell bt et _) :< _ ->
  54                         xmlify def
  55                          { inh_titles = titles
  56                          , inh_figure = True
  57                          } contentWithAbout <>
  58                         xmlify def foot
  59                         where
  60                         contentWithAbout =
  61                                 case Seq.findIndexL isAbout content of
  62                                  Nothing -> Tree (Cell bt et $ NodeHeader $ HeaderColon "about" "") mempty <| content
  63                                  Just{} -> content
  64                         isAbout = \case
  65                          (unTree -> (unCell -> NodeHeader (HeaderColon "about" _wh))) -> True
  66                          _ -> False
  67                  _ -> xmlify def doc
  68          _ -> xmlify def doc
  69
  70 partitionSection :: Root -> (Roots, Roots)
  71 partitionSection (Tree (unCell -> NodeHeader (HeaderSection lvlPar)) body) =
  72         case Seq.viewl body of
  73          EmptyL -> mempty
  74          title@(unTree -> Cell _bt et NodePara) :< rest ->
  75                 let (subtitles, content) = spanlSubtitles et rest in
  76                 (title <| (subtitles >>= subTrees), content)
  77                 where
  78                 spanlSubtitles ep ts =
  79                         case Seq.viewl ts of
  80                          sub@(unTree -> Cell bs es (NodeHeader (HeaderSection lvlSub))) :< rs
  81                                 | lvlSub <= lvlPar
  82                                 , pos_line bs - pos_line ep <= 1 ->
  83                                 let (subs, ts') = spanlSubtitles es rs in
  84                                 (sub <| subs, ts')
  85                          _ -> (mempty, ts)
  86          _ -> (mempty, body)
  87 partitionSection _ = mempty
  88
  89 -- * Type 'Inh'
  90 data Inh
  91  =   Inh
  92  {   inh_figure :: Bool
  93  ,   inh_para   :: [Inh -> Root -> XML]
  94  ,   inh_titles :: Roots
  95  }
  96 instance Default Inh where
  97         def = Inh
  98          { inh_figure = False
  99          , inh_para   = List.repeat elementPara
 100          , inh_titles = mempty
 101          }
 102
 103 -- ** 'inh_para'
 104 elementPara :: Inh -> Root -> XML
 105 elementPara inh (Tree c ts) = Tree (XmlElem "para" <$ c) $ xmlify inh ts
 106
 107 elementTitle :: Inh -> Root -> XML
 108 elementTitle inh (Tree c ts) = Tree (XmlElem "title" <$ c) $ xmlify inh ts
 109
 110 elementName :: Inh -> Root -> XML
 111 elementName inh (Tree c ts) = Tree (XmlElem "name" <$ c) $ xmlify inh ts
 112
 113 attributeName :: Inh -> Root -> XML
 114 attributeName _inh (Tree c ts) = tree0 (XmlAttr "name" (Plain.document ts) <$ c)
 115
 116 -- * Class 'Xmlify'
 117 class Xmlify a where
 118         xmlify :: Inh -> a -> XMLs
 119 instance Xmlify Roots where
 120         xmlify inh roots =
 121                 case Seq.viewl roots of
 122                  EmptyL -> mempty
 123                  r@(Tree cr@(Cell _br _er nr) ts) :< rs ->
 124                         case nr of
 125                         ----------------------
 126                          -- NOTE: HeaderColon becomes parent
 127                          -- of any continuous following-sibling HeaderBar or HeaderGreat
 128                          NodeHeader (HeaderColon n _wh)
 129                           | (span, rest) <- spanlHeaderColon rs
 130                           , not $ null span ->
 131                                 xmlify inh (Tree cr (ts<>span)) <>
 132                                 xmlify inh rest
 133                                 where
 134                                 spanlHeaderColon :: Roots -> (Roots, Roots)
 135                                 spanlHeaderColon =
 136                                         Seq.spanl $ \case
 137                                          Tree (unCell -> NodeHeader (HeaderBar   m _)) _ -> m == n
 138                                          Tree (unCell -> NodeHeader (HeaderGreat m _)) _ -> m == n
 139                                          _ -> False
 140                         ----------------------
 141                          -- NOTE: gather HeaderBrackets
 142                          NodeHeader HeaderBrackets{}
 143                           | (span,rest) <- spanlBrackets roots
 144                           , not (null span) ->
 145                                 (<| xmlify inh rest) $
 146                                 element "references" $
 147                                         span >>= xmlify inh
 148                                 where
 149                                 spanlBrackets :: Roots -> (Roots, Roots)
 150                                 spanlBrackets =
 151                                         Seq.spanl $ \case
 152                                          Tree (unCell -> NodeHeader HeaderBrackets{}) _ -> True
 153                                          _ -> False
 154                         ----------------------
 155                          -- NOTE: merge adjacent NodeText-s, shouldn't be needed, but just in case.
 156                          NodeText x
 157                           | Tree (cy@(unCell -> NodeText y)) ys :< rs' <- Seq.viewl rs ->
 158                                 xmlify inh $ Tree (NodeText <$> (x <$ cr) <> (y <$ cy)) (ts <> ys) <| rs'
 159                         ----------------------
 160                          -- NOTE: detect [some text](http://some.url) or [SomeRef]
 161                          NodePair PairParen
 162                           | Tree (Cell bb eb (NodePair PairBracket)) bracket :< rs' <- Seq.viewl rs ->
 163                                 (<| xmlify inh rs') $
 164                                 case bracket of
 165                                  (toList -> [unTree -> Cell bl el (NodeToken (TokenLink lnk))]) ->
 166                                         element "eref" $
 167                                                 xmlAttrs [Cell bl el ("to",lnk)] <>
 168                                                 xmlify inh ts
 169                                  _ ->
 170                                         element "rref" $
 171                                                 xmlAttrs [Cell bb eb ("to",Plain.document bracket)] <>
 172                                                 xmlify inh ts
 173                         ----------------------
 174                          -- NOTE: gather HeaderDash
 175                          _ | (span, rest) <- spanlItems (==HeaderDash) roots
 176                            , not $ null span ->
 177                                 (<| xmlify inh rest) $
 178                                 element "ul" $
 179                                         span >>= xmlify inh{inh_para=List.repeat elementPara}
 180                         ----------------------
 181                          -- NOTE: gather HeaderDot
 182                            | (span,rest) <- spanlItems (\case HeaderDot{} -> True; _ -> False) roots
 183                            , not $ null span ->
 184                                 (<| xmlify inh rest) $
 185                                 element "ol" $
 186                                         span >>= xmlify inh{inh_para=List.repeat elementPara}
 187                                 where
 188                                 spanlItems :: (Header -> Bool) -> Roots -> (Roots, Roots)
 189                                 spanlItems liHeader =
 190                                         Seq.spanl $ \(unTree -> (unCell -> nod)) ->
 191                                                 case nod of
 192                                                  NodeHeader (HeaderColon "li" _wh) -> True
 193                                                  NodeHeader hdr -> liHeader hdr
 194                                                  NodePair (PairElem "li" _as) -> True
 195                                                  _ -> False
 196                         ----------------------
 197                          NodePara | para:inh_para <- inh_para inh ->
 198                                 para inh r <|
 199                                 -- para (() <$ cr) (xmlify inh ts) <|
 200                                 xmlify inh{inh_para} rs
 201                         ----------------------
 202                          -- NOTE: context-free Root
 203                          _ ->
 204                                 xmlify inh r <>
 205                                 xmlify inh rs
 206                         where
 207                         element :: XmlName -> XMLs -> XML
 208                         element n = Tree (XmlElem n <$ cr)
 209 instance Xmlify Root where
 210         xmlify inh tn@(Tree (Cell bn en nod) ts) =
 211                 case nod of
 212                 ----------------------
 213                  NodePara ->
 214                         case inh_para inh of
 215                          [] -> xmlify inh ts
 216                          para:_ -> Seq.singleton $ para inh tn -- para (() <$ cn) $ xmlify inh ts
 217                 ----------------------
 218                  NodeHeader hdr ->
 219                         case hdr of
 220                         --
 221                          HeaderSection{} ->
 222                                 Seq.singleton $
 223                                 element "section" $ head <> xmlify inh' body
 224                                 where
 225                                 (titles, content) = partitionSection tn
 226                                 (attrs, body)     = partitionAttrs content
 227                                 head =
 228                                         case Seq.viewl titles of
 229                                          EmptyL -> mempty
 230                                          title@(unTree -> ct) :< subtitles ->
 231                                                 xmlAttrs (attrs `defaultAttr` (ct $> ("id",getAttrId title))) <>
 232                                                 xmlify inh{inh_para=List.repeat elementTitle} title <>
 233                                                 aliases
 234                                                 where
 235                                                 aliases =
 236                                                         subtitles >>= \subtitle@(unTree -> cs) ->
 237                                                                 return $
 238                                                                 Tree (cs $> XmlElem "alias") $
 239                                                                         xmlAttrs [cs $> ("id",getAttrId subtitle)]
 240                                 inh' = inh
 241                                  { inh_para   = List.repeat elementPara
 242                                  , inh_figure = True
 243                                  }
 244                         --
 245                          HeaderColon n _wh ->
 246                                 let (attrs,body) = partitionAttrs ts in
 247                                 case n of
 248                                 -- NOTE: insert titles into <about>.
 249                                  "about" ->
 250                                         Seq.singleton $
 251                                         element "about" $
 252                                                 xmlify inh' (inh_titles inh) <>
 253                                                 xmlAttrs attrs <>
 254                                                 xmlify inh'{inh_figure=False} body
 255                                 -- NOTE: in <figure> mode, unreserved elements become <figure>
 256                                  _ | inh_figure inh && n`List.notElem`elems || TL.null n ->
 257                                         Seq.singleton $
 258                                         element "figure" $
 259                                                 -- xmlAttrs (setAttr (Cell en en ("type",n)) attrs) <>
 260                                                 xmlAttrs (attrs `defaultAttr` Cell bn bn ("type", n)) <>
 261                                                 case toList body of
 262                                                  [Tree0{}] -> xmlify inh'{inh_para = List.repeat elementPara} body
 263                                                  _         -> xmlify inh'{inh_para = elementTitle : List.repeat elementPara} body
 264                                 -- NOTE: reserved elements
 265                                  _ ->
 266                                         Seq.singleton $
 267                                         element (xmlLocalName n) $
 268                                                 xmlAttrs attrs <>
 269                                                 xmlify inh' body
 270                                 where
 271                                 inh' = inh
 272                                  { inh_para =
 273                                         case n of
 274                                          "about"     -> List.repeat elementTitle
 275                                          "reference" -> elementTitle : List.repeat elementPara
 276                                          "serie"     -> List.repeat attributeName
 277                                          "author"    -> List.repeat attributeName
 278                                          "editor"    -> List.repeat attributeName
 279                                          "org"       -> List.repeat attributeName
 280                                          "note"      -> List.repeat elementPara
 281                                          _           -> []
 282                                  }
 283                         --
 284                          HeaderBar n wh ->
 285                                 if inh_figure inh && n`List.notElem`elems || TL.null n
 286                                 then
 287                                         Seq.singleton $
 288                                         element "artwork" $
 289                                                 xmlAttrs (Seq.singleton $ Cell bn bn ("type", n)) <>
 290                                                 xmlify inh{inh_para=[]} ts
 291                                 else
 292                                         xmlify inh $
 293                                                 Tree (Cell bn en $ NodeHeader $ HeaderColon n wh) ts
 294                         --
 295                          HeaderGreat n _wh ->
 296                                 Seq.singleton $
 297                                 let (attrs,body) = partitionAttrs ts in
 298                                 element "quote" $
 299                                         xmlAttrs (attrs `defaultAttr` Cell bn bn ("type", n)) <>
 300                                         xmlify inh{inh_para=List.repeat elementPara} body
 301                         --
 302                          HeaderEqual n _wh ->
 303                                 Seq.singleton $
 304                                 Tree0 $ cell $ XmlAttr (xmlLocalName n) $
 305                                         Plain.text (Plain.setStart ts def{Plain.state_escape = False}) ts
 306                         --
 307                          HeaderDot n ->
 308                                 Seq.singleton $
 309                                 element "li" $
 310                                         xmlAttrs (Seq.singleton $ Cell bn bn{pos_column=pos_column bn + int (TL.length n)} ("name", n)) <>
 311                                         xmlify inh ts
 312                         --
 313                          HeaderDash -> Seq.singleton $ element "li" $ xmlify inh ts
 314                         --
 315                          HeaderDashDash ->
 316                                 Seq.singleton $ Tree0 $ cell $
 317                                         XmlComment $ Plain.document ts
 318                         --
 319                          HeaderBrackets ident ->
 320                                 let (attrs,body) = partitionAttrs ts in
 321                                 Seq.singleton $
 322                                 element "reference" $
 323                                         xmlAttrs (setAttr (Cell en en ("id",ident)) attrs) <>
 324                                         xmlify inh'{inh_para = elementTitle : elementTitle : List.repeat elementPara} body
 325                                 where
 326                                 inh' = inh{inh_figure = False}
 327                         --
 328                          HeaderDotSlash p ->
 329                                 Seq.singleton $
 330                                 element "include" $
 331                                         xmlAttrs [cell ("href",TL.pack $ FP.replaceExtension p "dtc")] <>
 332                                         xmlify inh ts
 333                 ----------------------
 334                  NodePair pair ->
 335                         case pair of
 336                          PairBracket | to <- Plain.document ts
 337                                      , TL.all (\c -> Char.isAlphaNum c || Char.isSymbol c) to ->
 338                                 Seq.singleton $
 339                                 element "rref" $
 340                                         xmlAttrs [cell ("to",to)]
 341                          PairStar      -> Seq.singleton $ element "b"    $ xmlify inh ts
 342                          PairSlash     -> Seq.singleton $ element "i"    $ xmlify inh ts
 343                          PairBackquote -> Seq.singleton $ element "code" $ xmlify inh ts
 344                          PairFrenchquote ->
 345                                 Seq.singleton $
 346                                 element "q" $
 347                                         xmlify inh ts
 348                                 {-
 349                                 case ts of
 350                                  (Seq.viewl -> Tree0 (Cell bl el (TokenPlain l)) :< ls) ->
 351                                         case Seq.viewr ls of
 352                                          m :> Tree0 (Cell br er (TokenPlain r)) ->
 353                                                 xmlify inh $
 354                                                         Tree0 (Cell bl el (TokenPlain (Text.dropWhile Char.isSpace l)))
 355                                                          <|(m|>Tree0 (Cell br er (TokenPlain (Text.dropWhileEnd Char.isSpace r))))
 356                                          _ ->
 357                                                 xmlify inh $
 358                                                         Tree0 (Cell bl el (TokenPlain (Text.dropAround Char.isSpace l))) <| ls
 359                                  (Seq.viewr -> rs :> Tree0 (Cell br er (TokenPlain r))) ->
 360                                         xmlify inh $
 361                                                 rs |> Tree0 (Cell br er (TokenPlain (Text.dropAround Char.isSpace r)))
 362                                  _ -> xmlify inh ts
 363                                 -}
 364                          PairHash ->
 365                                 Seq.singleton $
 366                                 element "ref" $
 367                                         xmlAttrs [cell ("to",Plain.document ts)]
 368                          PairElem name attrs ->
 369                                 Seq.singleton $
 370                                 element (xmlLocalName name) $
 371                                         xmlAttrs (Seq.fromList $ (\(_wh,ElemAttr{..}) ->
 372                                                 cell (xmlLocalName elemAttr_name,elemAttr_value)) <$> attrs) <>
 373                                         xmlify inh ts
 374                          _ ->
 375                                 Seq.singleton (Tree0 $ Cell bn bn' $ XmlText open) `unionXml`
 376                                 xmlify inh ts `unionXml`
 377                                 Seq.singleton (Tree0 $ Cell en' en $ XmlText close)
 378                                 where
 379                                 (open, close) = pairBorders pair ts
 380                                 bn' = bn{pos_column=pos_column bn + int (TL.length open)}
 381                                 en' = en{pos_column=pos_column bn - int (TL.length close)}
 382                 ----------------------
 383                  NodeText t -> Seq.singleton $ Tree0 $ cell $ XmlText t
 384                 ----------------------
 385                  NodeToken tok ->
 386                         case tok of
 387                          TokenEscape c -> Seq.singleton $ Tree0 $ cell $ XmlText $ TL.singleton c
 388                          TokenText t   -> Seq.singleton $ Tree0 $ cell $ XmlText t
 389                          TokenTag t    -> Seq.singleton $ element "ref"  $ xmlAttrs [cell ("to",t)]
 390                          TokenLink lnk -> Seq.singleton $ element "eref" $ xmlAttrs [cell ("to",lnk)]
 391                 ----------------------
 392                  NodeLower n as ->
 393                         Seq.singleton $
 394                         element "artwork" $
 395                                 xmlify inh ts
 396                 where
 397                 cell :: a -> Cell a
 398                 cell = Cell bn en
 399                 element :: XmlName -> XMLs -> XML
 400                 element n = Tree (cell $ XmlElem n)
 401 instance Xmlify (Seq (Cell (XmlName,TL.Text))) where
 402         xmlify _inh = xmlAttrs
 403
 404 -- * Elements
 405
 406 -- | Reserved elements' name
 407 elems :: Set TL.Text
 408 elems =
 409  [ "about"
 410  , "abstract"
 411  , "address"
 412  , "alias"
 413  , "annotation"
 414  , "area"
 415  , "artwork"
 416  , "aside"
 417  , "audio"
 418  , "author"
 419  , "authors"
 420  , "bcp14"
 421  , "br"
 422  , "call"
 423  , "city"
 424  , "code"
 425  , "comment"
 426  , "comments"
 427  , "country"
 428  , "date"
 429  , "dd"
 430  , "define"
 431  , "del"
 432  , "div"
 433  , "dl"
 434  , "document"
 435  , "dt"
 436  , "editor"
 437  , "email"
 438  , "embed"
 439  , "eref"
 440  , "fax"
 441  , "feed"
 442  , "feedback"
 443  , "figure"
 444  , "filter"
 445  , "format"
 446  , "from"
 447  , "h"
 448  , "hi"
 449  , "html5"
 450  , "i"
 451  , "index"
 452  , "iref"
 453  , "keyword"
 454  , "li"
 455  , "link"
 456  , "name"
 457  , "note"
 458  , "ol"
 459  , "organization"
 460  , "para"
 461  , "postamble"
 462  , "preamble"
 463  , "q"
 464  , "ref"
 465  , "reference"
 466  , "references"
 467  , "region"
 468  , "rref"
 469  , "sc"
 470  , "section"
 471  , "serie"
 472  , "source"
 473  , "span"
 474  , "street"
 475  , "style"
 476  , "sub"
 477  , "sup"
 478  , "table"
 479  , "tbody"
 480  , "td"
 481  , "tel"
 482  , "tfoot"
 483  , "title"
 484  , "th"
 485  , "thead"
 486  , "toc"
 487  , "tof"
 488  , "tr"
 489  , "tt"
 490  , "u"
 491  , "ul"
 492  , "uri"
 493  , "version"
 494  , "video"
 495  , "workgroup"
 496  , "xml"
 497  , "zipcode"
 498  ]
 499
 500 -- * Attributes
 501
 502 -- | Convenient alias, forcing the types
 503 xmlAttrs :: Seq (Cell (XmlName,TL.Text)) -> XMLs
 504 xmlAttrs = (Tree0 . (uncurry XmlAttr <$>) <$>)
 505
 506 -- | Extract attributes
 507 partitionAttrs :: Roots -> (Seq (Cell (XmlName, TL.Text)), Roots)
 508 partitionAttrs ts = (attrs,cs)
 509         where
 510         (as,cs) = (`Seq.partition` ts) $ \case
 511          Tree (unCell -> NodeHeader (HeaderEqual n _wh)) _cs -> not $ TL.null n
 512          _ -> False
 513         attrs = attr <$> as
 514         attr = \case
 515          Tree (Cell bp ep (NodeHeader (HeaderEqual n _wh))) a ->
 516                 Cell bp ep (xmlLocalName n, v)
 517                 where
 518                 v = Plain.text (Plain.setStart a def{Plain.state_escape = False}) a
 519          _ -> undefined
 520
 521 getAttrId :: Root -> TL.Text
 522 getAttrId = Plain.document . Seq.singleton
 523
 524 setAttr ::
 525  Cell (XmlName, TL.Text) ->
 526  Seq (Cell (XmlName, TL.Text)) ->
 527  Seq (Cell (XmlName, TL.Text))
 528 setAttr a@(unCell -> (k, _v)) as =
 529         case Seq.findIndexL (\(unCell -> (n,_v)) -> n == k) as of
 530          Just idx -> Seq.update idx a as
 531          Nothing -> a <| as
 532
 533 defaultAttr ::
 534  Seq (Cell (XmlName, TL.Text)) ->
 535  Cell (XmlName, TL.Text) ->
 536  Seq (Cell (XmlName, TL.Text))
 537 defaultAttr as a@(unCell -> (k, _v)) =
 538         case Seq.findIndexL (\(unCell -> (n,_v)) -> n == k) as of
 539          Just _idx -> as
 540          Nothing -> a <| as
 541
 542 -- * Text
 543
 544 -- | Unify two 'XMLs', merging border 'XmlText's if any.
 545 unionXml :: XMLs -> XMLs -> XMLs
 546 unionXml x y =
 547         case (Seq.viewr x, Seq.viewl y) of
 548          (xs :> x0, y0 :< ys) ->
 549                 case (x0,y0) of
 550                  (  Tree0 (Cell bx ex (XmlText tx))
 551                   , Tree0 (Cell by ey (XmlText ty)) ) ->
 552                         xs `unionXml`
 553                         Seq.singleton (Tree0 $ (XmlText <$>) $ Cell bx ex tx <> Cell by ey ty) `unionXml`
 554                         ys
 555                  _ -> x <> y
 556          (Seq.EmptyR, _) -> y
 557          (_, Seq.EmptyL) -> x
 558
 559 unionsXml :: Foldable f => f XMLs -> XMLs
 560 unionsXml = foldl' unionXml mempty