home-manager/profiles/nvim.nix

   1 {
   2   inputs,
   3   lib,
   4   pkgs,
   5   #pkgs-unstable-latest,
   6   config,
   7   ...
   8 }:
   9 let
  10   nvim-impure = "/home/julm/work/sourcephile/nix/julm-nix/home-manager/profiles/nvim/";
  11   optionalPlugin = plugin: {
  12     inherit plugin;
  13     optional = true;
  14   };
  15 in
  16 {
  17   # Explanation(maint/modifiability):
  18   # home-manager provides a (convoluted) wrapper around pkgs.wrapNeovimUnstable,
  19   # and writes a minimal ~/.config/nvim/init.lua
  20   # which is here configured to source ./nvim from:
  21   # - either ${nvim-impure} which is where I store ./nvim before it gets into the Nix store.
  22   # - or ./nvim copied into the Nix store when rebuilding the system with home-manager.
  23   #
  24   # So, for quick feedback:
  25   # - if only ./nvim has changed: relaunch nvim
  26   # - or if only new plugin packages are required, rebuild nvim:
  27   #     nix -L build .#nixosConfigurations.nan2gua1.config.home-manager.users.julm.programs.neovim.finalPackage &&
  28   #     result/bin/nvim
  29   # - or if external packages need to be install: reinstall normally
  30   programs.neovim = {
  31     enable = lib.mkDefault true;
  32     extraLuaConfig = lib.concatStringsSep "\n" [
  33       # Lua config for normal usage
  34       "vim.opt.runtimepath:prepend('${./nvim}')"
  35       # Lua config for quick feedback when changing ./nvim
  36       "vim.opt.runtimepath:prepend('${nvim-impure}')"
  37       # Load ./nvim/lua/config
  38       "require('config')"
  39       # Lazy load ./nvim/lua/plugins
  40       "require('lz.n').load('plugins')"
  41       # Overrides `require()` to also search for optional plugins and load them with lz.n
  42       "require('lzn-auto-require').enable()"
  43     ];
  44     plugins = [
  45       pkgs.vimPlugins.lz-n
  46       pkgs.vimPlugins.lzn-auto-require
  47     ]
  48     ++ lib.map optionalPlugin [
  49       pkgs.vimPlugins.blink-cmp
  50       pkgs.vimPlugins.blink-emoji-nvim
  51       (pkgs.vimUtils.buildVimPlugin {
  52         pname = "bufstack";
  53         version = "main";
  54         src = inputs.bufstack;
  55       })
  56       pkgs.vimPlugins.comment-nvim
  57       pkgs.vimPlugins.conform-nvim
  58       pkgs.vimPlugins.diffview-nvim
  59       pkgs.vimPlugins.fastaction-nvim
  60       pkgs.vimPlugins.FixCursorHold-nvim # For neotest
  61       #pkgs.vimPlugins.fine-cmdline-nvim
  62       pkgs.vimPlugins.git-conflict-nvim
  63       pkgs.vimPlugins.github-nvim-theme
  64       #pkgs-unstable.vimPlugins.vim-moonfly-colors
  65       pkgs.vimPlugins.gitlinker-nvim
  66       pkgs.vimPlugins.gitsigns-nvim
  67       pkgs.vimPlugins.haskell-tools-nvim
  68       (pkgs.vimUtils.buildVimPlugin {
  69         pname = "jj-fugitive.nvim";
  70         version = "main";
  71         src = inputs.jj-fugitive;
  72       })
  73       (pkgs.vimUtils.buildVimPlugin {
  74         pname = "jj-diffconflicts.nvim";
  75         version = "main";
  76         src = inputs.jj-diffconflicts;
  77       })
  78       pkgs.vimPlugins.elixir-tools-nvim
  79       pkgs.vimPlugins.hunk-nvim
  80       pkgs.vimPlugins.image-nvim
  81       (pkgs.vimUtils.buildVimPlugin {
  82         pname = "jj.nvim";
  83         version = "master";
  84         src = inputs.sivansh11-jj-nvim;
  85       })
  86       pkgs.vimPlugins.lualine-nvim
  87       /*
  88         (pkgs.vimUtils.buildVimPlugin {
  89           pname = "modes.nvim";
  90           version = "master";
  91           src = inputs.modes-nvim;
  92         })
  93       */
  94       pkgs.vimPlugins.monokai-pro-nvim
  95       pkgs.vimPlugins.neo-tree-nvim
  96       pkgs.vimPlugins.neotest
  97       pkgs.vimPlugins.neotest-haskell
  98       pkgs.vimPlugins.neotest-plenary
  99       #pkgs.vimPlugins.neovim-ayu
 100       pkgs.vimPlugins.noice-nvim
 101       pkgs.vimPlugins.nui-nvim
 102       pkgs.vimPlugins.nvim-colorizer-lua
 103       pkgs.vimPlugins.nvim-fzf # For telescope
 104       pkgs.vimPlugins.nvim-lint
 105       pkgs.vimPlugins.nvim-navbuddy
 106       pkgs.vimPlugins.nvim-navic # For navbuddy
 107       pkgs.vimPlugins.nvim-nio
 108       pkgs.vimPlugins.nvim-rg
 109       pkgs.vimPlugins.nvim-treesitter.withAllGrammars
 110       pkgs.vimPlugins.nvim-web-devicons
 111       pkgs.vimPlugins.octo-nvim
 112       pkgs.vimPlugins.snacks-nvim
 113       /*
 114         (pkgs.vimUtils.buildVimPlugin {
 115           pname = "solarized-osaka.nvim";
 116           version = "master";
 117           src = inputs.solarized-osaka-nvim;
 118           doCheck = false;
 119         })
 120       */
 121       # pkgs.vimPlugins.sqlite-lua # For telescope-smart-history.nvim
 122       pkgs.vimPlugins.telescope-fzf-native-nvim
 123       pkgs.vimPlugins.telescope-git-conflicts-nvim
 124       pkgs.vimPlugins.telescope-live-grep-args-nvim
 125       pkgs.vimPlugins.telescope-nvim
 126       pkgs.vimPlugins.telescope-smart-history-nvim
 127       pkgs.vimPlugins.toggleterm-nvim
 128       pkgs.vimPlugins.trouble-nvim
 129       pkgs.vimPlugins.vim-illuminate
 130       #pkgs-unstable-latest.vimPlugins.vscode-diff-nvim
 131       pkgs.vimPlugins.which-key-nvim
 132     ];
 133
 134     viAlias = true;
 135     vimAlias = false;
 136
 137     withNodeJs = false;
 138     #withPerl = false;
 139     withPython3 = false;
 140     withRuby = false;
 141     # For image-nvim
 142     extraLuaPackages = ps: [ ps.magick ];
 143     extraPackages = [ pkgs.imagemagick ];
 144
 145     # Jailing neovim
 146     package =
 147       pkgs.firejailWrap {
 148         package = pkgs.neovim-unwrapped;
 149         args = [
 150           "--quiet"
 151           "--profile=nvim"
 152         ];
 153       }
 154       // {
 155         inherit (pkgs.neovim-unwrapped) lua;
 156       };
 157   };
 158   xdg.configFile."firejail/nvim.local".text = lib.concatStringsSep "\n" [
 159     # For jj
 160     "include ${firejail/allow-jujutsu.inc}"
 161     # For image-nvim
 162     "noblacklist /tmp/tmux-*"
 163     # For git status, eg. ~/.config/git/ignore
 164     "noblacklist \${HOME}/.config/git"
 165     # Reallow cc for LSPs, including Haskell's LSP
 166     "ignore include disable-devel.inc"
 167   ];
 168   home.packages = lib.mkIf config.programs.neovim.enable (
 169     lib.flatten (
 170       lib.attrValues {
 171         formatters = [
 172           pkgs.gdtoolkit_4
 173           pkgs.nixfmt-rfc-style
 174           #pkgs.fourmolu
 175           #pkgs.rustfmt
 176           pkgs.shfmt
 177           pkgs.stylua
 178         ];
 179         linters = [
 180           pkgs.statix
 181           pkgs.deadnix
 182           pkgs.shellcheck
 183           #pkgs.hlint
 184         ];
 185         lsp = [
 186           pkgs.bash-language-server
 187           #pkgs.elixir-ls
 188           pkgs.lua-language-server
 189           #pkgs.next-ls
 190           pkgs.nil
 191           pkgs.nixd
 192           #pkgs.rust-analyzer
 193           pkgs.taplo
 194         ];
 195         snacks = [
 196           pkgs.fd
 197           pkgs.ripgrep
 198         ];
 199         neovim = [
 200           pkgs.ripgrep
 201         ]
 202         ++ lib.optionals pkgs.stdenv.hostPlatform.isLinux [
 203           pkgs.xclip
 204           pkgs.wl-clipboard
 205         ];
 206       }
 207     )
 208   );
 209 }