symantic-lib/Language/Symantic/Lib/Char.hs

   1 {-# LANGUAGE UndecidableInstances #-}
   2 {-# OPTIONS_GHC -fno-warn-orphans #-}
   3 -- | Symantic for 'Char'.
   4 module Language.Symantic.Lib.Char where
   5
   6 import qualified Data.Char as Char
   7 import qualified Data.Text as Text
   8
   9 import Language.Symantic.Grammar hiding (char, any)
  10 import qualified Language.Symantic.Grammar as Gram
  11 import Language.Symantic
  12 import Language.Symantic.Lib.List (tyList)
  13
  14 -- * Class 'Sym_Char'
  15 type instance Sym (Proxy Char) = Sym_Char
  16 class Sym_Char term where
  17         char :: Char -> term Char
  18         char_toUpper :: term Char -> term Char
  19         char_toLower :: term Char -> term Char
  20
  21         default char         :: Sym_Char (UnT term) => Trans term => Char -> term Char
  22         default char_toUpper :: Sym_Char (UnT term) => Trans term => term Char -> term Char
  23         default char_toLower :: Sym_Char (UnT term) => Trans term => term Char -> term Char
  24
  25         char         = trans . char
  26         char_toUpper = trans1 char_toUpper
  27         char_toLower = trans1 char_toLower
  28
  29 -- Interpreting
  30 instance Sym_Char Eval where
  31         char         = Eval
  32         char_toUpper = eval1 Char.toUpper
  33         char_toLower = eval1 Char.toLower
  34 instance Sym_Char View where
  35         char a = View $ \_p _v ->
  36                 Text.pack (show a)
  37         char_toUpper = view1 "Char.toUpper"
  38         char_toLower = view1 "Char.toLower"
  39 instance (Sym_Char r1, Sym_Char r2) => Sym_Char (Dup r1 r2) where
  40         char x       = char x `Dup` char x
  41         char_toUpper = dup1 @Sym_Char char_toUpper
  42         char_toLower = dup1 @Sym_Char char_toLower
  43
  44 -- Transforming
  45 instance (Sym_Char term, Sym_Lambda term) => Sym_Char (BetaT term)
  46
  47 -- Typing
  48 instance ClassInstancesFor Char where
  49         proveConstraintFor _ (TyApp _ (TyConst _ _ q) z)
  50          | Just HRefl <- proj_ConstKiTy @_ @Char z
  51          = case () of
  52                  _ | Just Refl <- proj_Const @Bounded q -> Just Dict
  53                    | Just Refl <- proj_Const @Enum    q -> Just Dict
  54                    | Just Refl <- proj_Const @Eq      q -> Just Dict
  55                    | Just Refl <- proj_Const @Ord     q -> Just Dict
  56                    | Just Refl <- proj_Const @Show    q -> Just Dict
  57                  _ -> Nothing
  58         proveConstraintFor _c _q = Nothing
  59 instance TypeInstancesFor Char
  60
  61 -- Compiling
  62 instance
  63  ( Gram_Alt g
  64  , Gram_Rule g
  65  , Gram_Comment g
  66  , Gram_Meta src g
  67  , Inj_Sym ss Char
  68  , Source src
  69  ) => Gram_Term_AtomsFor src ss g Char where
  70         g_term_atomsFor _t =
  71          [ rule "teChar" $
  72                 lexeme $ withMeta $
  73                 (\c src -> BinTree0 $ Token_Term $ TermVT_CF $ (`setSource` src) $ teChar c)
  74                  <$> between tickG tickG (
  75                         cf_of_Terminal (Gram.any `but` tickG) <+>
  76                         '\'' <$ string "\\'"
  77                  )
  78          ]
  79                 where
  80                 tickG :: Gram_Terminal g' => g' Char
  81                 tickG = Gram.char '\''
  82 instance (Source src, Inj_Sym ss Char) => Module src ss Char where
  83         module_ _s = [NameMod "Char"] `moduleWhere`
  84          [ "toLower" := teChar_toLower
  85          , "toUpper" := teChar_toUpper
  86          ]
  87
  88 -- ** 'Type's
  89 tyChar :: Source src => Inj_Len vs => Type src vs Char
  90 tyChar = tyConst @(K Char) @Char
  91
  92 tyString :: Source src => Inj_Len vs => Type src vs String
  93 tyString = tyList tyChar
  94
  95 -- ** 'Term's
  96 teChar :: Source src => Inj_Sym ss Char => Char -> Term src ss ts '[] Char
  97 teChar b = Term noConstraint tyChar $ teSym @Char $ char b
  98
  99 teChar_toUpper, teChar_toLower :: TermDef Char '[] (Char -> Char)
 100 teChar_toUpper = Term noConstraint (tyChar ~> tyChar) $ teSym @Char $ lam1 char_toUpper
 101 teChar_toLower = Term noConstraint (tyChar ~> tyChar) $ teSym @Char $ lam1 char_toLower