flake.nix

   1 {
   2   /*
   3     nixConfig = {
   4     extra-substituters = [
   5       "https://nix-community.cachix.org"
   6     ];
   7     extra-trusted-public-keys = [
   8       "nix-community.cachix.org-1:mB9FSh9qf2dCimDSUo8Zy7bkq5CX+/rkCWyvRCYg3Fs="
   9     ];
  10     };
  11   */
  12
  13   inputs = {
  14     doom-emacs.flake = false;
  15     doom-emacs.url = "github:hlissner/doom-emacs";
  16     home-manager.inputs.nixpkgs.follows = "nixpkgs";
  17     home-manager.url = "github:nix-community/home-manager/release-24.05";
  18     nix-formatter-pack.inputs.nixpkgs.follows = "nixpkgs";
  19     nix-formatter-pack.url = "github:Gerschtli/nix-formatter-pack";
  20     nixpkgs.url = "github:NixOS/nixpkgs/nixos-24.05";
  21     git-hooks.inputs.nixpkgs.follows = "nixpkgs";
  22     git-hooks.inputs.nixpkgs-stable.follows = "nixpkgs";
  23     git-hooks.url = "github:cachix/git-hooks.nix";
  24   };
  25
  26   outputs = inputs:
  27     let
  28       remoteNixpkgsPatches = import nixpkgs/patches.nix;
  29       localNixpkgsPatches = [
  30       ];
  31       originPkgs = inputs.nixpkgs.legacyPackages."x86_64-linux";
  32       nixpkgsPath = originPkgs.applyPatches {
  33         name = "nixpkgs-patched";
  34         src = inputs.nixpkgs.outPath;
  35         patches = map originPkgs.fetchpatch remoteNixpkgsPatches ++ localNixpkgsPatches;
  36         postPatch = ''
  37           patch=$(printf '%s\n' ${builtins.concatStringsSep " "
  38              (map (p: p.sha256) remoteNixpkgsPatches ++ localNixpkgsPatches)} |
  39             sort | sha256sum | cut -c -7)
  40           echo "-patch-$patch" >.version-suffix
  41         '';
  42       };
  43       profile = "/nix/var/nix/profiles/system";
  44       inherit (inputs.nixpkgs) lib;
  45       overlays = system:
  46         import nixpkgs/overlays.nix ++ [
  47         ];
  48       #nixosSystem = lib.nixosSystem;
  49       nixosSystem = import (nixpkgsPath + "/nixos/lib/eval-config.nix");
  50       forAllSystems = f: lib.genAttrs lib.systems.flakeExposed (system: f rec {
  51         inherit system;
  52         #pkgs = inputs.nixpkgs.legacyPackages.${system};
  53         pkgs = import nixpkgsPath {
  54           inherit system;
  55           overlays = overlays system;
  56         };
  57       });
  58       self = with lib.fileset; toSource {
  59         root = ./.;
  60         fileset =
  61           let exts = [ "clear" "conf" "cred" "crt" "css" "el" "hs" "json" "nix" "patch" "pem" "pub" "sh" "theme" "vim" ]; in
  62           unions [
  63             (fileFilter (file: lib.any file.hasExt exts) ./home-manager)
  64             (fileFilter (file: lib.any file.hasExt exts) ./homes)
  65             (fileFilter (file: lib.any file.hasExt exts) ./hosts)
  66             (fileFilter (file: lib.any file.hasExt exts) ./nixos)
  67             (fileFilter (file: lib.any file.hasExt exts) ./nixpkgs)
  68             (fileFilter (file: lib.any file.hasExt exts) ./share)
  69             (fileFilter (file: lib.any file.hasExt exts) ./users)
  70             ./shell.nix
  71           ];
  72       };
  73     in
  74     rec {
  75       # nix -L build .#hello
  76       packages = forAllSystems ({ pkgs, ... }: pkgs);
  77
  78       # nix -L build .#nixosConfigurations.oignon.config.system.build.toplevel
  79       # nix -L build .#nixosConfigurations.oignon.config.boot.kernelPackages.kernel.configfile
  80       # nix -L build .#nixosConfigurations.oignon.pkgs.hello
  81       # nix eval --raw .#nixosConfigurations.oignon.config.networking.nftables.ruleset
  82       nixosConfigurations = lib.genAttrs
  83         (builtins.attrNames (lib.filterAttrs (_n: v: v == "directory") (builtins.readDir (self + "/hosts"))))
  84         (hostName: nixosSystem {
  85           system = null;
  86           specialArgs = {
  87             # Required to avoid infinite recursion
  88             # when `inputs` is used in `imports`.
  89             inherit inputs;
  90           };
  91           modules = [
  92             nixos/default.nix
  93             (import (self + "/hosts/${hostName}.nix"))
  94             ({ config, ... }: {
  95               _module.args = {
  96                 inherit hostName;
  97                 hosts = nixosConfigurations;
  98                 host = nixosConfigurations.${hostName}._module.args;
  99               };
 100               nixpkgs.overlays = overlays config.nixpkgs.hostPlatform.system;
 101               nixpkgs.config.allowUnfreePredicate = pkg: builtins.elem (lib.getName pkg) [
 102                 "anydesk"
 103                 "cudatoolkit"
 104                 "geogebra"
 105                 "hplip"
 106                 "memtest86-efi"
 107                 "nvidia-settings"
 108                 "nvidia-x11"
 109               ];
 110             })
 111             inputs.home-manager.nixosModules.home-manager
 112             {
 113               home-manager.useGlobalPkgs = true;
 114               home-manager.useUserPackages = true;
 115               home-manager.verbose = true;
 116               home-manager.backupFileExtension = null;
 117               home-manager.extraSpecialArgs = {
 118                 inherit hostName inputs;
 119               };
 120             }
 121           ];
 122         });
 123
 124       # nix -L develop  or  direnv allow
 125       devShells = forAllSystems ({ pkgs, system, ... }:
 126         {
 127           default = pkgs.callPackage (self + "/shell.nix")
 128             {
 129               inherit pkgs inputs system nixpkgsPath;
 130               inherit (checks.${system}.git-hooks-check) shellHook;
 131             };
 132         }
 133       );
 134
 135       # nix -L run .#oignon.switch
 136       apps = forAllSystems ({ pkgs, system, ... }:
 137         with builtins;
 138         mapAttrs
 139           (hostName: { config, ... }:
 140             let
 141               inherit (config.system) build;
 142               scriptApp = scriptName: ps: script: {
 143                 type = "app";
 144                 program = (pkgs.writeShellScript "${hostName}-${scriptName}" ''
 145                   export PATH="${lib.makeBinPath ([ pkgs.coreutils ] ++ ps)}:$PATH"
 146                   set -eux
 147                   ${script}
 148                 '').outPath;
 149               };
 150             in
 151             {
 152               # Example: nix run .#aubergine.switch
 153               "switch" = scriptApp "switch" [ ] ''
 154                 shopt -s globstar
 155
 156                 chmod -R g-rwx,o-rwx **/*.gpg
 157                 trap 'git reset **/*.gpg' EXIT
 158                 git rm -rf --cached --ignore-unmatch **/*.gpg # prevent copying to /nix/store
 159
 160                 nix-store --add-root hosts/${hostName}.nixpkgs --indirect --realise ${nixpkgsPath}
 161                 nix-store --add-root hosts/${hostName}.root --indirect --realise ${build.toplevel}
 162
 163                 nix copy --to "ssh://${config.install.target}?''${targetStore-}"${lib.optionalString config.install.substituteOnDestination " --substitute-on-destination"} ${build.toplevel}
 164
 165                 if ssh ${config.install.target} set -x ';' \
 166                   systemctl reset-failed nixos-fallback '2>/dev/null' ';' \
 167                   test "''${NO_NIXOS_FALLBACK:+set}" '||' \
 168                   systemd-run -u nixos-fallback --description=nixos-fallback /bin/sh -xc '''\'''
 169                     PATH=${with pkgs; lib.makeBinPath [ coreutils nix systemd ]}
 170                     sleep $((10 * 60))
 171                     ${profile}/bin/switch-to-configuration switch
 172                     systemctl reboot
 173                   '\'''' '&&' \
 174                   ${build.toplevel}/bin/switch-to-configuration test
 175                 then
 176                   ssh ${config.install.target} -o ControlPath=none set -x ';' \
 177                     systemctl stop nixos-fallback.service ';' \
 178                     nix-env --profile ${profile} --set '${build.toplevel}' ';' \
 179                     ${build.toplevel}/bin/switch-to-configuration boot '&&' \
 180                     nix-env --delete-generations 7d --profile ${profile}
 181                 else
 182                   tput rev
 183                   echo WARNING: switch-to-configuration was not registered at boot
 184                   tput sgr0
 185                   ssh ${config.install.target} -o ControlPath=none set -x ';' \
 186                     systemctl stop nixos-fallback.service
 187                   false
 188                 fi
 189               '';
 190             })
 191           nixosConfigurations);
 192
 193       # nix flake check
 194       checks = forAllSystems (args: with args; {
 195         git-hooks-check = inputs.git-hooks.lib.${system}.run {
 196           src = self;
 197           hooks = {
 198             nixpkgs-fmt.enable = true;
 199           };
 200         };
 201       });
 202
 203       # nix fmt
 204       formatter = forAllSystems ({ pkgs, ... }:
 205         inputs.nix-formatter-pack.lib.mkFormatter {
 206           inherit pkgs;
 207           config = {
 208             tools = {
 209               deadnix.enable = true;
 210               nixpkgs-fmt.enable = true;
 211               statix.enable = true;
 212             };
 213           };
 214         }
 215       );
 216     };
 217 }