home-manager/profiles/nvim.nix

   1 {
   2   inputs,
   3   lib,
   4   pkgs,
   5   config,
   6   ...
   7 }:
   8 let
   9   nvim-impure = "/home/julm/work/sourcephile/nix/julm-nix/home-manager/profiles/nvim/";
  10   optionalPlugin = plugin: {
  11     inherit plugin;
  12     optional = true;
  13   };
  14 in
  15 {
  16   # DevelopmentNote: home-manager provides a (convoluted) wrapper
  17   # around pkgs.wrapNeovimUnstable,
  18   # and writes a minimal ~/.config/nvim/init.lua
  19   # which is here configured to source ./nvim from:
  20   # - either ${nvim-impure} which is where I store ./nvim before it gets into the Nix store.
  21   # - or ./nvim copied into the Nix store when rebuilding the system with home-manager.
  22   #
  23   # So, for quick feedback:
  24   # - if only ./nvim has changed: relaunch nvim
  25   # - or if only new plugin packages are required, rebuild nvim:
  26   #     nix -L build .#nixosConfigurations.nan2gua1.config.home-manager.users.julm.programs.neovim.finalPackage &&
  27   #     result/bin/nvim
  28   # - or if external packages need to be install: reinstall normally
  29   programs.neovim = {
  30     enable = lib.mkDefault true;
  31     extraLuaConfig = ''
  32       -- Lua config for normal usage
  33       vim.opt.runtimepath:prepend('${./nvim}')
  34
  35       -- Lua config for quick feedback when changing ./nvim
  36       vim.opt.runtimepath:prepend("${nvim-impure}")
  37
  38       -- Load ./nvim/lua/config
  39       require("config")
  40
  41       -- Lazy load ./nvim/lua/plugins
  42       require("lz.n").load("plugins")
  43
  44       -- Overrides `require()` to also search for optional plugins and load them with lz.n
  45       require("lzn-auto-require").enable()
  46     '';
  47     plugins = [
  48       pkgs.vimPlugins.lz-n
  49       pkgs.vimPlugins.lzn-auto-require
  50     ]
  51     ++ lib.map optionalPlugin [
  52       pkgs.vimPlugins.blink-cmp
  53       pkgs.vimPlugins.comment-nvim
  54       pkgs.vimPlugins.conform-nvim
  55       pkgs.vimPlugins.fastaction-nvim
  56       #pkgs.vimPlugins.fine-cmdline-nvim
  57       pkgs.vimPlugins.git-conflict-nvim
  58       pkgs.vimPlugins.github-nvim-theme
  59       pkgs.vimPlugins.gitlinker-nvim
  60       pkgs.vimPlugins.gitsigns-nvim
  61       pkgs.vimPlugins.haskell-tools-nvim
  62       pkgs.vimPlugins.elixir-tools-nvim
  63       pkgs.vimPlugins.hunk-nvim
  64       pkgs.vimPlugins.image-nvim
  65       (pkgs.vimUtils.buildVimPlugin {
  66         pname = "jj.nvim";
  67         version = "master";
  68         src = inputs.jj-nvim;
  69       })
  70       pkgs.vimPlugins.lualine-nvim
  71       /*
  72         (pkgs.vimUtils.buildVimPlugin {
  73           pname = "modes.nvim";
  74           version = "master";
  75           src = inputs.modes-nvim;
  76         })
  77       */
  78       pkgs.vimPlugins.neo-tree-nvim
  79       #pkgs.vimPlugins.neovim-ayu
  80       pkgs.vimPlugins.nvim-colorizer-lua
  81       pkgs.vimPlugins.nvim-fzf # For telescope
  82       pkgs.vimPlugins.nvim-lint
  83       pkgs.vimPlugins.nvim-navbuddy
  84       pkgs.vimPlugins.nvim-navic # For navbuddy
  85       pkgs.vimPlugins.nvim-treesitter
  86       pkgs.vimPlugins.nvim-web-devicons
  87       /*
  88         (pkgs.vimUtils.buildVimPlugin {
  89           pname = "solarized-osaka.nvim";
  90           version = "master";
  91           src = inputs.solarized-osaka-nvim;
  92           doCheck = false;
  93         })
  94       */
  95       # pkgs.vimPlugins.sqlite-lua # For telescope-smart-history.nvim
  96       pkgs.vimPlugins.telescope-fzf-native-nvim
  97       pkgs.vimPlugins.telescope-git-conflicts-nvim
  98       pkgs.vimPlugins.telescope-live-grep-args-nvim
  99       pkgs.vimPlugins.telescope-nvim
 100       pkgs.vimPlugins.telescope-smart-history-nvim
 101       pkgs.vimPlugins.trouble-nvim
 102       pkgs.vimPlugins.vim-illuminate
 103       pkgs.vimPlugins.which-key-nvim
 104     ];
 105
 106     viAlias = true;
 107     vimAlias = false;
 108
 109     withNodeJs = false;
 110     #withPerl = false;
 111     withPython3 = false;
 112     withRuby = false;
 113     # For image-nvim
 114     extraLuaPackages = ps: [ ps.magick ];
 115     extraPackages = [ pkgs.imagemagick ];
 116
 117     # Jailing neovim
 118     package =
 119       pkgs.firejailWrap {
 120         package = pkgs.neovim-unwrapped;
 121         args = [
 122           "--quiet"
 123
 124           # For image-nvim
 125           "--noblacklist=/tmp/tmux-*"
 126
 127           # For git status, eg. ~/.config/git/ignore
 128           "--noblacklist=\\\${HOME}/.config/git"
 129
 130           # Reallow cc for LSPs, including Haskell's LSP
 131           "--ignore=include disable-devel.inc"
 132
 133           "--profile=${pkgs.firejail}/etc/firejail/nvim.profile"
 134         ];
 135       }
 136       // {
 137         inherit (pkgs.neovim-unwrapped) lua;
 138       };
 139   };
 140   home.packages = lib.mkIf config.programs.neovim.enable (
 141     lib.flatten (
 142       lib.attrValues {
 143         formatters = [
 144           pkgs.gdtoolkit_4
 145           pkgs.nixfmt-rfc-style
 146           #pkgs.fourmolu
 147           #pkgs.rustfmt
 148           pkgs.shfmt
 149           pkgs.stylua
 150         ];
 151         linters = [
 152           pkgs.statix
 153           pkgs.deadnix
 154           pkgs.shellcheck
 155           #pkgs.hlint
 156         ];
 157         lsp = [
 158           pkgs.bash-language-server
 159           pkgs.lua-language-server
 160           pkgs.nixd
 161           pkgs.nil
 162           pkgs.next-ls
 163           #pkgs.rust-analyzer
 164         ];
 165         snacks = [
 166           pkgs.fd
 167           pkgs.ripgrep
 168         ];
 169         neovim = [
 170           pkgs.ripgrep
 171         ]
 172         ++ lib.optionals pkgs.stdenv.hostPlatform.isLinux [
 173           pkgs.xclip
 174           pkgs.wl-clipboard
 175         ];
 176       }
 177     )
 178   );
 179 }