shell.nix

   1 let
   2   nixpkgs_channel = builtins.getEnv "nixpkgs_channel";
   3   originNixpkgs = import (.config/nixpkgs-channel + ("/" + nixpkgs_channel + ".nix"));
   4   originPkgs = import originNixpkgs {
   5     config   = {}; # Make the config pure, ignoring user's config.
   6     overlays = [];
   7   };
   8   nixpkgsPatches = [
   9     /*
  10     { meta.description = "nsd : use types.lines where appropriate";
  11       url = "https://github.com/NixOS/nixpkgs/pull/78968.diff";
  12       sha256 = "11bqq1g1ax6i7xghihyhklmqpsq3njalardp6nvzphkjgxrypb47";
  13     }
  14     { meta.description = "shorewall: init at 5.2.3.3";
  15       url = "https://github.com/NixOS/nixpkgs/pull/46131.diff";
  16       sha256 = "0mfzlcr23ni5spnwksmmls50sw10alqbr5j6hjrwp9i30z0419yx";
  17     }
  18     */
  19     { meta.description = "Dovecot plugin for Full Text Search (FTS) with Xapian";
  20       url = "https://github.com/NixOS/nixpkgs/pull/78780.diff";
  21       sha256 = "053md69ryybj27cp0xdfrza48zyzpblk6wvb2m2dbs9hm0gmcwc4";
  22     }
  23     /* Disabled because it triggers the local build of too many reverse-dependencies
  24     { meta.description = "openldap: enable sha2 and pbkdf2 modules";
  25       url = "https://github.com/NixOS/nixpkgs/pull/79286.diff";
  26       sha256 = "0y255x74qksqy7fm4bdwlknhm3s55vgfgbv4dd7580p4lcavya0m";
  27     }
  28     */
  29     /*
  30     { meta.description = "Replace simp-le with lego and support DNS-01 challenge";
  31       url = "https://github.com/NixOS/nixpkgs/pull/77578.diff";
  32       sha256 = "15zs2146zh54jg1gywrcwyqxpx7izc35vlakk3cvrlqwwsvlr2rf";
  33     }
  34     */
  35     { meta.description = "dstat: fix pluginpath";
  36       url = "https://github.com/NixOS/nixpkgs/pull/80151.diff";
  37       sha256 = "0jjw2gvp7b7v2n2m2d6yj0gw711j6p9lyjf5ywp2y9ql6905qf4b";
  38     }
  39     /*
  40     { meta.description = "shorewall: fix warnings due to types.loaOf being deprecated";
  41       url = "https://github.com/NixOS/nixpkgs/pull/80154.diff";
  42       sha256 = "0b216m1rib3jl6s3r5cbkd5h1bfhppikg4cz9ayr1fspsflr3bci";
  43     }
  44     { meta.description = "shorewall: fix RestartTriggers";
  45       url = "https://github.com/NixOS/nixpkgs/pull/81774.diff";
  46       sha256 = "14drpym2mq9gq505psjzqq23gv0wkbwrrvh438h5jirzcym3467a";
  47     }
  48     */
  49   ];
  50   localNixpkgsPatches = [
  51     patches/direnv.diff
  52   ];
  53   nixpkgs = originPkgs.stdenv.mkDerivation {
  54     name = "nixpkgs-patched";
  55     src = originNixpkgs;
  56     phases = [ "unpackPhase" "patchPhase" ];
  57     patches = map originPkgs.fetchpatch nixpkgsPatches ++ localNixpkgsPatches;
  58     postPatch = ''
  59       patch=$(printf '%s\n' ${builtins.concatStringsSep " " (map (p: p.sha256) nixpkgsPatches)} |
  60         sort | sha256sum | cut -c -7)
  61       mv $PWD $out
  62       echo "+patch-$patch" >$out/.version-suffix
  63     '';
  64   };
  65   pkgs = import nixpkgs {
  66     config = {}; # Make the config pure, ignoring user's config.
  67     overlays = import ./overlays.nix;
  68   };
  69
  70
  71   lib = pkgs.lib;
  72   nixos = pkgs.nixos {};
  73   # Configuration of shell/modules/
  74   configuration = {config, ...}: {
  75     imports = [
  76     ];
  77     nix = {
  78       nixConf = ''
  79         auto-optimise-store = true
  80       '';
  81     };
  82     nix-plugins = {
  83       enable = true;
  84     };
  85     gnupg = {
  86       enable = true;
  87       gnupgHome = toString ../sec/gnupg;
  88       keys = import shell/openpgp.nix;
  89       gpgExtraConf = ''
  90         # julm@sourcephile.fr
  91         trusted-key 0xB2450D97085B7B8C
  92       '';
  93     };
  94     openssl = {
  95       enable = true;
  96       opensslHome = toString ../sec/openssl;
  97       certificates = import shell/x509.nix;
  98     };
  99     openssh = {
 100       # WARNING: nixops uses its own ssh, not this one.
 101       enable = true;
 102       sshConf = ''
 103         Ciphers aes256-gcm@openssh.com,aes128-gcm@openssh.com,aes256-ctr
 104         Compression no
 105         #CompressionLevel 4
 106         ControlMaster auto
 107         ControlPath ${builtins.toString ../sec/ssh}/ssh-%h-%p-%r.socket
 108         HashKnownHosts no
 109         #SSAPIAuthentication no
 110         SendEnv LANG LC_*
 111         StrictHostKeyChecking yes
 112         UserKnownHostsFile ${builtins.toString ../sec/ssh/known_hosts}
 113       '';
 114     };
 115     virtualbox = {
 116       enable = true;
 117     };
 118   };
 119
 120   # Using modules enables to separate specific configurations
 121   # from reusable code in shell/modules.nix and shell/modules/
 122   # which may find its way in another git repository one day.
 123   modules =
 124     (import shell/modules.nix {
 125       inherit pkgs lib;
 126       modules = [ configuration ];
 127     }).config;
 128
 129   # Utility to query the Nix files like nixops show-option
 130   # but without requiring a nixops database, and not limited to config entries.
 131   pwd = toString (./. + "");
 132   sourcephile-nix-get = pkgs.writeShellScriptBin "sourcephile-nix-get" ''
 133     nix-instantiate --read-write-mode \
 134      --arg networkExprs "[${pwd}/servers.nix ${pwd}/servers/production.nix]" \
 135      --arg args '{}' --argstr "uuid" whatever \
 136      --argstr deploymentName production "<nixops/eval-machine-info.nix>" \
 137      --eval-only --strict --arg checkConfigurationOptions false -A "$@"
 138   '';
 139   sourcephile-shred-tmp = pkgs.writeShellScriptBin "sourcephile-shred-tmp" ''
 140     # Cleanup "../sec/tmp/"
 141     # This is done when entering the nix-shell
 142     # because direnv already hooks trap EXIT.
 143     cd "${pwd}"
 144     find sec/tmp -type f -exec shred -fu {} +
 145     rm -rf sec/tmp
 146   '';
 147 in
 148 pkgs.mkShell {
 149   name = "sourcephile-nix";
 150   src = null;
 151   #preferLocalBuild = true;
 152   #allowSubstitutes = false;
 153   buildInputs = modules.nix-shell.buildInputs ++ [
 154     sourcephile-nix-get
 155     sourcephile-shred-tmp
 156     nixos.nixos-generate-config
 157     nixos.nixos-install
 158     nixos.nixos-enter
 159     #pkgs.binutils
 160     pkgs.coreutils
 161     pkgs.cryptsetup
 162     pkgs.curl
 163     #pkgs.direnv
 164     pkgs.dnsutils
 165     #pkgs.dropbear
 166     pkgs.e2fsprogs
 167     pkgs.git
 168     pkgs.glibcLocales
 169     pkgs.gnumake
 170     pkgs.gnupg
 171     pkgs.htop
 172     #pkgs.inetutils
 173     pkgs.ipcalc
 174     #pkgs.iputils
 175     pkgs.less
 176     pkgs.libfaketime
 177     pkgs.ldns
 178     #pkgs.ldns.examples
 179     #pkgs.mailutils
 180     pkgs.man
 181     pkgs.mdadm
 182     pkgs.gptfdisk
 183     pkgs.ncdu
 184     pkgs.ncurses
 185     pkgs.nixops
 186     #pkgs.openssl
 187     pkgs.pass
 188     pkgs.procps
 189     pkgs.rsync
 190     #pkgs.rxvt_unicode.terminfo
 191     #pkgs.sqlite
 192     pkgs.sqlite
 193     #pkgs.sudo
 194     pkgs.tig
 195     pkgs.time
 196     #pkgs.tmux
 197     pkgs.tree
 198     pkgs.utillinux
 199     #pkgs.vim
 200     #pkgs.virtualbox
 201     pkgs.which
 202     pkgs.xdg_utils
 203     pkgs.zfs
 204     pkgs.fio
 205     pkgs.strace
 206     pkgs.utillinux
 207     #pkgs.zfstools
 208   ];
 209   #enableParallelBuilding = true;
 210   shellHook = ''
 211     echo >&2 "nix: running shellHook"
 212
 213     # Nix
 214     PATH=$NIX_SHELL_PATH:$PATH
 215     export NIX_PATH="nixpkgs=${toString pkgs.path}:nixpkgs-overlays="$PWD"/overlays:nixops=${toString pkgs.nixops}/share/nix/nixops"
 216     export nixpkgs_channel=${nixpkgs_channel}
 217
 218     # Since the .envrc calls this shellHook
 219     # the EXIT trap cannot be freely used
 220     # because it's already used by direnv,
 221     # hence shred at startup, which is not ideal.
 222     sourcephile-shred-tmp
 223
 224     ${modules.nix-shell.shellHook}
 225
 226     # password-store
 227     export PASSWORD_STORE_DIR="$PWD"/../sec/pass
 228
 229     # gpg
 230     export GPG_TTY=$(tty)
 231     gpg-connect-agent updatestartuptty /bye >/dev/null
 232
 233     # nixops
 234     #export NIXOPS_DEPLOYMENT="staging"
 235     export MERMET_DEPLOYMENT=production
 236     export LOSURDO_DEPLOYMENT=production
 237     export NIXOPS_STATE="$PWD"/../sec/nixops/state.nixops
 238     NIXOPS_OPTS+=" --show-trace"
 239     export NIXOPS_OPTS
 240
 241     # disnix
 242     #export DISNIXOS_USE_NIXOPS=1
 243     #export DISNIX_CLIENT_INTERFACE=disnix-nixops-client
 244     #export DISNIX_PROFILE=default
 245     #export DISNIX_TARGET_PROPERTY=hostname
 246     #export DYSNOMIA_STATEDIR="$PWD"/../sec/dysnomia
 247   '';
 248 }