Language/LOL/Symantic/Type/Maybe.hs

   1 {-# LANGUAGE FlexibleContexts #-}
   2 {-# LANGUAGE GADTs #-}
   3 {-# LANGUAGE MultiParamTypeClasses #-}
   4 {-# LANGUAGE OverloadedStrings #-}
   5 {-# LANGUAGE ScopedTypeVariables #-}
   6 {-# LANGUAGE TypeFamilies #-}
   7 {-# LANGUAGE UndecidableInstances #-}
   8 module Language.LOL.Symantic.Type.Maybe where
   9
  10 import Data.Maybe (isJust)
  11 import Data.Type.Equality ((:~:)(Refl))
  12 import Data.Proxy
  13
  14 import Language.LOL.Symantic.AST
  15 import Language.LOL.Symantic.Type.Common
  16 import Language.LOL.Symantic.Type.Fun
  17 import Language.LOL.Symantic.Type.Bool
  18 import Language.LOL.Symantic.Type.Var
  19
  20 -- * Type 'Type_Maybe'
  21 -- | The 'Maybe' type.
  22 data Type_Maybe root h where
  23         Type_Maybe :: root h_a
  24                    -> Type_Maybe root (Maybe h_a)
  25
  26 type instance Root_of_Type      (Type_Maybe root) = root
  27 type instance Error_of_Type ast (Type_Maybe root) = ()
  28
  29 instance -- Type_Eq
  30  Type_Eq root =>
  31  Type_Eq (Type_Maybe root) where
  32         type_eq (Type_Maybe a1) (Type_Maybe a2)
  33          | Just Refl <- a1 `type_eq` a2
  34          = Just Refl
  35         type_eq _ _ = Nothing
  36 instance -- Eq
  37  Type_Eq root =>
  38  Eq (Type_Maybe root h) where
  39         x == y = isJust $ type_eq x y
  40 instance -- Type_from AST
  41  ( Type_Eq root
  42  , Type_from AST root
  43  , Type_Root_Lift Type_Maybe root
  44  , Error_Type_Lift   (Error_Type AST) (Error_of_Type AST root)
  45  , Error_Type_Unlift (Error_Type AST) (Error_of_Type AST root)
  46  , Root_of_Type root ~ root
  47  , Implicit_HBool (Is_Last_Type (Type_Maybe root) root)
  48  ) => Type_from AST (Type_Maybe root) where
  49         type_from px_ty ast k =
  50                 case ast of
  51                  AST "Maybe" asts ->
  52                         case asts of
  53                          [ast_a] ->
  54                                 type_from (Proxy::Proxy root) ast_a $ \(ty_a::root h_a) ->
  55                                         k (type_root_lift $ Type_Maybe ty_a
  56                                          :: root (Maybe h_a))
  57                          _ -> Left $ error_type_lift $
  58                                 Error_Type_Wrong_number_of_arguments ast 1
  59                  _ -> Left $ error_type_unsupported px_ty ast
  60 instance -- String_from_Type
  61  String_from_Type root =>
  62  String_from_Type (Type_Maybe root) where
  63         string_from_type (Type_Maybe a) =
  64                 "Maybe (" ++ string_from_type a ++ ")"
  65 instance -- Show
  66  String_from_Type root =>
  67  Show (Type_Maybe root h) where
  68         show = string_from_type
  69
  70 -- | Convenient alias to include a 'Type_Maybe' within a type.
  71 type_maybe
  72  :: Type_Root_Lift Type_Maybe root
  73  => root h_a
  74  -> root (Maybe h_a)
  75 type_maybe a = type_root_lift (Type_Maybe a)
  76
  77 -- * Type 'Type_Fun_Bool_Maybe'
  78 -- | Convenient alias.
  79 type Type_Fun_Bool_Maybe lam
  80  = Type_Root (Type_Alt Type_Var
  81              (Type_Alt (Type_Fun lam)
  82              (Type_Alt Type_Bool
  83                        Type_Maybe)))