android/default.nix

   1 {
   2   inputs,
   3   system,
   4   pkgs,
   5   mainLynxBundle,
   6 }:
   7 let
   8   lib = pkgs.lib;
   9   config = rec {
  10     gradle = pkgs.gradle;
  11     androidPlatformVersion = "34";
  12     androidBuildToolsVersion = "34.0.0";
  13     #androidCmakeVersion = "3.22.1";
  14     androidSdkArgs = {
  15       #cmakeVersions = [ androidCmakeVersion ];
  16       platformVersions = [ androidPlatformVersion ];
  17       abiVersions = [
  18         #"arm64-v8a"
  19         #"armeabi-v7a"
  20         "x86_64"
  21       ];
  22       buildToolsVersions = [ androidBuildToolsVersion ];
  23       includeNDK = true;
  24       includeEmulator = false;
  25
  26       includeSystemImages = true;
  27       systemImageTypes = [
  28         #"google_apis"
  29         "google_apis_playstore"
  30       ];
  31
  32       extraLicenses = [
  33         "android-sdk-license"
  34         "google-gdk-license"
  35         #"android-sdk-preview-license"
  36         #"android-googletv-license"
  37         #"android-sdk-arm-dbt-license"
  38         #"intel-android-extra-license"
  39         #"intel-android-sysimage-license"
  40         #"mips-android-sysimage-license"
  41       ];
  42     };
  43     androidEmulateAppArgs = rec {
  44       name = "android-emulate-app";
  45       androidUserHome = null;
  46       #androidUserHome = "/var/lib/android";
  47       deviceName = "device-${androidPlatformVersion}";
  48
  49       sdkExtraArgs = androidSdkArgs // {
  50         includeEmulator = true;
  51       };
  52       platformVersion = androidPlatformVersion;
  53       systemImageType = "google_apis_playstore";
  54
  55       # PortabilityNote: workaround `-gpu host` not working
  56       # on my Vulkan system.
  57       androidEmulatorFlags = "-gpu guest";
  58
  59       configOptions = {
  60         "hw.keyboard" = "yes";
  61         #"sdcard.path" = "${androidUserHome}/avd/${deviceName}.sdcard.img";
  62         # FixMe: Not working for me:
  63         # WARNING | emuglConfig_get_vulkan_hardware_gpu: Failed to create vulkan instance error code: -9
  64         # See https://issuetracker.google.com/issues/356896486
  65         #"hw.gpu.enabled" = "yes";
  66       };
  67     };
  68     ANDROID_SDK_ROOT = "${androidComposition.androidsdk}/libexec/android-sdk";
  69     ANDROID_NDK_ROOT = "${androidComposition.androidsdk}/libexec/android-sdk/ndk-bundle";
  70     androidComposition = pkgs.androidenv.composeAndroidPackages config.androidSdkArgs;
  71   };
  72 in
  73 {
  74   inherit config;
  75   allowUnfreePredicate =
  76     pkg:
  77     builtins.elem (lib.getName pkg) [
  78       "android-sdk-build-tools"
  79       "android-sdk-cmdline-tools"
  80       "android-sdk-ndk"
  81       "android-sdk-platform-tools"
  82       "android-sdk-platforms"
  83       "emulator"
  84       "android-sdk-tools"
  85       "android-studio-stable"
  86       "android-emulate-app"
  87       "build-tools"
  88       "cmake"
  89       "cmdline-tools"
  90       "ndk"
  91       "platform-tools"
  92       "platforms"
  93       "tools"
  94       "android-sdk-emulator"
  95       "android-sdk-system-image-${config.androidPlatformVersion}-google_apis_playstore-x86_64"
  96       "system-image-${config.androidPlatformVersion}-google_apis_playstore-x86_64"
  97       "system-image-${config.androidPlatformVersion}-google_apis-x86_64"
  98       "android-sdk-system-image-${config.androidPlatformVersion}-google_apis-x86_64"
  99     ];
 100   devShells = {
 101     default = {
 102       nativeBuildInputs = [
 103         (pkgs.android-studio.withSdk config.androidComposition.androidsdk)
 104         config.androidComposition.androidsdk
 105         config.androidComposition.platform-tools
 106         config.androidComposition.emulator # For mksdcard
 107         config.gradle
 108         config.gradle.jdk
 109         pkgs.just
 110         pkgs.apkeep
 111       ];
 112       shellHook = ''
 113         # ExplanationNote: ANDROID_HOME is deprecated. Use ANDROID_SDK_ROOT.
 114         export ANDROID_SDK_ROOT="${config.ANDROID_SDK_ROOT}"
 115         export ANDROID_NDK_ROOT="${config.ANDROID_NDK_ROOT}"
 116         export PATH="${
 117           lib.concatStringsSep ":" [
 118             #"$ANDROID_SDK_ROOT/cmake/${config.androidCmakeVersion}/bin"
 119             "$ANDROID_SDK_ROOT/build-tools/${config.androidBuildToolsVersion}"
 120             "$PATH"
 121           ]
 122         }"
 123
 124         # Use the same androidBuildToolsVersion
 125         # and a statically linked aapt2 to workaround a dynamic linking failure.
 126         export GRADLE_OPTS="-Dorg.gradle.project.android.aapt2FromMavenOverride=$ANDROID_SDK_ROOT/build-tools/${config.androidBuildToolsVersion}/aapt2";
 127       '';
 128     };
 129   };
 130   packages = rec {
 131     default = pkgs.stdenv.mkDerivation (finalAttrs: {
 132       pname = "${mainLynxBundle.pname}-apk";
 133       version = mainLynxBundle.version;
 134       src =
 135         with lib.fileset;
 136         toSource rec {
 137           root = ./.;
 138           fileset = unions [
 139             (fileFilter (
 140               file:
 141               lib.any file.hasExt [
 142                 "java"
 143                 "kt"
 144                 "toml"
 145                 "xml"
 146               ]
 147             ) ./app)
 148             ./build.gradle
 149             ./gradle.properties
 150             ./settings.gradle
 151             app/build.gradle
 152             app/proguard-rules.pro
 153             app/src/main/res
 154             gradle/libs.versions.toml
 155           ];
 156         };
 157       inherit (config)
 158         ANDROID_SDK_ROOT
 159         ANDROID_NDK_ROOT
 160         ;
 161
 162       nativeBuildInputs = [
 163         config.gradle
 164         pkgs.makeWrapper
 165       ];
 166
 167       mitmCache = config.gradle.fetchDeps {
 168         pkg = finalAttrs.finalPackage;
 169         # MaintenanceNote: nix -L run .#default.update-deps
 170         data = ./deps.json;
 171       };
 172
 173       passthru = {
 174         update-deps = pkgs.writeShellApplication {
 175           name = "update-deps.sh";
 176           text = ''
 177             exec ${finalAttrs.finalPackage.mitmCache.updateScript}
 178           '';
 179         };
 180       };
 181
 182       # this is required for using mitm-cache on Darwin
 183       __darwinAllowLocalNetworking = true;
 184
 185       gradleFlags = [
 186         "-Dfile.encoding=utf-8"
 187         # Use the same androidBuildToolsVersion
 188         # and a statically linked aapt2 to workaround a dynamic linking failure.
 189         "-Dorg.gradle.project.android.aapt2FromMavenOverride=${config.ANDROID_SDK_ROOT}/build-tools/${config.androidBuildToolsVersion}/aapt2"
 190       ];
 191
 192       #gradleBuildTask = "shadowJar";
 193       gradleBuildTask = "assemble";
 194
 195       # MaintenanceToDo: remove this `gradleUpdateScript`
 196       # if https://github.com/NixOS/nixpkgs/pull/383115
 197       # is ever merged.
 198       gradleUpdateScript = ''
 199         runHook preBuild
 200         gradle help --write-verification-metadata sha256
 201       '';
 202
 203       # will run the gradleCheckTask (defaults to "test")
 204       doCheck = false;
 205
 206       preBuild = ''
 207         install -Dm440 \
 208          ${mainLynxBundle}/main.lynx.bundle \
 209          app/src/main/assets/main.lynx.bundle
 210       '';
 211       installPhase = ''
 212         mkdir -p $out
 213         ${
 214           if finalAttrs.gradleBuildTask == "bundleRelease" then
 215             "cp -RL app/build/outputs/bundle/release/*.aab $out"
 216           else
 217             "cp -RL app/build/outputs/apk/*/*.apk $out"
 218         }
 219       '';
 220
 221       meta.sourceProvenance = with lib.sourceTypes; [
 222         fromSource
 223         binaryBytecode # mitm cache
 224       ];
 225     });
 226
 227     # Run the app into an Android emulator
 228     android-emulator-x86_64 = pkgs.androidenv.emulateApp (
 229       config.androidEmulateAppArgs
 230       // {
 231         abiVersion = "x86_64";
 232         # SecurityToDo: sign the APK
 233         # See: https://stackoverflow.com/questions/18328730/how-to-create-a-release-signed-apk-file-using-gradle
 234         app = "${default}/app-debug.apk";
 235         #app = "${default}/app-release-unsigned.apk";
 236         package = "com.lynx.javaemptyproject";
 237         activity = ".MainActivity";
 238       }
 239     );
 240   };
 241 }