hosts/losurdo/acme/autogeree.net.nix

   1 { pkgs, lib, config, hosts, ... }:
   2 let
   3   domain = "autogeree.net";
   4   domainID = lib.replaceStrings ["."] ["_"] domain;
   5   inherit (config.security) gnupg;
   6   inherit (config.users) users groups;
   7 in
   8 {
   9 networking.nftables.ruleset = ''
  10   # for lego to update ACME DNS-01 challenge
  11   add rule inet filter fw2net ip daddr ${hosts.mermet._module.args.ipv4} meta l4proto { udp, tcp } th dport 53 counter accept comment "ACME DNS-01"
  12   # for lego to check DNS propagation on ns6.gandi.net
  13   add rule inet filter fw2net ip daddr 217.70.177.40 meta l4proto { udp, tcp } th dport 53 skuid ${users.acme.name} counter accept comment "DNS gandi"
  14   add rule inet filter fw2net ip6 daddr 2001:4b98:d:1::40 meta l4proto { udp, tcp } th dport 53 skuid ${users.acme.name} counter accept comment "DNS gandi"
  15   # for lego to check DNS propagation on ns0.muarf.org
  16   #add rule inet filter fw2net ip daddr 78.192.65.63 meta l4proto { udp, tcp } th dport 53 skuid ${users.acme.name} counter accept comment "DNS muarf"
  17 '';
  18 security.acme.certs."${domain}" = {
  19   email = "root+letsencrypt@${domain}";
  20   extraDomainNames = [
  21     "*.${domain}"
  22   ];
  23   group = groups.acme.name;
  24   keyType = "rsa4096";
  25   dnsProvider = "rfc2136";
  26   # ns6.gandi.net takes roughly 5min to update
  27   # hence lego's RFC2136_PROPAGATION_TIMEOUT=1000
  28   #dnsPropagationCheck = false;
  29   credentialsFile = gnupg.secrets."lego/${domain}/rfc2136".path;
  30 };
  31 security.gnupg.secrets."lego/${domain}/rfc2136" = {
  32   pipe = ''
  33     cat - ${pkgs.writeText "env" ''
  34     RFC2136_NAMESERVER=ns.${domain}:53
  35     RFC2136_TSIG_ALGORITHM=hmac-sha256.
  36     RFC2136_TSIG_KEY=acme_${domainID}
  37     RFC2136_PROPAGATION_TIMEOUT=1000
  38     RFC2136_POLLING_INTERVAL=30
  39     RFC2136_SEQUENCE_INTERVAL=30
  40     RFC2136_DNS_TIMEOUT=1000
  41     RFC2136_TTL=1
  42     ''}
  43   '';
  44 };
  45 systemd.services."acme-${domain}" = {
  46   after = [
  47     "unbound.service"
  48     gnupg.secrets."lego/${domain}/rfc2136".service
  49   ];
  50   wants = [
  51     "unbound.service"
  52     gnupg.secrets."lego/${domain}/rfc2136".service
  53   ];
  54 };
  55 }