flake.nix

   1 # SPDX-FileCopyrightText: 2025 Julien Moutinho <julm+worksheets@sourcephile.fr>
   2 # SPDX-License-Identifier: CC0-1.0
   3 {
   4   description = "Worksheet";
   5   inputs = {
   6     nixpkgs.url = "flake:nixpkgs";
   7     git-hooks.url = "github:cachix/git-hooks.nix";
   8     git-hooks.inputs.nixpkgs.follows = "nixpkgs";
   9   };
  10   outputs =
  11     inputs:
  12     let
  13       pkg = "worksheets";
  14       lib = inputs.nixpkgs.lib;
  15       fileInputs = with lib.fileset; toSource {
  16         root = ./.;
  17         fileset = unions [
  18           ./worksheets.cabal
  19           #./ChangeLog.md
  20           #./Readme.md
  21           ./LICENSES
  22           (fileFilter (file: lib.any file.hasExt [ "hs" ]) ./src)
  23           (fileFilter (file: lib.any file.hasExt [ "css" ]) ./style)
  24           (fileFilter (file: lib.any file.hasExt [ "hs" "html" "txt" ]) ./tests)
  25           #(fileFilter (file: lib.any file.hasExt [ "hs" ]) ./app)
  26         ];
  27       };
  28       # Helper to build for each system in `lib.systems.flakeExposed`.
  29       perSystem =
  30         f:
  31         lib.genAttrs lib.systems.flakeExposed (
  32           system:
  33           f rec {
  34             inherit system;
  35             #pkgs = import inputs.nixpkgs { inherit system; };
  36             pkgs = inputs.nixpkgs.legacyPackages.${system};
  37             haskellPackages = pkgs.haskellPackages.extend (with pkgs.haskell.lib; finalHaskellPkgs: previousHaskellPkgs: {
  38               ${pkg} = buildFromSdist (finalHaskellPkgs.callCabal2nix pkg fileInputs { });
  39             });
  40           }
  41         );
  42     in
  43     {
  44       # `nix -L build`
  45       packages = perSystem ({ haskellPackages, ... }: {
  46         default = haskellPackages.${pkg};
  47       });
  48       # `nix -L develop`  or  `direnv allow`
  49       devShells = perSystem ({ pkgs, haskellPackages, system, ... }: {
  50         default =
  51           haskellPackages.shellFor {
  52             packages = ps: [ ps.${pkg} ];
  53             nativeBuildInputs = [
  54               haskellPackages.cabal-fmt
  55               haskellPackages.cabal-install
  56               haskellPackages.ghcid
  57               haskellPackages.haskell-language-server
  58               haskellPackages.hlint
  59               #pkgs.git-chglog
  60               pkgs.reuse
  61             ];
  62             withHoogle = false;
  63             inherit (inputs.self.checks.${system}.git-hooks-check) shellHook;
  64           };
  65       });
  66       # `nix flake check`
  67       checks = perSystem (args: with args; {
  68         git-hooks-check = inputs.git-hooks.lib.${system}.run {
  69           src = ./.;
  70           hooks = {
  71             cabal-fmt.enable = true;
  72             fourmolu.enable = true;
  73             hlint.enable = true;
  74             nixpkgs-fmt.enable = true;
  75             ormolu.settings.cabalDefaultExtensions = true;
  76             ormolu.settings.defaultExtensions = [
  77               "ImportQualifiedPost"
  78               "TypeApplications"
  79             ];
  80             reuse = {
  81               enable = true;
  82               entry = "${pkgs.reuse}/bin/reuse lint";
  83               pass_filenames = false;
  84             };
  85           };
  86         };
  87       });
  88     };
  89 }