hosts/oignon.nix

   1 { config, pkgs, lib, inputs, private, hostName, ... }:
   2 {
   3 imports = [
   4   ../nixos/profiles/builder.nix
   5   ../nixos/profiles/debug.nix
   6   ../nixos/profiles/dnscrypt-proxy2.nix
   7   ../nixos/profiles/graphical.nix
   8   ../nixos/profiles/lang-fr.nix
   9   ../nixos/profiles/networking.nix
  10   ../nixos/profiles/printing.nix
  11   ../nixos/profiles/security.nix
  12   ../nixos/profiles/system.nix
  13   ../nixos/profiles/tor.nix
  14   ../nixos/profiles/irssi.nix
  15   ../nixos/profiles/wireguard/wg-intra.nix
  16   oignon/backup.nix
  17   oignon/hardware.nix
  18   oignon/wireguard.nix
  19 ];
  20
  21 home-manager.users.julm = {
  22   imports = [ ../homes/julm.nix ];
  23   host.hardware = [ "ThinkPad" "X201" ];
  24 };
  25 systemd.services.home-manager-julm.postStart = ''
  26   ${pkgs.nix}/bin/nix-env --delete-generations +1 --profile /nix/var/nix/profiles/per-user/julm/home-manager
  27 '';
  28 users.users.julm = {
  29   isNormalUser = true;
  30   uid = 1000;
  31   # Put the hashedPassword in /nix/store, but it will also be in /etc/passwd
  32   # which is already world readable.
  33   hashedPassword = lib.readFile ../private/world/julm/hashedPassword;
  34   extraGroups = [
  35     "adbusers"
  36     "lp"
  37     "networkmanager"
  38     "scanner"
  39     "tor"
  40     "video"
  41     "wheel"
  42     #"ipfs"
  43     config.services.davfs2.davGroup
  44     #"vboxusers"
  45   ];
  46   # If created, zfs-mount.service would require:
  47   # zfs set overlay=yes ${hostName}/home
  48   createHome = false;
  49   openssh.authorizedKeys.keys = map lib.readFile [
  50     ../private/shared/ssh/julm/losurdo.pub
  51   ];
  52 };
  53
  54 nix = {
  55   extraOptions = ''
  56     secret-key-files = ${private}/${hostName}/nix/binary-cache/priv.pem
  57   '';
  58   settings = {
  59     trusted-users = [ config.users.users."julm".name ];
  60     substituters = [
  61       #"http://nix-localcache.losurdo.wg"
  62       "ssh://nix-ssh@losurdo.wg?priority=30"
  63     ];
  64     trusted-public-keys = map lib.readFile [
  65       ../private/shared/nix/losurdo.pub
  66     ];
  67   };
  68   nixPath = lib.mkForce [ "nixpkgs=${inputs.nixpkgs}" ];
  69 };
  70 #environment.etc."nixpkgs".source = pkgs.path;
  71 #environment.etc."nixpkgs-overlays".source = inputs.self + "/nixpkgs";
  72
  73 nix.settings.allowed-users = [ config.users.users."nix-ssh".name ];
  74 nix.sshServe = {
  75   enable = true;
  76   keys = map lib.readFile [
  77     ../private/shared/ssh/julm/losurdo.pub
  78     ../private/shared/ssh/sevy/patate.pub
  79     ../private/shared/ssh/julm/oignon.pub
  80   ];
  81 };
  82
  83 environment.systemPackages = [
  84   pkgs.riseup-vpn # Can't be installed by home-manager because it needs to install policy-kit rules
  85 ];
  86
  87 boot.extraModulePackages = [
  88   #config.boot.kernelPackages.v4l2loopback
  89 ];
  90
  91 programs.fuse.userAllowOther = true;
  92
  93 services.davfs2.enable = true;
  94
  95 fileSystems =
  96   # Use the user's gpg-agent session to query
  97   # for the password of the SSH key when auto-mounting.
  98   let
  99     sshAsUser = user:
 100       pkgs.writeScript "sshAsUser-${user}" ''
 101          exec ${pkgs.sudo}/bin/sudo -i -u ${user} \
 102            ${pkgs.openssh}/bin/ssh "$@"
 103       '';
 104     options =
 105       [
 106         "noatime" "noexec" "nosuid"
 107         "user" "uid=julm" "gid=users" "allow_other"
 108         "_netdev" "ssh_command=${sshAsUser "julm"}" #  "reconnect"
 109         "noauto" "x-gvfs-hide" "x-systemd.automount"
 110         #"Compression=yes" # YMMV
 111         # Disconnect approximately 2*15=30 seconds after a network failure
 112         "ServerAliveCountMax=1"
 113         "ServerAliveInterval=15"
 114       ];
 115   in {
 116   "/mnt/losurdo" = {
 117     device = "${pkgs.sshfs-fuse}/bin/sshfs#julm@losurdo.wg:/";
 118     fsType = "fuse";
 119     inherit options;
 120   };
 121   "/mnt/mermet" = {
 122     device = "${pkgs.sshfs-fuse}/bin/sshfs#julm@mermet.wg:/";
 123     fsType = "fuse";
 124     inherit options;
 125   };
 126   "/mnt/ilico/severine" = {
 127     device = "https://nuage.ilico.org/remote.php/dav/files/severine/";
 128     fsType = "davfs";
 129     options =
 130       let conf = pkgs.writeText "davfs2.conf" ''
 131         backup_dir /home/julm/.local/share/davfs2/ilico/severine
 132         secrets /home/julm/.davfs2/secrets
 133       ''; in
 134       [ "conf=${conf}" "user" "noexec" "nosuid"
 135         "noauto" "nofail" "_netdev" "reconnect"
 136         "x-systemd.automount"
 137         "x-systemd.device-timeout=1m"
 138         "x-systemd.idle-timeout=1m"
 139         "x-systemd.mount-timeout=10s"
 140       ];
 141   };
 142 };
 143
 144 networking.firewall.extraCommands = ''
 145   ip46tables -A nixos-fw -i wg-intra -p tcp -m tcp --dport 8000 -j ACCEPT
 146 '';
 147
 148 services.ipfs = {
 149   #enable = true;
 150   defaultMode = "online";
 151   autoMount = true;
 152   enableGC = true;
 153   localDiscovery = false;
 154   extraConfig = {
 155     Datastore.StorageMax = "10GB";
 156     Discovery.MDNS.Enabled = false;
 157     #Bootstrap = [
 158     #];
 159     #Swarm.AddrFilters = null;
 160   };
 161   startWhenNeeded = true;
 162 };
 163
 164 services.udev.packages = [
 165   # Allow the console user access the Yubikey USB device node,
 166   # needed for challenge/response to work correctly.
 167   pkgs.yubikey-personalization
 168 ];
 169
 170 services.xserver = {
 171   desktopManager = {
 172     session = [
 173       # Let the session be generated by home-manager
 174       { name = "home-manager";
 175         start = ''
 176           ${pkgs.runtimeShell} $HOME/.hm-xsession &
 177           waitPID=$!
 178         '';
 179       }
 180     ];
 181   };
 182   displayManager = {
 183     defaultSession = "home-manager";
 184     #defaultSession = "none+xmonad";
 185     #defaultSession = "mate";
 186     #defaultSession = "cinnamon";
 187     autoLogin = {
 188       user = config.users.users.julm.name;
 189     };
 190   };
 191 };
 192
 193 # This value determines the NixOS release with which your system is to be
 194 # compatible, in order to avoid breaking some software such as database
 195 # servers. You should change this only after NixOS release notes say you should.
 196 system.stateVersion = "20.09"; # Did you read the comment?
 197 }