hosts/oignon.nix

   1 { config, pkgs, lib, inputs, hostName, ... }:
   2 {
   3 imports = [
   4   ../nixos/profiles/builder.nix
   5   ../nixos/profiles/debug.nix
   6   ../nixos/profiles/graphical.nix
   7   ../nixos/profiles/lang-fr.nix
   8   ../nixos/profiles/printing.nix
   9   ../nixos/profiles/security.nix
  10   ../nixos/profiles/system.nix
  11   ../nixos/profiles/tor.nix
  12   ../nixos/profiles/irssi.nix
  13   oignon/backup.nix
  14   oignon/hardware.nix
  15   oignon/networking.nix
  16 ];
  17
  18 # Lower kernel's security for better performances
  19 boot.kernelParams = [ "mitigations=off" ];
  20
  21 home-manager.users.julm = {
  22   imports = [ ../homes/julm.nix ];
  23 };
  24 systemd.services.home-manager-julm.postStart = ''
  25   ${pkgs.nix}/bin/nix-env --delete-generations +1 --profile /nix/var/nix/profiles/per-user/julm/home-manager
  26 '';
  27 users.users.root = {
  28   openssh.authorizedKeys.keys = map lib.readFile [
  29     # For nix -L run .#oignon.switch
  30     ../users/julm/ssh/oignon.pub
  31   ];
  32 };
  33 users.users.julm = {
  34   isNormalUser = true;
  35   uid = 1000;
  36   # Put the hashedPassword in /nix/store,
  37   # though /etc/shadow is not world readable...
  38   # printf %s $(mkpasswd -m md5crypt)
  39   hashedPassword = lib.readFile oignon/users/julm/login/hashedPassword.clear;
  40   extraGroups = [
  41     "adbusers"
  42     "dialout"
  43     "lp"
  44     "networkmanager"
  45     "scanner"
  46     "tor"
  47     "video"
  48     "wheel"
  49     #"ipfs"
  50     config.services.davfs2.davGroup
  51     #"vboxusers"
  52   ];
  53   # If created, zfs-mount.service would require:
  54   # zfs set overlay=yes ${hostName}/home
  55   createHome = false;
  56   openssh.authorizedKeys.keys = map lib.readFile [
  57     ../users/julm/ssh/losurdo.pub
  58   ];
  59 };
  60
  61 systemd.services.nix-daemon.serviceConfig.LoadCredentialEncrypted =
  62   [ ("${hostName}.key:" + inputs.self + "/hosts/${hostName}/nix/secret-key-files.priv.pem.cred") ];
  63 nix = {
  64   extraOptions = ''
  65     secret-key-files = /run/credentials/nix-daemon.service/${hostName}.key
  66   '';
  67   settings = {
  68     trusted-users = [ config.users.users."julm".name ];
  69     substituters = [
  70       #"http://nix-localcache.losurdo.wg"
  71       "ssh://nix-ssh@losurdo.wg?priority=30"
  72     ];
  73     trusted-public-keys = map lib.readFile [
  74       ../hosts/losurdo/nix/key.pub
  75     ];
  76   };
  77   nixPath = lib.mkForce [ "nixpkgs=${inputs.nixpkgs}" ];
  78 };
  79 #environment.etc."nixpkgs".source = pkgs.path;
  80 #environment.etc."nixpkgs-overlays".source = inputs.self + "/nixpkgs";
  81
  82 nix.settings.allowed-users = [ config.users.users."nix-ssh".name ];
  83 nix.sshServe = {
  84   enable = true;
  85   keys = map lib.readFile [
  86     ../users/julm/ssh/losurdo.pub
  87     ../users/julm/ssh/oignon.pub
  88     ../users/sevy/ssh/patate.pub
  89   ];
  90 };
  91
  92 environment.systemPackages = [
  93   pkgs.riseup-vpn # Can't be installed by home-manager because it needs to install policy-kit rules
  94 ];
  95
  96 boot.extraModulePackages = [
  97   #config.boot.kernelPackages.v4l2loopback
  98 ];
  99
 100 programs.fuse.userAllowOther = true;
 101
 102 services.davfs2.enable = true;
 103
 104 fileSystems =
 105   # Use the user's gpg-agent session to query
 106   # for the password of the SSH key when auto-mounting.
 107   let
 108     sshAsUser = user:
 109       pkgs.writeScript "sshAsUser-${user}" ''
 110          exec ${pkgs.sudo}/bin/sudo -i -u ${user} \
 111            ${pkgs.openssh}/bin/ssh "$@"
 112       '';
 113     options =
 114       [
 115         "noatime" "noexec" "nosuid"
 116         "user" "uid=julm" "gid=users" "allow_other"
 117         "_netdev" "ssh_command=${sshAsUser "julm"}" #  "reconnect"
 118         "noauto" "x-gvfs-hide" "x-systemd.automount"
 119         #"Compression=yes" # YMMV
 120         # Disconnect approximately 2*15=30 seconds after a network failure
 121         "ServerAliveCountMax=1"
 122         "ServerAliveInterval=15"
 123       ];
 124   in {
 125   "/mnt/aubergine" = {
 126     device = "${pkgs.sshfs-fuse}/bin/sshfs#julm@aubergine.wg:/";
 127     fsType = "fuse";
 128     inherit options;
 129   };
 130   "/mnt/losurdo" = {
 131     device = "${pkgs.sshfs-fuse}/bin/sshfs#julm@losurdo.wg:/";
 132     fsType = "fuse";
 133     inherit options;
 134   };
 135   "/mnt/mermet" = {
 136     device = "${pkgs.sshfs-fuse}/bin/sshfs#julm@mermet.wg:/";
 137     fsType = "fuse";
 138     inherit options;
 139   };
 140   "/mnt/ilico/severine" = {
 141     device = "https://nuage.ilico.org/remote.php/dav/files/severine/";
 142     fsType = "davfs";
 143     options =
 144       let conf = pkgs.writeText "davfs2.conf" ''
 145         backup_dir /home/julm/.local/share/davfs2/ilico/severine
 146         secrets /home/julm/.davfs2/secrets
 147       ''; in
 148       [ "conf=${conf}" "user" "noexec" "nosuid"
 149         "noauto" "nofail" "_netdev" "reconnect"
 150         "x-systemd.automount"
 151         "x-systemd.device-timeout=1m"
 152         "x-systemd.idle-timeout=1m"
 153         "x-systemd.mount-timeout=10s"
 154       ];
 155   };
 156 };
 157
 158 networking.firewall.extraCommands = ''
 159   ip46tables -A nixos-fw -i wg-intra -p tcp -m tcp --dport 8000 -j ACCEPT
 160 '';
 161
 162 services.kubo = {
 163   #enable = true;
 164   defaultMode = "online";
 165   autoMount = true;
 166   enableGC = true;
 167   localDiscovery = false;
 168   extraConfig = {
 169     Datastore.StorageMax = "10GB";
 170     Discovery.MDNS.Enabled = false;
 171     #Bootstrap = [
 172     #];
 173     #Swarm.AddrFilters = null;
 174   };
 175   startWhenNeeded = true;
 176 };
 177
 178 services.udev.packages = [
 179   # Allow the console user access the Yubikey USB device node,
 180   # needed for challenge/response to work correctly.
 181   pkgs.yubikey-personalization
 182 ];
 183
 184 services.xserver = {
 185   desktopManager = {
 186     session = [
 187       # Let the session be generated by home-manager
 188       { name = "home-manager";
 189         start = ''
 190           ${pkgs.runtimeShell} $HOME/.hm-xsession &
 191           waitPID=$!
 192         '';
 193       }
 194     ];
 195   };
 196   displayManager = {
 197     defaultSession = "home-manager";
 198     #defaultSession = "none+xmonad";
 199     #defaultSession = "mate";
 200     #defaultSession = "cinnamon";
 201     autoLogin = {
 202       user = config.users.users.julm.name;
 203     };
 204   };
 205 };
 206
 207 # This value determines the NixOS release with which your system is to be
 208 # compatible, in order to avoid breaking some software such as database
 209 # servers. You should change this only after NixOS release notes say you should.
 210 system.stateVersion = "20.09"; # Did you read the comment?
 211 }