flake.nix

   1 # SPDX-FileCopyrightText: 2025 Julien Moutinho <julm+worksheets@sourcephile.fr>
   2 # SPDX-License-Identifier: CC0-1.0
   3 {
   4   description = "Worksheet";
   5   inputs = {
   6     nixpkgs.url = "github:NixOS/nixpkgs/9cb344e96d5b6918e94e1bca2d9f3ea1e9615545";
   7     git-hooks.url = "github:cachix/git-hooks.nix";
   8     git-hooks.inputs.nixpkgs.follows = "nixpkgs";
   9     symantic-base = { url = "git://git.sourcephile.fr/haskell/symantic-base.git"; flake = false; };
  10     ipa-hs = { url = "git+file:///home/julm/work/sourcephile/haskell/worksheets/libs/ipa-hs"; flake = false; };
  11   };
  12   outputs =
  13     inputs:
  14     let
  15       pkg = "worksheets";
  16       lib = inputs.nixpkgs.lib;
  17       fileInputs = with lib.fileset; toSource {
  18         root = ./.;
  19         fileset = unions [
  20           ./worksheets.cabal
  21           #./ChangeLog.md
  22           #./Readme.md
  23           ./LICENSES
  24           (fileFilter (file: lib.any file.hasExt [ "hs" ]) ./src)
  25           (fileFilter (file: lib.any file.hasExt [ "css" ]) ./data/styles)
  26           (fileFilter (file: lib.any file.hasExt [ "hs" "html" "txt" ]) ./tests)
  27           #(fileFilter (file: lib.any file.hasExt [ "hs" ]) ./app)
  28         ];
  29       };
  30       # Helper to build for each system in `lib.systems.flakeExposed`.
  31       perSystem =
  32         f:
  33         lib.genAttrs lib.systems.flakeExposed (
  34           system:
  35           f rec {
  36             inherit system;
  37             #pkgs = import inputs.nixpkgs { inherit system; };
  38             pkgs = inputs.nixpkgs.legacyPackages.${system};
  39             haskellPackages = pkgs.haskellPackages.extend (with pkgs.haskell.lib; finalHaskellPkgs: previousHaskellPkgs: {
  40               ${pkg} = buildFromSdist (finalHaskellPkgs.callCabal2nix pkg fileInputs { });
  41               anki-tools = null;
  42               symantic-base = finalHaskellPkgs.callCabal2nix "symantic-base" inputs.symantic-base { };
  43               #ipa = doJailbreak (unmarkBroken previousHaskellPkgs.ipa);
  44               ipa = doJailbreak (finalHaskellPkgs.callCabal2nix "ipa-hs" inputs.ipa-hs { });
  45               python-pickle = dontCheck (doJailbreak (unmarkBroken previousHaskellPkgs.python-pickle));
  46             });
  47           }
  48         );
  49     in
  50     {
  51       # `nix -L build`
  52       packages = perSystem ({ haskellPackages, pkgs, ... }: pkgs // {
  53         default = haskellPackages.${pkg};
  54       });
  55       # `nix -L develop`  or  `direnv allow`
  56       devShells = perSystem ({ pkgs, haskellPackages, system, ... }: {
  57         default =
  58           haskellPackages.shellFor {
  59             packages = ps: [ ps.${pkg} ];
  60             nativeBuildInputs = [
  61               haskellPackages.cabal-fmt
  62               haskellPackages.cabal-install
  63               haskellPackages.ghcid
  64               haskellPackages.haskell-language-server
  65               haskellPackages.hlint
  66               #pkgs.git-chglog
  67               pkgs.reuse
  68               pkgs.xdot
  69               pkgs.zgrviewer
  70               pkgs.gephi
  71             ];
  72             withHoogle = false;
  73             inherit (inputs.self.checks.${system}.git-hooks-check) shellHook;
  74           };
  75       });
  76       # `nix flake check`
  77       checks = perSystem (args: with args; {
  78         git-hooks-check = inputs.git-hooks.lib.${system}.run {
  79           src = ./.;
  80           hooks = {
  81             cabal-fmt.enable = true;
  82             fourmolu.enable = true;
  83             hlint.enable = true;
  84             nixpkgs-fmt.enable = true;
  85             ormolu.settings.cabalDefaultExtensions = true;
  86             ormolu.settings.defaultExtensions = [
  87               "ImportQualifiedPost"
  88               "TypeApplications"
  89             ];
  90             reuse = {
  91               enable = true;
  92               entry = "${pkgs.reuse}/bin/reuse lint";
  93               pass_filenames = false;
  94             };
  95           };
  96         };
  97       });
  98     };
  99 }