src/Gargantext/API/Node.hs

   1 {-|
   2 Module      : Gargantext.API.Node
   3 Description : Server API
   4 Copyright   : (c) CNRS, 2017-Present
   5 License     : AGPL + CECILL v3
   6 Maintainer  : team@gargantext.org
   7 Stability   : experimental
   8 Portability : POSIX
   9
  10 -- TODO-SECURITY: Critical
  11
  12 -- TODO-ACCESS: CanGetNode
  13 -- TODO-EVENTS: No events as this is a read only query.
  14 Node API
  15 -------------------------------------------------------------------
  16 -- TODO-ACCESS: access by admin only.
  17 --              At first let's just have an isAdmin check.
  18 --              Later: check userId CanDeleteNodes Nothing
  19 -- TODO-EVENTS: DeletedNodes [NodeId]
  20 --              {"tag": "DeletedNodes", "nodes": [Int*]}
  21
  22 -}
  23
  24 {-# OPTIONS_GHC -fno-warn-orphans #-}
  25
  26 {-# LANGUAGE ScopedTypeVariables  #-}
  27 {-# LANGUAGE TemplateHaskell      #-}
  28 {-# LANGUAGE TypeOperators        #-}
  29
  30 module Gargantext.API.Node
  31   where
  32
  33 import Data.Aeson (FromJSON, ToJSON)
  34 import Data.Maybe
  35 import Data.Swagger
  36 import Data.Text (Text())
  37 import GHC.Generics (Generic)
  38 import Gargantext.API.Admin.Auth (withAccess, PathId(..))
  39 import Gargantext.API.Metrics
  40 import Gargantext.API.Ngrams (TabType(..), TableNgramsApi, apiNgramsTableCorpus)
  41 import Gargantext.API.Node.New
  42 import Gargantext.API.Prelude
  43 import Gargantext.API.Search (SearchDocsAPI, searchDocs, SearchPairsAPI, searchPairs)
  44 import Gargantext.API.Table
  45 import Gargantext.Core.Types (NodeTableResult)
  46 import Gargantext.Core.Types.Individu (User(..))
  47 import Gargantext.Core.Types.Main (Tree, NodeTree)
  48 import Gargantext.Database.Action.Flow.Pairing (pairing)
  49 import Gargantext.Database.Admin.Types.Node
  50 import Gargantext.Database.Prelude -- (Cmd, CmdM)
  51 import Gargantext.Database.Query.Facet (FacetDoc, OrderBy(..))
  52 import Gargantext.Database.Query.Table.Node
  53 import Gargantext.Database.Query.Table.Node.Children (getChildren)
  54 import Gargantext.Database.Query.Table.Node.Error (HasNodeError(..))
  55 import Gargantext.Database.Query.Table.Node.Update (Update(..), update)
  56 import Gargantext.Database.Query.Table.Node.UpdateOpaleye (updateHyperdata)
  57 import Gargantext.Database.Query.Table.Node.User
  58 import Gargantext.Database.Query.Table.NodeNode
  59 import Gargantext.Database.Query.Tree (tree, TreeMode(..))
  60 import Gargantext.Prelude
  61 import Gargantext.Viz.Phylo.API (PhyloAPI, phyloAPI)
  62 import Servant
  63 import Test.QuickCheck (elements)
  64 import Test.QuickCheck.Arbitrary (Arbitrary, arbitrary)
  65 import qualified Gargantext.API.Node.Share  as Share
  66 import qualified Gargantext.API.Node.Update as Update
  67 import qualified Gargantext.Database.Action.Delete as Action (deleteNode)
  68 import qualified Gargantext.Database.Query.Table.Node.Update as U (update, Update(..))
  69
  70 {-
  71 import qualified Gargantext.Text.List.Learn as Learn
  72 import qualified Data.Vector as Vec
  73 --}
  74
  75 -- | Admin NodesAPI
  76 -- TODO
  77 type NodesAPI  = Delete '[JSON] Int
  78
  79 -- | Delete Nodes
  80 -- Be careful: really delete nodes
  81 -- Access by admin only
  82 nodesAPI :: [NodeId] -> GargServer NodesAPI
  83 nodesAPI = deleteNodes
  84
  85 ------------------------------------------------------------------------
  86 -- | TODO-ACCESS: access by admin only.
  87 -- At first let's just have an isAdmin check.
  88 -- Later: CanAccessAnyNode or (CanGetAnyNode, CanPutAnyNode)
  89 -- To manage the Users roots
  90 -- TODO-EVENTS:
  91 --   PutNode ?
  92 -- TODO needs design discussion.
  93 type Roots =  Get    '[JSON] [Node HyperdataUser]
  94          :<|> Put    '[JSON] Int -- TODO
  95
  96 -- | TODO: access by admin only
  97 roots :: GargServer Roots
  98 roots = getNodesWithParentId Nothing
  99     :<|> pure (panic "not implemented yet") -- TODO use patch map to update what we need
 100
 101 -------------------------------------------------------------------
 102 -- | Node API Types management
 103 -- TODO-ACCESS : access by users
 104 -- No ownership check is needed if we strictly follow the capability model.
 105 --
 106 -- CanGetNode (Node, Children, TableApi, TableNgramsApiGet, PairingApi, ChartApi,
 107 --             SearchAPI)
 108 -- CanRenameNode (or part of CanEditNode?)
 109 -- CanCreateChildren (PostNodeApi)
 110 -- CanEditNode / CanPutNode TODO not implemented yet
 111 -- CanDeleteNode
 112 -- CanPatch (TableNgramsApi)
 113 -- CanFavorite
 114 -- CanMoveToTrash
 115
 116 type NodeAPI a = Get '[JSON] (Node a)
 117              :<|> "rename" :> RenameApi
 118              :<|> PostNodeApi -- TODO move to children POST
 119              :<|> PostNodeAsync
 120              :<|> ReqBody '[JSON] a :> Put    '[JSON] Int
 121              :<|> "update"     :> Update.API
 122              :<|> Delete '[JSON] Int
 123              :<|> "children"  :> ChildrenApi a
 124
 125              -- TODO gather it
 126              :<|> "table"      :> TableApi
 127              :<|> "ngrams"     :> TableNgramsApi
 128
 129              :<|> "category"   :> CatApi
 130              :<|> "search"     :> SearchDocsAPI
 131              :<|> "share"      :> Share.API
 132
 133              -- Pairing utilities
 134              :<|> "pairwith"   :> PairWith
 135              :<|> "pairs"      :> Pairs
 136              :<|> "pairing"    :> PairingApi
 137              :<|> "searchPair" :> SearchPairsAPI
 138
 139              -- VIZ
 140              :<|> "metrics"   :> ScatterAPI
 141              :<|> "chart"     :> ChartApi
 142              :<|> "pie"       :> PieApi
 143              :<|> "tree"      :> TreeApi
 144              :<|> "phylo"     :> PhyloAPI
 145              -- :<|> "add"       :> NodeAddAPI
 146              :<|> "move"      :> MoveAPI
 147
 148 -- TODO-ACCESS: check userId CanRenameNode nodeId
 149 -- TODO-EVENTS: NodeRenamed RenameNode or re-use some more general NodeEdited...
 150 type RenameApi = Summary " Rename Node"
 151                :> ReqBody '[JSON] RenameNode
 152                :> Put     '[JSON] [Int]
 153
 154 type PostNodeApi = Summary " PostNode Node with ParentId as {id}"
 155                  :> ReqBody '[JSON] PostNode
 156                  :> Post    '[JSON] [NodeId]
 157
 158 type ChildrenApi a = Summary " Summary children"
 159                  :> QueryParam "type"   NodeType
 160                  :> QueryParam "offset" Int
 161                  :> QueryParam "limit"  Int
 162                  -- :> Get '[JSON] [Node a]
 163                  :> Get '[JSON] (NodeTableResult a)
 164
 165 ------------------------------------------------------------------------
 166 type NodeNodeAPI a = Get '[JSON] (Node a)
 167
 168 nodeNodeAPI :: forall proxy a. (JSONB a, ToJSON a)
 169             => proxy a
 170             -> UserId
 171             -> CorpusId
 172             -> NodeId
 173             -> GargServer (NodeNodeAPI a)
 174 nodeNodeAPI p uId cId nId = withAccess (Proxy :: Proxy (NodeNodeAPI a)) Proxy uId (PathNodeNode cId nId) nodeNodeAPI'
 175   where
 176     nodeNodeAPI' :: GargServer (NodeNodeAPI a)
 177     nodeNodeAPI' = getNodeWith nId p
 178
 179 ------------------------------------------------------------------------
 180 -- TODO: make the NodeId type indexed by `a`, then we no longer need the proxy.
 181 nodeAPI :: forall proxy a.
 182        ( JSONB a
 183        , FromJSON a
 184        , ToJSON a
 185        ) => proxy a
 186          -> UserId
 187          -> NodeId
 188          -> GargServer (NodeAPI a)
 189 nodeAPI p uId id' = withAccess (Proxy :: Proxy (NodeAPI a)) Proxy uId (PathNode id') nodeAPI'
 190   where
 191     nodeAPI' :: GargServer (NodeAPI a)
 192     nodeAPI' =  getNodeWith   id' p
 193            :<|> rename        id'
 194            :<|> postNode  uId id'
 195            :<|> postNodeAsyncAPI  uId id'
 196            :<|> putNode       id'
 197            :<|> Update.api  uId id'
 198            :<|> Action.deleteNode (RootId $ NodeId uId) id'
 199            :<|> getChildren   id' p
 200
 201            -- TODO gather it
 202            :<|> tableApi             id'
 203            :<|> apiNgramsTableCorpus id'
 204
 205            :<|> catApi      id'
 206            :<|> searchDocs  id'
 207            :<|> Share.api   id'
 208            -- Pairing Tools
 209            :<|> pairWith    id'
 210            :<|> pairs       id'
 211            :<|> getPair     id'
 212            :<|> searchPairs id'
 213
 214            :<|> scatterApi id'
 215            :<|> chartApi   id'
 216            :<|> pieApi     id'
 217            :<|> treeApi    id'
 218            :<|> phyloAPI   id' uId
 219            :<|> moveNode   (RootId $ NodeId uId) id'
 220            -- :<|> nodeAddAPI id'
 221            -- :<|> postUpload id'
 222
 223 ------------------------------------------------------------------------
 224 data RenameNode = RenameNode { r_name :: Text }
 225   deriving (Generic)
 226
 227 -- TODO unPrefix "r_" FromJSON, ToJSON, ToSchema, adapt frontend.
 228 instance FromJSON  RenameNode
 229 instance ToJSON    RenameNode
 230 instance ToSchema  RenameNode
 231 instance Arbitrary RenameNode where
 232   arbitrary = elements [RenameNode "test"]
 233 ------------------------------------------------------------------------
 234 ------------------------------------------------------------------------
 235 type CatApi =  Summary " To Categorize NodeNodes: 0 for delete, 1/null neutral, 2 favorite"
 236             :> ReqBody '[JSON] NodesToCategory
 237             :> Put     '[JSON] [Int]
 238
 239 data NodesToCategory = NodesToCategory { ntc_nodesId :: [NodeId]
 240                                        , ntc_category :: Int
 241                                        }
 242   deriving (Generic)
 243
 244 -- TODO unPrefix "ntc_" FromJSON, ToJSON, ToSchema, adapt frontend.
 245 instance FromJSON  NodesToCategory
 246 instance ToJSON    NodesToCategory
 247 instance ToSchema  NodesToCategory
 248
 249 catApi :: CorpusId -> GargServer CatApi
 250 catApi = putCat
 251   where
 252     putCat :: CorpusId -> NodesToCategory -> Cmd err [Int]
 253     putCat cId cs' = nodeNodesCategory $ map (\n -> (cId, n, ntc_category cs')) (ntc_nodesId cs')
 254
 255 ------------------------------------------------------------------------
 256 -- TODO adapt FacetDoc -> ListDoc (and add type of document as column)
 257 -- Pairing utilities to move elsewhere
 258 type PairingApi = Summary " Pairing API"
 259                 :> QueryParam "view"   TabType
 260                 -- TODO change TabType -> DocType (CorpusId for pairing)
 261                 :> QueryParam "offset" Int
 262                 :> QueryParam "limit"  Int
 263                 :> QueryParam "order"  OrderBy
 264                 :> Get '[JSON] [FacetDoc]
 265
 266 ----------
 267 type Pairs    = Summary "List of Pairs"
 268               :> Get '[JSON] [AnnuaireId]
 269 pairs :: CorpusId -> GargServer Pairs
 270 pairs cId = do
 271   ns <- getNodeNode cId
 272   pure $ map _nn_node2_id ns
 273
 274 type PairWith = Summary "Pair a Corpus with an Annuaire"
 275               :> "annuaire" :> Capture "annuaire_id" AnnuaireId
 276               :> "list"     :> Capture "list_id"     ListId
 277               :> Post '[JSON] Int
 278
 279 pairWith :: CorpusId -> GargServer PairWith
 280 pairWith cId aId lId = do
 281   r <- pairing cId aId lId
 282   _ <- insertNodeNode [ NodeNode cId aId Nothing Nothing]
 283   pure r
 284
 285 ------------------------------------------------------------------------
 286
 287 ------------------------------------------------------------------------
 288 type TreeAPI   = QueryParams "type" NodeType :> Get '[JSON] (Tree NodeTree)
 289
 290 treeAPI :: NodeId -> GargServer TreeAPI
 291 treeAPI = tree Advanced
 292
 293 ------------------------------------------------------------------------
 294 -- | TODO Check if the name is less than 255 char
 295 rename :: NodeId -> RenameNode -> Cmd err [Int]
 296 rename nId (RenameNode name') = U.update (U.Rename nId name')
 297
 298 putNode :: forall err a. (HasNodeError err, JSONB a, ToJSON a)
 299         => NodeId
 300         -> a
 301         -> Cmd err Int
 302 putNode n h = fromIntegral <$> updateHyperdata n h
 303
 304 -------------------------------------------------------------
 305 type MoveAPI  = Summary "Move Node endpoint"
 306               :> Capture "parent_id" ParentId
 307               :> Put '[JSON] [Int]
 308
 309 moveNode :: User
 310          -> NodeId
 311          -> ParentId
 312          -> Cmd err [Int]
 313 moveNode _u n p = update (Move n p)
 314 -------------------------------------------------------------
 315 -------------------------------------------------------------