servers/losurdo/acme/sourcephile.fr.nix

   1 { pkgs, lib, config, servers, ... }:
   2 let
   3   domain = "sourcephile.fr";
   4   domainID = lib.replaceStrings ["."] ["_"] domain;
   5   inherit (config.security) pass;
   6   inherit (config.users) users groups;
   7 in
   8 {
   9 networking.nftables.ruleset = ''
  10   # for lego to update ACME DNS-01 challenge
  11   add rule inet filter fw2net tcp dport 53 ip daddr ${servers.mermet.ipv4} counter accept comment "ACME DNS-01"
  12   add rule inet filter fw2net udp dport 53 ip daddr ${servers.mermet.ipv4} counter accept comment "ACME DNS-01"
  13   # for lego to check DNS propagation on ns6.gandi.net
  14   add rule inet filter fw2net ip daddr 217.70.177.40 tcp dport 53 skuid ${users.root.name} counter accept comment "DNS gandi"
  15   add rule inet filter fw2net ip daddr 217.70.177.40 udp dport 53 skuid ${users.root.name} counter accept comment "DNS gandi"
  16 '';
  17 security.acme.certs."${domain}" = {
  18   email = "root+letsencrypt@${domain}";
  19   extraDomains = {
  20     "*.${domain}" = null;
  21   };
  22   user = users.root.name;
  23   group = groups.acme.name;
  24   allowKeysForGroup = true;
  25   keyType = "rsa4096";
  26   dnsProvider = "rfc2136";
  27   # ns6.gandi.net takes roughly 5min to update
  28   # hence lego's RFC2136_PROPAGATION_TIMEOUT=1000
  29   #dnsPropagationCheck = false;
  30   credentialsFile = pass.secrets."lego/${domain}/rfc2136".path;
  31 };
  32 security.pass.secrets."lego/${domain}/rfc2136" = {
  33   pipe = ''
  34     cat - ${pkgs.writeText "env" ''
  35     RFC2136_NAMESERVER=ns.${domain}:53
  36     RFC2136_TSIG_ALGORITHM=hmac-sha256.
  37     RFC2136_TSIG_KEY=acme_${domainID}
  38     RFC2136_PROPAGATION_TIMEOUT=1000
  39     RFC2136_POLLING_INTERVAL=30
  40     RFC2136_SEQUENCE_INTERVAL=30
  41     RFC2136_DNS_TIMEOUT=1000
  42     RFC2136_TTL=1
  43     ''}
  44   '';
  45 };
  46 systemd.services."acme-${domain}" = {
  47   after = [
  48     "unbound.service"
  49     pass.secrets."lego/${domain}/rfc2136".service
  50   ];
  51   wants = [
  52     "unbound.service"
  53     pass.secrets."lego/${domain}/rfc2136".service
  54   ];
  55 };
  56 }