Language/Symantic/Expr/Lambda.hs

   1 {-# LANGUAGE DefaultSignatures #-}
   2 {-# LANGUAGE DataKinds #-}
   3 {-# LANGUAGE FlexibleContexts #-}
   4 {-# LANGUAGE FlexibleInstances #-}
   5 {-# LANGUAGE MultiParamTypeClasses #-}
   6 {-# LANGUAGE OverloadedStrings #-}
   7 {-# LANGUAGE Rank2Types #-}
   8 {-# LANGUAGE ScopedTypeVariables #-}
   9 {-# LANGUAGE TypeFamilies #-}
  10 {-# LANGUAGE TypeOperators #-}
  11 -- | Expression for /lambda abstraction/s
  12 -- in /Higher-Order Abstract Syntax/ (HOAS).
  13 module Language.Symantic.Expr.Lambda
  14  ( module Language.Symantic.Expr.Lambda
  15  , Sym_Lambda_Lam(..)
  16  ) where
  17
  18 import qualified Control.Applicative as Applicative
  19 import qualified Data.Function as Fun
  20 import Data.Monoid
  21 import Data.Proxy (Proxy(..))
  22 import Data.Text (Text)
  23 import qualified Data.Text as Text
  24 import Data.Type.Equality ((:~:)(Refl))
  25 import Prelude hiding (const, id)
  26
  27 import Language.Symantic.Type
  28 import Language.Symantic.Repr
  29 import Language.Symantic.Expr.Root
  30 import Language.Symantic.Expr.Error
  31 import Language.Symantic.Expr.From
  32 import Language.Symantic.Trans.Common
  33
  34 -- * Class 'Sym_Lambda'
  35 -- | Symantic.
  36 class Sym_Lambda_Lam repr => Sym_Lambda repr where
  37         -- | /Lambda application/.
  38         ($$) :: repr ((->) arg res) -> repr arg -> repr res
  39         default ($$) :: Trans t repr
  40          => t repr ((->) arg res) -> t repr arg -> t repr res
  41         ($$) f x = trans_lift (trans_apply f $$ trans_apply x)
  42
  43         -- | Convenient 'lam' and '$$' wrapper.
  44         let_ :: repr var -> (repr var -> repr res) -> repr res
  45         let_ x y = lam y $$ x
  46
  47         id :: repr a -> repr a
  48         id a = (lam Fun.id) $$ a
  49
  50         const :: repr a -> repr b -> repr a
  51         const a b = lam (lam . Fun.const) $$ a $$ b
  52
  53         -- | /Lambda composition/.
  54         (#) :: repr (b -> c) -> repr (a -> b) -> repr (a -> c)
  55         (#) f g = lam $ \a -> f $$ (g $$ a)
  56
  57         flip :: repr (a -> b -> c) -> repr (b -> a -> c)
  58         flip f = lam $ \b -> lam $ \a -> f $$ a $$ b
  59
  60 infixl 0 $$
  61 infixr 9 #
  62
  63 instance Sym_Lambda Repr_Host where
  64         ($$)  = (Applicative.<*>)
  65 instance Sym_Lambda Repr_Text where
  66         -- ($$) = repr_text_infix "$" (Precedence 0)
  67         ($$) (Repr_Text a1) (Repr_Text a2) =
  68                 Repr_Text $ \p v ->
  69                         let p' = precedence_App in
  70                         paren p p' $ a1 p' v <> " " <> a2 p' v
  71         let_ e in_ =
  72                 Repr_Text $ \p v ->
  73                         let p' = Precedence 2 in
  74                         let x = "x" <> Text.pack (show v) in
  75                         paren p p' $ "let" <> " " <> x <> " = "
  76                          <> unRepr_Text e (Precedence 0) (succ v) <> " in "
  77                          <> unRepr_Text (in_ (Repr_Text $ \_p _v -> x)) p' (succ v)
  78         (#)   = repr_text_infix "." (Precedence 9)
  79         id    = repr_text_app1 "id"
  80         const = repr_text_app2 "const"
  81         flip  = repr_text_app1 "flip"
  82 instance (Sym_Lambda r1, Sym_Lambda r2) => Sym_Lambda (Repr_Dup r1 r2) where
  83         ($$) = repr_dup2 sym_Lambda ($$)
  84
  85 sym_Lambda :: Proxy Sym_Lambda
  86 sym_Lambda = Proxy
  87
  88 -- * Type 'Expr_Lambda'
  89 -- | Expression.
  90 data Expr_Lambda (root:: *)
  91 type instance Root_of_Expr      (Expr_Lambda root)      = root
  92 type instance Type_of_Expr      (Expr_Lambda root)      = Type_Fun
  93 type instance Sym_of_Expr       (Expr_Lambda root) repr = Sym_Lambda repr
  94 type instance Error_of_Expr ast (Expr_Lambda root)      = Error_Expr_Lambda ast
  95
  96 -- | Parsing utility to check that the given type is a 'Type_Fun'
  97 -- or raise 'Error_Expr_Type_mismatch'.
  98 check_type_fun
  99  :: forall ast ex root ty h ret.
 100  ( root ~ Root_of_Expr ex
 101  , ty ~ Type_Root_of_Expr ex
 102  , Type0_Lift   Type_Fun (Type_of_Expr root)
 103  , Type0_Unlift Type_Fun (Type_of_Expr root)
 104  , Error_Expr_Lift (Error_Expr (Error_of_Type ast ty) ty ast)
 105                    (Error_of_Expr ast root)
 106  )
 107  => Proxy ex -> ast -> ty h
 108  -> (Type_Fun ty h -> Either (Error_of_Expr ast root) ret)
 109  -> Either (Error_of_Expr ast root) ret
 110 check_type_fun ex ast ty k =
 111         case type0_unlift $ unType_Root ty of
 112          Just ty_f -> k ty_f
 113          Nothing -> Left $ error_expr ex $
 114                 Error_Expr_Type_mismatch ast
 115                  (Exists_Type0 (type_var0 SZero `type_fun` type_var0 (SSucc SZero)
 116                  :: ty ((->) Var0 Var0)))
 117                  (Exists_Type0 ty)
 118
 119 -- | Parse a /lambda variable/.
 120 var_from
 121  :: forall ast root hs ret.
 122  ( Type0_From ast (Type_Root_of_Expr root)
 123  , Error_Expr_Lift (Error_Expr_Lambda ast)
 124                    (Error_of_Expr ast root)
 125  , Root_of_Expr root ~ root
 126  ) => Text -> ExprFrom ast (Expr_Lambda root) hs ret
 127 var_from name _ex ast = go
 128         where
 129         go :: forall ex hs'. (ex ~ (Expr_Lambda root))
 130          => Lambda_Context (Lambda_Var (Type_Root_of_Expr ex)) hs'
 131          -> ( forall h. Type_Root_of_Expr ex h
 132             -> Forall_Repr_with_Context ex hs' h
 133             -> Either (Error_of_Expr ast (Root_of_Expr ex)) ret )
 134          ->    Either (Error_of_Expr ast (Root_of_Expr ex)) ret
 135         go c k' =
 136                 case c of
 137                  Lambda_Context_Empty -> Left $ error_expr_lift $
 138                         Error_Expr_Lambda_Var_unbound name ast
 139                  Lambda_Var n ty `Lambda_Context_Next` _ | n == name ->
 140                         k' ty $ Forall_Repr_with_Context $
 141                          \(repr `Lambda_Context_Next` _) -> repr
 142                  _ `Lambda_Context_Next` ctx' ->
 143                         go ctx' $ \ty (Forall_Repr_with_Context repr) ->
 144                         k' ty $ Forall_Repr_with_Context $
 145                          \(_ `Lambda_Context_Next` c') -> repr c'
 146
 147 -- | Parse '$$'.
 148 app_from
 149  :: forall ty ast root hs ret.
 150  ( ty ~ Type_Root_of_Expr root
 151  , Type0_From ast ty
 152  , Type0_Eq ty
 153  , Expr_From ast root
 154  , Type0_Lift Type_Fun (Type_of_Expr root)
 155  , Error_Expr_Lift (Error_Expr (Error_of_Type ast ty) ty ast)
 156                    (Error_of_Expr ast root)
 157  , Type0_Unlift Type_Fun (Type_of_Expr root)
 158  , Root_of_Expr root ~ root
 159  ) => ast -> ast
 160  -> ExprFrom ast (Expr_Lambda root) hs ret
 161 app_from ast_lam ast_arg_actual ex ast ctx k =
 162         expr_from (Proxy::Proxy root) ast_lam ctx $
 163          \(ty_lam::ty h_lam) (Forall_Repr_with_Context l) ->
 164         expr_from (Proxy::Proxy root) ast_arg_actual ctx $
 165          \(ty_arg_actual::ty h_arg_actual)
 166           (Forall_Repr_with_Context arg_actual) ->
 167         case type0_unlift $ unType_Root ty_lam of
 168          Nothing -> Left $
 169                 error_expr ex $
 170                 Error_Expr_Type_mismatch ast
 171                  (Exists_Type0 (type_var0 SZero `type_fun` type_var0 (SSucc SZero)
 172                  :: ty ((->) Var0 Var0)))
 173                  (Exists_Type0 ty_lam)
 174          Just (Type2 Proxy ty_arg_expected ty_res
 175           :: Type_Fun ty h_lam) ->
 176                 check_type0_eq ex ast
 177                  ty_arg_expected ty_arg_actual $ \Refl ->
 178                         k ty_res $ Forall_Repr_with_Context $
 179                          \c -> l c $$ arg_actual c
 180
 181 -- | Parse 'lam'.
 182 lam_from
 183  :: forall ty ast root hs ret.
 184  ( ty ~ Type_Root_of_Expr root
 185  , root ~ Root_of_Expr root
 186  , Type0_From ast ty
 187  , Expr_From ast root
 188  , Type0_Lift Type_Fun (Type_of_Expr root)
 189  , Error_Expr_Lift (Error_Expr (Error_of_Type ast ty) ty ast)
 190                    (Error_of_Expr ast root)
 191  ) => Text -> ast -> ast
 192  -> ExprFrom ast (Expr_Lambda root) hs ret
 193 lam_from name ast_ty_arg ast_body ex ast ctx k =
 194         either (\err -> Left $ error_expr ex $ Error_Expr_Type err ast) Fun.id $
 195         type0_from (Proxy::Proxy ty) ast_ty_arg $ \ty_arg -> Right $
 196         expr_from (Proxy::Proxy root) ast_body
 197          (Lambda_Var name ty_arg `Lambda_Context_Next` ctx) $
 198          \(ty_res::ty h_res) (Forall_Repr_with_Context res) ->
 199         k (ty_arg `type_fun` ty_res) $ Forall_Repr_with_Context $
 200          \c -> lam $ \arg -> res (arg `Lambda_Context_Next` c)
 201
 202 -- | Parse 'let_'.
 203 let_from
 204  :: forall ty ast root hs ret.
 205  ( ty ~ Type_Root_of_Expr root
 206  , root ~ Root_of_Expr root
 207  , Type0_From ast ty
 208  , Expr_From ast root
 209  , Error_Expr_Lift (Error_Expr (Error_of_Type ast ty) ty ast)
 210                    (Error_of_Expr ast root)
 211  ) => Text -> ast -> ast
 212  -> ExprFrom ast (Expr_Lambda root) hs ret
 213 let_from name ast_var ast_body _ex _ast ctx k =
 214         expr_from (Proxy::Proxy root) ast_var ctx $
 215          \ty_var (Forall_Repr_with_Context var) ->
 216         expr_from (Proxy::Proxy root) ast_body
 217          (Lambda_Var name ty_var `Lambda_Context_Next` ctx) $
 218          \ty_res (Forall_Repr_with_Context res) ->
 219         k ty_res $ Forall_Repr_with_Context $
 220          \c -> let_ (var c) $ \arg -> res (arg `Lambda_Context_Next` c)
 221
 222 -- * Type 'Error_Expr_Lambda'
 223 data Error_Expr_Lambda ast
 224  =   Error_Expr_Lambda_Var_unbound Lambda_Var_Name ast
 225  deriving (Eq, Show)