home-manager/profiles/nvim.nix

   1 {
   2   inputs,
   3   lib,
   4   pkgs,
   5   config,
   6   ...
   7 }:
   8 let
   9   nvim-impure = "/home/julm/work/sourcephile/nix/julm-nix/home-manager/profiles/nvim/";
  10   optionalPlugin = plugin: {
  11     inherit plugin;
  12     optional = true;
  13   };
  14 in
  15 {
  16   # DevelopmentNote: home-manager provides a (convoluted) wrapper
  17   # around pkgs.wrapNeovimUnstable,
  18   # and writes a minimal ~/.config/nvim/init.lua
  19   # which is here configured to source ./nvim from:
  20   # - either ${nvim-impure} which is where I store ./nvim before it gets into the Nix store.
  21   # - or ./nvim copied into the Nix store when rebuilding the system with home-manager.
  22   #
  23   # So, for quick feedback:
  24   # - if only ./nvim has changed: relaunch nvim
  25   # - or if only new plugin packages are required, rebuild nvim:
  26   #     nix -L build .#nixosConfigurations.nan2gua1.config.home-manager.users.julm.programs.neovim.finalPackage &&
  27   #     result/bin/nvim
  28   # - or if external packages need to be install: reinstall normally
  29   programs.neovim = {
  30     enable = lib.mkDefault true;
  31     extraLuaConfig = ''
  32       -- Lua config for normal usage
  33       vim.opt.runtimepath:prepend('${./nvim}')
  34
  35       -- Lua config for quick feedback when changing ./nvim
  36       vim.opt.runtimepath:prepend("${nvim-impure}")
  37
  38       -- Load ./nvim/lua/config
  39       require("config")
  40
  41       -- Lazy load ./nvim/lua/plugins
  42       require("lz.n").load("plugins")
  43
  44       -- Overrides `require()` to also search for optional plugins and load them with lz.n
  45       require("lzn-auto-require").enable()
  46     '';
  47     plugins = [
  48       pkgs.vimPlugins.lz-n
  49       pkgs.vimPlugins.lzn-auto-require
  50     ]
  51     ++ lib.map optionalPlugin [
  52       pkgs.vimPlugins.blink-cmp
  53       pkgs.vimPlugins.comment-nvim
  54       pkgs.vimPlugins.conform-nvim
  55       pkgs.vimPlugins.fastaction-nvim
  56       #pkgs.vimPlugins.fine-cmdline-nvim
  57       pkgs.vimPlugins.git-conflict-nvim
  58       pkgs.vimPlugins.github-nvim-theme
  59       pkgs.vimPlugins.gitlinker-nvim
  60       pkgs.vimPlugins.gitsigns-nvim
  61       pkgs.vimPlugins.haskell-tools-nvim
  62       pkgs.vimPlugins.hunk-nvim
  63       pkgs.vimPlugins.image-nvim
  64       (pkgs.vimUtils.buildVimPlugin {
  65         pname = "jj.nvim";
  66         version = "master";
  67         src = inputs.jj-nvim;
  68       })
  69       pkgs.vimPlugins.lualine-nvim
  70       /*
  71         (pkgs.vimUtils.buildVimPlugin {
  72           pname = "modes.nvim";
  73           version = "master";
  74           src = inputs.modes-nvim;
  75         })
  76       */
  77       pkgs.vimPlugins.neo-tree-nvim
  78       #pkgs.vimPlugins.neovim-ayu
  79       pkgs.vimPlugins.nvim-colorizer-lua
  80       pkgs.vimPlugins.nvim-fzf # For telescope
  81       pkgs.vimPlugins.nvim-lint
  82       pkgs.vimPlugins.nvim-navbuddy
  83       pkgs.vimPlugins.nvim-navic # For navbuddy
  84       pkgs.vimPlugins.nvim-treesitter
  85       pkgs.vimPlugins.nvim-web-devicons
  86       /*
  87         (pkgs.vimUtils.buildVimPlugin {
  88           pname = "solarized-osaka.nvim";
  89           version = "master";
  90           src = inputs.solarized-osaka-nvim;
  91           doCheck = false;
  92         })
  93       */
  94       pkgs.vimPlugins.telescope-fzf-native-nvim
  95       pkgs.vimPlugins.telescope-git-conflicts-nvim
  96       pkgs.vimPlugins.telescope-live-grep-args-nvim
  97       pkgs.vimPlugins.telescope-nvim
  98       pkgs.vimPlugins.vim-illuminate
  99       pkgs.vimPlugins.which-key-nvim
 100     ];
 101
 102     viAlias = true;
 103     vimAlias = true;
 104
 105     withNodeJs = false;
 106     #withPerl = false;
 107     withPython3 = false;
 108     withRuby = false;
 109     # For image-nvim
 110     extraLuaPackages = ps: [ ps.magick ];
 111     extraPackages = [ pkgs.imagemagick ];
 112
 113     # Jailing neovim
 114     package =
 115       pkgs.firejailWrap {
 116         package = pkgs.neovim-unwrapped;
 117         args = [
 118           "--quiet"
 119
 120           # For image-nvim
 121           "--noblacklist=/tmp/tmux-*"
 122
 123           "--profile=${pkgs.firejail}/etc/firejail/nvim.profile"
 124         ];
 125       }
 126       // {
 127         inherit (pkgs.neovim-unwrapped) lua;
 128       };
 129   };
 130   home.packages = lib.mkIf config.programs.neovim.enable (
 131     lib.flatten (
 132       lib.attrValues {
 133         formatters = [
 134           pkgs.gdtoolkit_4
 135           pkgs.nixfmt-rfc-style
 136           #pkgs.fourmolu
 137           #pkgs.rustfmt
 138           pkgs.stylua
 139         ];
 140         linters = [
 141           pkgs.statix
 142           pkgs.deadnix
 143           pkgs.shellcheck
 144           #pkgs.hlint
 145         ];
 146         lsp = [
 147           pkgs.bash-language-server
 148           pkgs.lua-language-server
 149           pkgs.nixd
 150           pkgs.nil
 151           #pkgs.rust-analyzer
 152         ];
 153         snacks = [
 154           pkgs.fd
 155           pkgs.ripgrep
 156         ];
 157         neovim = [
 158           pkgs.ripgrep
 159         ]
 160         ++ lib.optionals pkgs.stdenv.hostPlatform.isLinux [
 161           pkgs.xclip
 162           pkgs.wl-clipboard
 163         ];
 164       }
 165     )
 166   );
 167 }