flake.nix

   1 {
   2   inputs = {
   3     nixpkgs.url = "flake:nixpkgs";
   4     git-hooks.url = "github:cachix/git-hooks.nix";
   5     git-hooks.inputs.nixpkgs.follows = "nixpkgs";
   6     logic.url = "git+https://radicle-mermet.sourcephile.fr/z3795BqJN8hSMGkyAUr8hHviEEi2H.git";
   7   };
   8   outputs = inputs:
   9     let
  10       pkg = "literate-phylomemy";
  11       lib = inputs.nixpkgs.lib;
  12       fileInputs = with lib.fileset; toSource {
  13         root = ./.;
  14         fileset = unions [
  15           ./literate-phylomemy.cabal
  16           ./ChangeLog.md
  17           ./Readme.md
  18           ./LICENSES
  19           (fileFilter (file: lib.any file.hasExt [ "hs" ]) ./src)
  20           (fileFilter (file: lib.any file.hasExt [ "hs" "golden" ]) ./tests)
  21         ];
  22       };
  23       perSystem = f: lib.genAttrs lib.systems.flakeExposed (system: f rec {
  24         inherit system;
  25         pkgs = inputs.nixpkgs.legacyPackages.${system};
  26         haskellPackages = pkgs.haskellPackages.extend (with pkgs.haskell.lib; finalHaskellPkgs: previousHaskellPkgs: {
  27           ${pkg} = buildFromSdist (finalHaskellPkgs.callCabal2nix pkg fileInputs { });
  28           logic = finalHaskellPkgs.callCabal2nix "logic" inputs.logic { };
  29         });
  30       });
  31     in
  32     rec {
  33       # nix -L build
  34       packages = perSystem ({ haskellPackages, ... }: {
  35         default = haskellPackages.${pkg};
  36       });
  37       # nix -L develop  or  direnv allow
  38       devShells = perSystem ({ pkgs, haskellPackages, system, ... }: {
  39         default =
  40           haskellPackages.shellFor {
  41             packages = ps: [ ps.${pkg} ];
  42             nativeBuildInputs = [
  43               haskellPackages.cabal-fmt
  44               haskellPackages.cabal-install
  45               haskellPackages.ghcid
  46               haskellPackages.haskell-language-server
  47               haskellPackages.hlint
  48               pkgs.git-chglog
  49               pkgs.reuse
  50             ];
  51             withHoogle = false;
  52             inherit (checks.${system}.git-hooks-check) shellHook;
  53           };
  54       });
  55       # nix flake check
  56       checks = perSystem (args: with args; {
  57         git-hooks-check = inputs.git-hooks.lib.${system}.run {
  58           src = ./.;
  59           hooks = {
  60             cabal-fmt.enable = true;
  61             fourmolu.enable = true;
  62             hlint.enable = true;
  63             nixpkgs-fmt.enable = true;
  64             ormolu.settings.cabalDefaultExtensions = true;
  65             reuse = {
  66               enable = true;
  67               entry = "${pkgs.reuse}/bin/reuse lint";
  68               pass_filenames = false;
  69             };
  70           };
  71         };
  72       });
  73     };
  74 }