android/default.nix

   1 {
   2   inputs,
   3   system,
   4   pkgs,
   5   mainLynxBundle,
   6 }:
   7 let
   8   lib = pkgs.lib;
   9   gradle = pkgs.gradle;
  10   config = rec {
  11     androidPlatformVersion = "34";
  12     androidBuildToolsVersion = "34.0.0";
  13     androidCmakeVersion = "3.22.1";
  14     androidSdkArgs = {
  15       #cmakeVersions = [ androidCmakeVersion ];
  16       platformVersions = [ androidPlatformVersion ];
  17       abiVersions = [
  18         #"arm64-v8a"
  19         #"armeabi-v7a"
  20         "x86_64"
  21       ];
  22       #platformToolsVersion = "35.0.2";
  23       #ndkVersions = [ "23.1.7779620" ];
  24       buildToolsVersions = [ androidBuildToolsVersion ];
  25       includeNDK = true;
  26       includeEmulator = false;
  27
  28       # avdmanager create avd --force -n device -k 'system-images;android-36;google_apis_playstore;x86_64'
  29       #emulatorVersion = "35.6.2";
  30       includeSystemImages = true;
  31       systemImageTypes = [
  32         #"google_apis"
  33         "google_apis_playstore"
  34       ];
  35
  36       extraLicenses = [
  37         "android-sdk-license"
  38         "google-gdk-license"
  39         #"android-sdk-preview-license"
  40         #"android-googletv-license"
  41         #"android-sdk-arm-dbt-license"
  42         #"intel-android-extra-license"
  43         #"intel-android-sysimage-license"
  44         #"mips-android-sysimage-license"
  45       ];
  46     };
  47     androidEmulateAppArgs = rec {
  48       name = "android-emulate-app";
  49       androidUserHome = null;
  50       #androidUserHome = "/var/lib/android";
  51       deviceName = "device-${androidPlatformVersion}";
  52
  53       sdkExtraArgs = androidSdkArgs // {
  54         includeEmulator = true;
  55         #emulatorVersion = "35.6.2";
  56       };
  57       platformVersion = androidPlatformVersion;
  58       systemImageType = "google_apis_playstore";
  59
  60       # PortabilityNote: workaround `-gpu host` not working
  61       # on my Vulkan system.
  62       androidEmulatorFlags = "-gpu guest";
  63
  64       configOptions = {
  65         "hw.keyboard" = "yes";
  66         #"sdcard.path" = "${androidUserHome}/avd/${deviceName}.sdcard.img";
  67         # FixMe: Not working for me:
  68         # WARNING | emuglConfig_get_vulkan_hardware_gpu: Failed to create vulkan instance error code: -9
  69         # See https://issuetracker.google.com/issues/356896486
  70         #"hw.gpu.enabled" = "yes";
  71       };
  72     };
  73     ANDROID_SDK_ROOT = "${androidComposition.androidsdk}/libexec/android-sdk";
  74     ANDROID_NDK_ROOT = "${androidComposition.androidsdk}/libexec/android-sdk/ndk-bundle";
  75     androidComposition = pkgs.androidenv.composeAndroidPackages config.androidSdkArgs;
  76   };
  77 in
  78 {
  79   inherit config;
  80   devShells = {
  81     default = {
  82       buildInputs = [
  83         (pkgs.android-studio.withSdk config.androidComposition.androidsdk)
  84         config.androidComposition.androidsdk
  85         config.androidComposition.platform-tools
  86         config.androidComposition.emulator # For mksdcard
  87         gradle
  88         gradle.jdk
  89         pkgs.just
  90       ];
  91       shellHook = ''
  92         # ExplanationNote: ANDROID_HOME is deprecated. Use ANDROID_SDK_ROOT.
  93         export ANDROID_SDK_ROOT="${config.ANDROID_SDK_ROOT}"
  94         export ANDROID_NDK_ROOT="${config.ANDROID_NDK_ROOT}"
  95         export PATH="${
  96           lib.concatStringsSep ":" [
  97             "$ANDROID_SDK_ROOT/cmake/${config.androidCmakeVersion}/bin"
  98             "$ANDROID_SDK_ROOT/build-tools/${config.androidBuildToolsVersion}"
  99             "$PATH"
 100           ]
 101         }"
 102
 103         # Use the same androidBuildToolsVersion
 104         # and a statically linked aapt2 to workaround a dynamic linking failure.
 105         export GRADLE_OPTS="-Dorg.gradle.project.android.aapt2FromMavenOverride=$ANDROID_SDK_ROOT/build-tools/${config.androidBuildToolsVersion}/aapt2";
 106       '';
 107     };
 108   };
 109   packages = rec {
 110     default = pkgs.stdenv.mkDerivation (finalAttrs: {
 111       pname = "${mainLynxBundle.pname}-apk";
 112       version = mainLynxBundle.version;
 113       src =
 114         with lib.fileset;
 115         toSource rec {
 116           root = ./.;
 117           fileset = unions [
 118             (fileFilter (file: lib.any file.hasExt [ "java" "kt" "xml" "toml" ]) ./app)
 119             ./build.gradle
 120             ./gradle.properties
 121             ./settings.gradle
 122             app/build.gradle
 123             app/proguard-rules.pro
 124             app/src/main/res
 125             gradle/libs.versions.toml
 126           ];
 127         };
 128       inherit (config)
 129         ANDROID_SDK_ROOT
 130         ANDROID_NDK_ROOT
 131         ;
 132
 133       nativeBuildInputs = [
 134         gradle
 135         pkgs.makeWrapper
 136       ];
 137
 138       mitmCache = gradle.fetchDeps {
 139         pkg = finalAttrs.finalPackage;
 140         # MaintenanceNote: nix -L run .#default.update-deps
 141         data = ./deps.json;
 142       };
 143
 144       passthru = {
 145         update-deps = pkgs.writeShellApplication {
 146           name = "update-deps.sh";
 147           text = ''
 148             exec ${finalAttrs.finalPackage.mitmCache.updateScript}
 149           '';
 150         };
 151       };
 152
 153       # this is required for using mitm-cache on Darwin
 154       __darwinAllowLocalNetworking = true;
 155
 156       gradleFlags = [
 157         "-Dfile.encoding=utf-8"
 158         # Use the same androidBuildToolsVersion
 159         # and a statically linked aapt2 to workaround a dynamic linking failure.
 160         "-Dorg.gradle.project.android.aapt2FromMavenOverride=${config.ANDROID_SDK_ROOT}/build-tools/${config.androidBuildToolsVersion}/aapt2"
 161       ];
 162
 163       #gradleBuildTask = "shadowJar";
 164       gradleBuildTask = "assemble";
 165
 166       # MaintenanceToDo: remove this `gradleUpdateScript`
 167       # if https://github.com/NixOS/nixpkgs/pull/383115
 168       # is ever merged.
 169       gradleUpdateScript = ''
 170         runHook preBuild
 171         gradle help --write-verification-metadata sha256
 172       '';
 173
 174       # will run the gradleCheckTask (defaults to "test")
 175       doCheck = false;
 176
 177       preBuild = ''
 178         install -Dm440 \
 179          ${mainLynxBundle}/main.lynx.bundle \
 180          app/src/main/assets/main.lynx.bundle
 181       '';
 182       installPhase = ''
 183         mkdir -p $out
 184         ${
 185           if finalAttrs.gradleBuildTask == "bundleRelease" then
 186             "cp -RL app/build/outputs/bundle/release/*.aab $out"
 187           else
 188             "cp -RL app/build/outputs/apk/*/*.apk $out"
 189         }
 190       '';
 191
 192       meta.sourceProvenance = with lib.sourceTypes; [
 193         fromSource
 194         binaryBytecode # mitm cache
 195       ];
 196     });
 197     android-emulator-x86_64 = pkgs.androidenv.emulateApp (
 198       config.androidEmulateAppArgs
 199       // {
 200         abiVersion = "x86_64";
 201         app = "${default}/app-debug.apk";
 202         #app = "${default}/app-release-unsigned.apk";
 203         package = "com.lynx.javaemptyproject";
 204         activity = ".MainActivity";
 205       }
 206     );
 207   };
 208 }