symantic/Language/Symantic/Typing/Type.hs

   1 {-# LANGUAGE ConstraintKinds #-}
   2 {-# LANGUAGE GADTs #-}
   3 {-# LANGUAGE GeneralizedNewtypeDeriving #-}
   4 {-# LANGUAGE TypeInType #-}
   5 {-# LANGUAGE UndecidableInstances #-}
   6 {-# LANGUAGE ViewPatterns #-}
   7 {-# OPTIONS_GHC -fno-warn-orphans #-}
   8 module Language.Symantic.Typing.Type where
   9
  10 import Control.Applicative (Applicative(..))
  11 import qualified Data.Char as Char
  12 import Data.Monoid ((<>))
  13 import Data.Proxy
  14 import Data.Maybe (fromMaybe, isJust)
  15 import Data.String (IsString(..))
  16 import Data.Text (Text)
  17 import qualified Data.Text as Text
  18 import Data.Type.Equality
  19 import qualified Data.Kind as K
  20
  21 import Language.Symantic.Typing.Kind
  22 import Language.Symantic.Typing.Constant
  23 import Language.Symantic.Parsing
  24
  25 -- * Type 'Type'
  26
  27 -- | /Type of terms/.
  28 --
  29 -- * @cs@: /type constants/, fixed at compile time.
  30 -- * @h@: indexed Haskell type.
  31 --
  32 -- * 'TyConst': /type constant/, selected amongst @cs@.
  33 -- * @(:$)@: /type application/.
  34 --
  35 -- See also: https://ghc.haskell.org/trac/ghc/wiki/Typeable
  36 -- Which currently concludes:
  37 -- "Why kind equalities, then? Given the fact that Richard's branch
  38 -- doesn't solve this problem, what is it good for?
  39 -- It still works wonders in the mono-kinded case,
  40 -- such as for decomposing ->.
  41 -- It's just that poly-kinded constructors are still a pain."
  42 data Type (cs::[K.Type]) (h::k) where
  43         TyConst :: TyConst cs c -> Type cs c
  44         (:$) :: Type cs f -> Type cs x -> Type cs (f x)
  45         -- TODO: TyVar :: SKind k -> Type cs (v::k)
  46 infixl 9 :$
  47
  48 -- | 'Type' constructor to be used
  49 -- with @TypeApplications@
  50 -- and @NoMonomorphismRestriction@.
  51 ty :: forall c cs. Inj_TyConst cs c => Type cs c
  52 ty = TyConst inj_TyConst
  53  -- NOTE: The forall brings @c@ first in the type variables,
  54  -- which is convenient to use @TypeApplications@.
  55
  56 instance TestEquality (Type cs) where
  57         testEquality = eq_Type
  58 instance Eq (Type cs h) where
  59         _x == _y = True
  60 instance Show_TyConst cs => Show (Type cs h) where
  61         showsPrec = show_Type
  62 -- deriving instance Show_TyConst cs => Show (Type cs h)
  63
  64 kind_of :: Type cs (h::k) -> SKind k
  65 kind_of t =
  66         case t of
  67          TyConst c -> kind_of_TyConst c
  68          f :$ _x ->
  69                 case kind_of f of
  70                  _kx `SKiArrow` kf -> kf
  71
  72 eq_Type
  73  :: Type cs (x::k) -> Type cs (y::k) -> Maybe (x:~:y)
  74 eq_Type (TyConst x) (TyConst y)
  75  | Just Refl <- testEquality x y
  76  = Just Refl
  77 eq_Type (xf :$ xx) (yf :$ yx)
  78  | Just Refl <- eq_skind (kind_of xf) (kind_of yf)
  79  , Just Refl <- eq_Type xf yf
  80  , Just Refl <- eq_Type xx yx
  81  = Just Refl
  82 eq_Type _ _ = Nothing
  83
  84 eq_Kind_Type
  85  :: Type cs (x::kx) -> Type cs (y::ky) -> Maybe (kx:~:ky)
  86 eq_Kind_Type (TyConst x) (TyConst y)
  87  | Just Refl <- eq_Kind_TyConst x y
  88  = Just Refl
  89 eq_Kind_Type (xf :$ xx) (yf :$ yx)
  90  | Just Refl <- eq_Kind_Type xf yf
  91  , Just Refl <- eq_Kind_Type xx yx
  92  = Just Refl
  93 eq_Kind_Type _x _y = Nothing
  94
  95 show_Type :: Show_TyConst cs => Int -> Type cs h -> ShowS
  96 show_Type n (TyConst c) = showsPrec n c
  97 show_Type n (f :$ a)    = showParen (n > 10) $ show_Type 11 f . showString " " . show_Type 11 a
  98 -- show_Type (TyVar v) = "t" <> show (integral_from_peano v::Integer)
  99
 100 -- | Cons a @new_c@ to @cs@.
 101 lift_Type :: Type cs c -> Type (new_c ': cs) c
 102 lift_Type (TyConst c) = TyConst (TyConstS c)
 103 lift_Type (f :$ a) = lift_Type f :$ lift_Type a
 104
 105 -- * Type 'EType'
 106 -- | Existential for 'Type'.
 107 data EType cs = forall h. EType (Type cs h)
 108
 109 instance Eq (EType cs) where
 110         EType x == EType y
 111          | Just Refl <- eq_Kind_Type x y
 112          = isJust $ eq_Type x y
 113         _x == _y = False
 114 instance Show_TyConst cs => Show (EType cs) where
 115         show (EType t) = show t
 116
 117 -- * Type 'KType'
 118 -- | Existential for 'Type' of a known 'Kind'.
 119 data KType cs k = forall (h::k). KType (Type cs h)
 120
 121 instance Eq (KType cs ki) where
 122         KType x == KType y = isJust $ eq_Type x y
 123 instance Show_TyConst cs => Show (KType cs ki) where
 124         showsPrec n (KType t) = show_Type n t
 125
 126 -- * Type 'Token_Type'
 127 type Token_Type = Type '[] ()
 128
 129 -- * Type 'TyName'
 130 newtype TyName = TyName Text
 131  deriving (Eq, Ord, Show)
 132 instance IsString TyName where
 133         fromString = TyName . fromString
 134
 135 data instance TokenT meta ts (Proxy Token_Type)
 136  = Token_Type TyName [EToken meta ts]
 137 deriving instance Eq_Token meta ts => Eq (TokenT meta ts (Proxy Token_Type))
 138 deriving instance Show_Token meta ts => Show (TokenT meta ts (Proxy Token_Type))
 139
 140 instance
 141  ( Read_TyNameR TyName cs rs
 142  , Inj_TyConst cs Token_Type
 143  ) => Read_TyNameR TyName cs (Proxy Token_Type ': rs) where
 144         read_TyNameR _rs (TyName "Type") k = k (ty @Token_Type)
 145         read_TyNameR _rs raw k = read_TyNameR (Proxy @rs) raw k
 146 instance Show_TyConst cs => Show_TyConst (Proxy Token_Type ': cs) where
 147         show_TyConst TyConstZ{} = "Type"
 148         show_TyConst (TyConstS c) = show_TyConst c
 149
 150 -- * Class 'Compile_Type'
 151 -- | Try to build a 'Type' from name data.
 152 class Compile_Type ts cs where
 153         compile_Type
 154          :: ( MonoLift (Error_Type meta ts) err
 155             , MonoLift (Con_Kind meta ts) err )
 156          => EToken meta ts
 157          -> (forall k h. Type cs (h::k) -> Either err ret)
 158          -> Either err ret
 159
 160 compile_EType
 161  :: Read_TyName TyName cs
 162  => EToken meta '[Proxy Token_Type]
 163  -> Either (Error_Type meta '[Proxy Token_Type]) (EType cs)
 164 compile_EType tok = compile_Type tok (Right . EType)
 165
 166 -- ** Type 'Con_Kind'
 167 data Con_Kind meta ts
 168  =   Con_Kind_Eq    (At meta ts EKind) (At meta ts EKind)
 169  |   Con_Kind_Arrow (At meta ts EKind)
 170 deriving instance (Eq_TokenR meta ts ts) => Eq (Con_Kind meta ts)
 171 deriving instance (Show_TokenR meta ts ts) => Show (Con_Kind meta ts)
 172
 173 check_Kind
 174  :: MonoLift (Con_Kind meta ts) err
 175  => At meta ts (SKind x)
 176  -> At meta ts (SKind y)
 177  -> ((x :~: y) -> Either err ret) -> Either err ret
 178 check_Kind x y k =
 179         case unAt x `eq_skind` unAt y of
 180          Just Refl -> k Refl
 181          Nothing -> Left $ olift $
 182                 Con_Kind_Eq (EKind <$> x) (EKind <$> y)
 183
 184 check_Kind_arrow
 185  :: MonoLift (Con_Kind meta ts) err
 186  => At meta ts (SKind x)
 187  -> (forall a b. (x :~: (a -> b)) -> SKind a -> SKind b -> Either err ret)
 188  -> Either err ret
 189 check_Kind_arrow x k =
 190         case unAt x of
 191          a `SKiArrow` b -> k Refl a b
 192          _ -> Left $ olift $
 193                 Con_Kind_Arrow (EKind <$> x)
 194
 195 -- ** Type 'Error_Type'
 196 data Error_Type meta ts
 197  =   Error_Type_Token_invalid    (EToken meta ts)
 198  |   Error_Type_Constant_unknown (At meta ts TyName)
 199  |   Error_Type_Con_Kind  (Con_Kind meta ts)
 200 deriving instance (Eq_TokenR meta ts ts) => Eq (Error_Type meta ts)
 201 deriving instance (Show_TokenR meta ts ts) => Show (Error_Type meta ts)
 202
 203 -- * Class 'Read_TyName'
 204 type Read_TyName raw cs = Read_TyNameR raw cs cs
 205
 206 read_TyName
 207  :: forall raw cs ret.
 208  Read_TyNameR raw cs cs
 209  => raw -> (forall k c. Type cs (c::k) -> Maybe ret)
 210  -> Maybe ret
 211 read_TyName = read_TyNameR (Proxy @cs)
 212
 213 -- ** Class 'Read_TyNameR'
 214 class Read_TyNameR raw cs rs where
 215         read_TyNameR
 216          :: Proxy rs -> raw -> (forall k c. Type cs (c::k) -> Maybe ret)
 217          -> Maybe ret
 218
 219 instance Read_TyNameR raw cs '[] where
 220         read_TyNameR _cs _c _k = Nothing
 221
 222 -- TODO: move each of these to a dedicated module.
 223 instance
 224  ( Read_TyNameR TyName cs rs
 225  , Inj_TyConst cs Fractional
 226  ) => Read_TyNameR TyName cs (Proxy Fractional ': rs) where
 227         read_TyNameR _cs (TyName "Fractional") k = k (ty @Fractional)
 228         read_TyNameR _rs raw k = read_TyNameR (Proxy @rs) raw k
 229 instance
 230  ( Read_TyNameR TyName cs rs
 231  , Inj_TyConst cs []
 232  , Inj_TyConst cs Char
 233  ) => Read_TyNameR TyName cs (Proxy String ': rs) where
 234         read_TyNameR _cs (TyName "String") k = k (ty @[] :$ ty @Char)
 235         read_TyNameR _rs raw k = read_TyNameR (Proxy @rs) raw k
 236
 237 instance
 238  ( Read_TyName TyName cs
 239  , Proj_Token ts Token_Type
 240  ) => Compile_Type ts cs where
 241         compile_Type
 242          :: forall meta err ret.
 243          ( MonoLift (Error_Type meta ts) err
 244          , MonoLift (Con_Kind meta ts) err
 245          ) => EToken meta ts
 246          -> (forall k h. Type cs (h::k) -> Either err ret)
 247          -> Either err ret
 248         compile_Type tok@(proj_EToken -> Just (Token_Type cst args)) kk =
 249                 fromMaybe (Left $ olift $ Error_Type_Constant_unknown $ At (Just tok) cst) $
 250                 read_TyName cst $ \typ -> Just $
 251                 go args typ kk
 252                 where
 253                 go :: [EToken meta ts]
 254                  -> Type cs h
 255                  -> (forall k' h'. Type cs (h'::k') -> Either err ret)
 256                  -> Either err ret
 257                 go [] typ k = k typ
 258                 go (tok_x:tok_xs) ty_f k =
 259                         compile_Type tok_x $ \(ty_x::Type cs (h'::k')) ->
 260                         check_Kind_arrow
 261                          (At (Just tok) $ kind_of ty_f) $ \Refl ki_f_a _ki_f_b ->
 262                         check_Kind
 263                          (At (Just tok) ki_f_a)
 264                          (At (Just tok_x) $ kind_of ty_x) $ \Refl ->
 265                         go tok_xs (ty_f :$ ty_x) k
 266         compile_Type tok _k = Left $ olift $ Error_Type_Token_invalid tok
 267
 268 -- * Type 'Types'
 269 data Types cs (hs::[K.Type]) where
 270         TypesZ :: Types cs '[]
 271         TypesS :: Type  cs h
 272                -> Types cs hs
 273                -> Types cs (Proxy h ': hs)
 274 infixr 5 `TypesS`
 275
 276 eTypes :: Types cs hs -> [EType cs]
 277 eTypes TypesZ = []
 278 eTypes (TypesS t ts) = EType t : eTypes ts
 279
 280 -- | Build the left spine of a 'Type'.
 281 spine_of_Type
 282  :: Type cs h
 283  -> (forall kc (c::kc) hs. TyConst cs c -> Types cs hs -> ret) -> ret
 284 spine_of_Type (TyConst c) k = k c TypesZ
 285 spine_of_Type (f :$ a) k = spine_of_Type f $ \c as -> k c (a `TypesS` as)
 286
 287 -- * Type 'UnProxy'
 288 type family UnProxy (x::K.Type) :: k where
 289         UnProxy (Proxy x) = x
 290
 291 -- * Class 'MonoLift'
 292 class MonoLift a b where
 293         olift :: a -> b
 294 instance MonoLift
 295  (Error_Type meta ts)
 296  (Error_Type meta ts) where
 297         olift = id
 298 instance
 299  MonoLift (Con_Kind meta ts) (Error_Type meta ts) where
 300         olift = olift . Error_Type_Con_Kind
 301
 302 -- * Class 'Gram_Type'
 303 type TokType meta = EToken meta '[Proxy Token_Type]
 304 class
 305  ( Alt g
 306  , Alter g
 307  , App g
 308  , Try g
 309  , Gram_CF g
 310  , Gram_Rule g
 311  , Gram_Terminal g
 312  , Gram_Lexer g
 313  , Gram_Op g
 314  , Gram_Meta meta g
 315  ) => Gram_Type meta g where
 316         g_type :: CF g (TokType meta)
 317         g_type = rule "type" $ g_type_fun
 318         g_type_fun :: CF g (TokType meta)
 319         g_type_fun = rule "type_fun" $
 320                 infixrG g_type_list (metaG $ op <$ symbol "->")
 321                 where op meta a b = inj_EToken meta $ Token_Type (TyName "(->)") [a, b]
 322         g_type_list :: CF g (TokType meta)
 323         g_type_list = rule "type_list" $
 324                 metaG $ inside f
 325                  (symbol "[") (option [] (pure <$> g_type)) (symbol "]")
 326                  (const <$> g_type_tuple2)
 327                 where f a meta = inj_EToken meta $ Token_Type (TyName "[]") a
 328         g_type_tuple2 :: CF g (TokType meta)
 329         g_type_tuple2 = rule "type_tuple2" $
 330                 try (parens (infixrG g_type (metaG $ op <$ symbol ","))) <+> g_type_app
 331                 where op meta a b = inj_EToken meta $ Token_Type (TyName "(,)") [a, b]
 332         g_type_app :: CF g (TokType meta)
 333         g_type_app = rule "type_app" $
 334                 f <$> some g_type_atom
 335                 where
 336                 f :: [TokType meta] -> TokType meta
 337                 f (EToken (TokenZ meta (Token_Type a as)):as') =
 338                         EToken $ TokenZ meta $ Token_Type a $ as <> as'
 339                 f _ = error "Oops, the impossible happened"
 340         g_type_atom :: CF g (TokType meta)
 341         g_type_atom = rule "type_atom" $
 342                 try (parens g_type) <+>
 343                 g_type_name <+>
 344                 g_type_symbol
 345         g_type_name :: CF g (TokType meta)
 346         g_type_name = rule "type_name" $
 347                 metaG $ lexeme $
 348                 (\c cs meta -> EToken $ TokenZ meta $ Token_Type (TyName $ Text.pack $ c:cs) [])
 349                  <$> unicat (Unicat Char.UppercaseLetter)
 350                  <*> many (choice $ unicat <$> [Unicat_Letter, Unicat_Number])
 351         g_type_symbol :: CF g (TokType meta)
 352         g_type_symbol = rule "type_symbol" $
 353                 metaG $ (f <$>) $
 354                 parens $ many $ cf_of_Terminal $ choice g_ok `but` choice g_ko
 355                 where
 356                 f s meta = inj_EToken meta $ (`Token_Type` []) $
 357                         TyName $ Text.concat ["(", Text.pack s, ")"]
 358                 g_ok = unicat <$>
 359                  [ Unicat_Symbol
 360                  , Unicat_Punctuation
 361                  , Unicat_Mark
 362                  ]
 363                 g_ko = char <$> ['(', ')', '`']
 364
 365 deriving instance Gram_Type meta g => Gram_Type meta (CF g)
 366 instance Gram_Type meta EBNF
 367 instance Gram_Type meta RuleDef
 368
 369 -- | List of the rules of 'Gram_Type'.
 370 gram_type :: Gram_Type meta g => [CF g (TokType meta)]
 371 gram_type =
 372  [ g_type
 373  , g_type_fun
 374  , g_type_list
 375  , g_type_tuple2
 376  , g_type_app
 377  , g_type_atom
 378  , g_type_name
 379  , g_type_symbol
 380  ]