home-manager/profiles/emacs.nix

   1 {
   2   inputs,
   3   pkgs,
   4   lib,
   5   config,
   6   ...
   7 }:
   8 {
   9   /*
  10     imports = [
  11     inputs.nix-doom-emacs.hmModule
  12     ];
  13     programs.doom-emacs = {
  14     enable = true;
  15     doomPrivateDir =
  16     "${config.home.homeDirectory}/.doom.d";
  17     };
  18   */
  19   services.emacs = {
  20     enable = lib.mkDefault true;
  21     package = config.programs.emacs.finalPackage;
  22     client.enable = true;
  23     socketActivation.enable = true;
  24   };
  25   programs.emacs = {
  26     enable = lib.mkDefault true;
  27     extraPackages = epkgs: [
  28       epkgs.vterm
  29     ];
  30   };
  31   fonts.fontconfig.enable = lib.mkDefault true;
  32   home.packages = with pkgs; [
  33     # DOOM Emacs dependencies
  34     binutils
  35     (ripgrep.override { withPCRE2 = true; })
  36     fd
  37     gnutls
  38     hack-font
  39     imagemagick
  40     zstd
  41     #nodePackages.javascript-typescript-langserver
  42     sqlite
  43     #editorconfig-core-c
  44     #emacs-all-the-icons-fonts
  45     pkgs.nerd-fonts.symbols-only
  46   ];
  47   home.sessionPath = [ "${config.xdg.configHome}/emacs/bin" ];
  48   home.sessionVariables = {
  49     DOOMDIR = "${config.xdg.configHome}/doom";
  50     DOOMLOCALDIR = "${config.xdg.dataHome}/doom";
  51     DOOMPROFILELOADFILE = "${config.xdg.stateHome}/doom/load.el";
  52   };
  53   xdg.configFile = {
  54     "doom/cli.el".text = lib.readFile emacs/cli.el;
  55     "doom/config.el".text = lib.readFile emacs/config.el;
  56     "doom/init.el".text = lib.readFile emacs/init.el;
  57     "doom/packages.el".text = lib.readFile emacs/packages.el;
  58     "emacs" = {
  59       source = inputs.doom-emacs;
  60       # FIXME: the first install takes ages, it timeouts home-manager-${USER}.service
  61       onChange = "${pkgs.writeShellScript "doom-change" ''
  62         export DOOMDIR="${config.home.sessionVariables.DOOMDIR}"
  63         export DOOMLOCALDIR="${config.home.sessionVariables.DOOMLOCALDIR}"
  64         export DOOMPROFILELOADFILE="${config.home.sessionVariables.DOOMPROFILELOADFILE}"
  65         if [ ! -d "$DOOMLOCALDIR" ]; then
  66           ${config.xdg.configHome}/emacs/bin/doom install
  67         else
  68           ${config.xdg.configHome}/emacs/bin/doom sync
  69         fi
  70       ''}";
  71     };
  72   };
  73   xresources.properties = {
  74     #"Emacs.FontBackend" = "xft";
  75   };
  76 }