home-manager/profiles/nvim.nix

   1 {
   2   inputs,
   3   lib,
   4   pkgs,
   5   config,
   6   ...
   7 }:
   8 let
   9   nvim-impure = "/home/julm/work/sourcephile/nix/julm-nix/home-manager/profiles/nvim/";
  10   optionalPlugin = plugin: {
  11     inherit plugin;
  12     optional = true;
  13   };
  14 in
  15 {
  16   # DevelopmentNote: home-manager provides a (convoluted) wrapper
  17   # around pkgs.wrapNeovimUnstable,
  18   # and writes a minimal ~/.config/nvim/init.lua
  19   # which is here configured to source ./nvim from:
  20   # - either ${nvim-impure} which is where I store ./nvim before it gets into the Nix store.
  21   # - or ./nvim copied into the Nix store when rebuilding the system with home-manager.
  22   #
  23   # So, for quick feedback:
  24   # - if only ./nvim has changed: relaunch nvim
  25   # - or if only new plugin packages are required, rebuild nvim:
  26   #     nix -L build .#nixosConfigurations.nan2gua1.config.home-manager.users.julm.programs.neovim.finalPackage &&
  27   #     result/bin/nvim
  28   # - or if external packages need to be install: reinstall normally
  29   programs.neovim = {
  30     enable = lib.mkDefault true;
  31     extraLuaConfig = ''
  32       -- Lua config for normal usage
  33       vim.opt.runtimepath:prepend('${./nvim}')
  34
  35       -- Lua config for quick feedback when changing ./nvim
  36       vim.opt.runtimepath:prepend("${nvim-impure}")
  37
  38       -- Load ./nvim/lua/config
  39       require("config")
  40
  41       -- Lazy load ./nvim/lua/plugins
  42       require("lz.n").load("plugins")
  43
  44       -- Overrides `require()` to also search for optional plugins and load them with lz.n
  45       require("lzn-auto-require").enable()
  46     '';
  47     plugins = [
  48       pkgs.vimPlugins.lz-n
  49       pkgs.vimPlugins.lzn-auto-require
  50     ]
  51     ++ lib.map optionalPlugin [
  52       pkgs.vimPlugins.blink-cmp
  53       pkgs.vimPlugins.comment-nvim
  54       pkgs.vimPlugins.conform-nvim
  55       pkgs.vimPlugins.fastaction-nvim
  56       #pkgs.vimPlugins.fine-cmdline-nvim
  57       pkgs.vimPlugins.git-conflict-nvim
  58       pkgs.vimPlugins.github-nvim-theme
  59       pkgs.vimPlugins.gitlinker-nvim
  60       pkgs.vimPlugins.gitsigns-nvim
  61       pkgs.vimPlugins.haskell-tools-nvim
  62       pkgs.vimPlugins.hunk-nvim
  63       pkgs.vimPlugins.image-nvim
  64       (pkgs.vimUtils.buildVimPlugin {
  65         pname = "jj.nvim";
  66         version = "master";
  67         src = inputs.jj-nvim;
  68       })
  69       pkgs.vimPlugins.lualine-nvim
  70       /*
  71         (pkgs.vimUtils.buildVimPlugin {
  72           pname = "modes.nvim";
  73           version = "master";
  74           src = inputs.modes-nvim;
  75         })
  76       */
  77       pkgs.vimPlugins.neo-tree-nvim
  78       #pkgs.vimPlugins.neovim-ayu
  79       pkgs.vimPlugins.nvim-colorizer-lua
  80       pkgs.vimPlugins.nvim-fzf # For telescope
  81       pkgs.vimPlugins.nvim-lint
  82       pkgs.vimPlugins.nvim-navbuddy
  83       pkgs.vimPlugins.nvim-navic # For navbuddy
  84       pkgs.vimPlugins.nvim-treesitter
  85       pkgs.vimPlugins.nvim-web-devicons
  86       /*
  87         (pkgs.vimUtils.buildVimPlugin {
  88           pname = "solarized-osaka.nvim";
  89           version = "master";
  90           src = inputs.solarized-osaka-nvim;
  91           doCheck = false;
  92         })
  93       */
  94       pkgs.vimPlugins.telescope-fzf-native-nvim
  95       pkgs.vimPlugins.telescope-git-conflicts-nvim
  96       pkgs.vimPlugins.telescope-live-grep-args-nvim
  97       pkgs.vimPlugins.telescope-nvim
  98       pkgs.vimPlugins.telescope-smart-history-nvim
  99       pkgs.vimPlugins.trouble-nvim
 100       pkgs.vimPlugins.vim-illuminate
 101       pkgs.vimPlugins.which-key-nvim
 102     ];
 103
 104     viAlias = true;
 105     vimAlias = false;
 106
 107     withNodeJs = false;
 108     #withPerl = false;
 109     withPython3 = false;
 110     withRuby = false;
 111     # For image-nvim
 112     extraLuaPackages = ps: [ ps.magick ];
 113     extraPackages = [ pkgs.imagemagick ];
 114
 115     # Jailing neovim
 116     package =
 117       pkgs.firejailWrap {
 118         package = pkgs.neovim-unwrapped;
 119         args = [
 120           "--quiet"
 121
 122           # For image-nvim
 123           "--noblacklist=/tmp/tmux-*"
 124
 125           # For git status, eg. ~/.config/git/ignore
 126           "--noblacklist=\\\${HOME}/.config/git"
 127
 128           # Reallow cc for LSPs, including Haskell's LSP
 129           "--ignore=include disable-devel.inc"
 130
 131           "--profile=${pkgs.firejail}/etc/firejail/nvim.profile"
 132         ];
 133       }
 134       // {
 135         inherit (pkgs.neovim-unwrapped) lua;
 136       };
 137   };
 138   home.packages = lib.mkIf config.programs.neovim.enable (
 139     lib.flatten (
 140       lib.attrValues {
 141         formatters = [
 142           pkgs.gdtoolkit_4
 143           pkgs.nixfmt-rfc-style
 144           #pkgs.fourmolu
 145           #pkgs.rustfmt
 146           pkgs.shfmt
 147           pkgs.stylua
 148         ];
 149         linters = [
 150           pkgs.statix
 151           pkgs.deadnix
 152           pkgs.shellcheck
 153           #pkgs.hlint
 154         ];
 155         lsp = [
 156           pkgs.bash-language-server
 157           pkgs.lua-language-server
 158           pkgs.nixd
 159           pkgs.nil
 160           #pkgs.rust-analyzer
 161         ];
 162         snacks = [
 163           pkgs.fd
 164           pkgs.ripgrep
 165         ];
 166         neovim = [
 167           pkgs.ripgrep
 168         ]
 169         ++ lib.optionals pkgs.stdenv.hostPlatform.isLinux [
 170           pkgs.xclip
 171           pkgs.wl-clipboard
 172         ];
 173       }
 174     )
 175   );
 176 }